From 1922ee7d4015956555f5a5d82994df027ca60415 Mon Sep 17 00:00:00 2001
From: Jean-Marc Lasgouttes <lasgouttes@lyx.org>
Date: Fri, 15 Oct 2021 17:05:04 +0200
Subject: [PATCH] Autoconf: disable warning deprecated-copy when supported

Cherry-picked from:
4aee447af1ab29d094e917b94ec3e3d4af36f1cd
c52049bb83d71b926e6b949362a47bde9f8d5653
37c34c5ca98a31669144a7119068edf96d68261c
---
 config/lyxinclude.m4        | 11 ++++----
 m4/ax_check_compile_flag.m4 | 53 +++++++++++++++++++++++++++++++++++++
 status.23x                  |  4 ++-
 3 files changed, 62 insertions(+), 6 deletions(-)
 create mode 100644 m4/ax_check_compile_flag.m4

diff --git a/config/lyxinclude.m4 b/config/lyxinclude.m4
index 59421ae225..2443201a5d 100644
--- a/config/lyxinclude.m4
+++ b/config/lyxinclude.m4
@@ -411,11 +411,12 @@ if test x$GXX = xyes; then
   dnl Warnings are for preprocessor too
   if test x$enable_warnings = xyes ; then
       AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
-      case $gxx_version in
-	  9.*|10.*|clang-10*)
-	      AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-copy";;
-	  *);;
-      esac
+      dnl Shut off warning -Wdeprecated-copy, which triggers too much
+      dnl note that g++ always accepts -Wno-xxx, even when -Wxxx is an error.
+      AC_LANG_PUSH(C++)
+      AX_CHECK_COMPILE_FLAG([-Wdeprecated-copy],
+	[AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-copy"], [], [-Werror])
+      AC_LANG_POP(C++)
     fi
   case $gxx_version in
       2.*|3.*) AC_ERROR([gcc >= 4.6 is required]);;
diff --git a/m4/ax_check_compile_flag.m4 b/m4/ax_check_compile_flag.m4
new file mode 100644
index 0000000000..bd753b34d7
--- /dev/null
+++ b/m4/ax_check_compile_flag.m4
@@ -0,0 +1,53 @@
+# ===========================================================================
+#  https://www.gnu.org/software/autoconf-archive/ax_check_compile_flag.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_CHECK_COMPILE_FLAG(FLAG, [ACTION-SUCCESS], [ACTION-FAILURE], [EXTRA-FLAGS], [INPUT])
+#
+# DESCRIPTION
+#
+#   Check whether the given FLAG works with the current language's compiler
+#   or gives an error.  (Warnings, however, are ignored)
+#
+#   ACTION-SUCCESS/ACTION-FAILURE are shell commands to execute on
+#   success/failure.
+#
+#   If EXTRA-FLAGS is defined, it is added to the current language's default
+#   flags (e.g. CFLAGS) when the check is done.  The check is thus made with
+#   the flags: "CFLAGS EXTRA-FLAGS FLAG".  This can for example be used to
+#   force the compiler to issue an error when a bad flag is given.
+#
+#   INPUT gives an alternative input source to AC_COMPILE_IFELSE.
+#
+#   NOTE: Implementation based on AX_CFLAGS_GCC_OPTION. Please keep this
+#   macro in sync with AX_CHECK_{PREPROC,LINK}_FLAG.
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
+#   Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved.  This file is offered as-is, without any
+#   warranty.
+
+#serial 6
+
+AC_DEFUN([AX_CHECK_COMPILE_FLAG],
+[AC_PREREQ(2.64)dnl for _AC_LANG_PREFIX and AS_VAR_IF
+AS_VAR_PUSHDEF([CACHEVAR],[ax_cv_check_[]_AC_LANG_ABBREV[]flags_$4_$1])dnl
+AC_CACHE_CHECK([whether _AC_LANG compiler accepts $1], CACHEVAR, [
+  ax_check_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
+  _AC_LANG_PREFIX[]FLAGS="$[]_AC_LANG_PREFIX[]FLAGS $4 $1"
+  AC_COMPILE_IFELSE([m4_default([$5],[AC_LANG_PROGRAM()])],
+    [AS_VAR_SET(CACHEVAR,[yes])],
+    [AS_VAR_SET(CACHEVAR,[no])])
+  _AC_LANG_PREFIX[]FLAGS=$ax_check_save_flags])
+AS_VAR_IF(CACHEVAR,yes,
+  [m4_default([$2], :)],
+  [m4_default([$3], :)])
+AS_VAR_POPDEF([CACHEVAR])dnl
+])dnl AX_CHECK_COMPILE_FLAGS
diff --git a/status.23x b/status.23x
index 9ab48d5cf5..91fc32f1c8 100644
--- a/status.23x
+++ b/status.23x
@@ -32,7 +32,7 @@ What's new
   equivalent to hitting the left arrow key (bug 11678).
 
 - Other than directly inserted, now references can also be pasted as insets
-  into an equation, instead of simply as text (bug 11539). 
+  into an equation, instead of simply as text (bug 11539).
 
 - Add support for High DPI screens in Windows and Linux (bug 12060).
 
@@ -156,3 +156,5 @@ What's new
 
 - The WM class of LyX for X Window environment is now the package name, typically
   "lyx" or "lyx[suffix]" (bug 11930).
+
+- Fix warnings with recent compilers (gcc 11, clang+++ >= 10)
-- 
2.39.5