+dnl Usage: LYX_USE_INCLUDED_ZLIB : select if the included zlib should
+dnl be used.
+AC_DEFUN([LYX_USE_INCLUDED_ZLIB],[
+ AC_MSG_CHECKING([whether to use included zlib library])
+ AC_ARG_WITH(included-zlib,
+ [AS_HELP_STRING([--with-included-zlib], [use the zlib lib supplied with LyX instead of the system one])],
+ [lyx_cv_with_included_zlib=$withval],
+ [lyx_cv_with_included_zlib=no])
+ AM_CONDITIONAL(USE_INCLUDED_ZLIB, test x$lyx_cv_with_included_zlib = xyes)
+ AC_MSG_RESULT([$lyx_cv_with_included_zlib])
+ if test x$lyx_cv_with_included_zlib = xyes ; then
+ lyx_included_libs="$lyx_included_libs zlib"
+ ZLIB_INCLUDES='-I$(top_srcdir)/3rdparty/zlib/1.2.8 -I$(top_builddir)/3rdparty/zlib'
+ ZLIB_LIBS='$(top_builddir)/3rdparty/zlib/liblyxzlib.a'
+ mkdir -p 3rdparty/zlib
+dnl include standard config.h for HAVE_UNISTD_H
+ echo "#include <../../config.h>" > 3rdparty/zlib/zconf.h
+dnl prevent clash with system zlib that might be dragged in by other libs
+ echo "#define Z_PREFIX 1" >> 3rdparty/zlib/zconf.h
+ cat "${srcdir}/3rdparty/zlib/1.2.8/zconf.h.in" >> 3rdparty/zlib/zconf.h
+ else
+ ZLIB_INCLUDES=
+ AC_CHECK_HEADERS(zlib.h,
+ [AC_CHECK_LIB(z, gzopen, [ZLIB_LIBS="-lz"], LYX_LIB_ERROR(libz,zlib))],
+ [LYX_LIB_ERROR(zlib.h,zlib)])
+ fi
+ AC_SUBST(ZLIB_INCLUDES)
+ AC_SUBST(ZLIB_LIBS)
+])
+
+
+dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
+dnl necessary APIs are available to print callstacks.
+AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
+[AC_ARG_ENABLE([callstack-printing],
+ [AS_HELP_STRING([--disable-callstack-printing],[do not print a callstack when crashing])],
+ lyx_cv_callstack_printing=$enableval, lyx_cv_callstack_printing=yes)
+
+if test x"$lyx_cv_callstack_printing" = xyes; then
+ AC_CACHE_CHECK([whether printing callstack is possible],
+ [lyx_cv_callstack_printing],
+ [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+ #include <execinfo.h>
+ #include <cxxabi.h>
+ ]], [[
+ void* array[200];
+ size_t size = backtrace(array, 200);
+ backtrace_symbols(array, size);
+ int status = 0;
+ abi::__cxa_demangle("abcd", 0, 0, &status);
+ ]])],[],[lyx_cv_callstack_printing=no])])
+fi
+if test x"$lyx_cv_callstack_printing" = xyes; then
+ AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
+ [Define if callstack can be printed])
+ lyx_flags="$lyx_flags callback-printing"
+ AM_LDFLAGS="${AM_LDFLAGS} -rdynamic"
+fi
+])
+
+
+dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
+dnl be used.
+AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
+ AC_ARG_WITH(included-mythes,
+ [AS_HELP_STRING([--with-included-mythes], [force to use the MyThes lib supplied with LyX])],
+ [use_included_mythes=$withval],
+ [use_included_mythes=no])
+ if test x$use_included_mythes != xyes ; then
+ AC_LANG_PUSH(C++)
+ use_included_mythes=yes
+ AC_CHECK_HEADERS([mythes.hxx mythes/mythes.hxx],
+ [mythes_h_location="<$ac_header>"
+ save_LIBS=$LIBS
+ AC_MSG_CHECKING([checking for MyThes library])
+ for ac_lib in mythes mythes-1.2 ; do
+ LIBS="-l$ac_lib $save_LIBS"
+ AC_LINK_IFELSE(
+ [AC_LANG_PROGRAM([#include <cstdio>]
+ [#include $mythes_h_location], [MyThes dummy("idx","dat")])],
+ [MYTHES_LIBS=-l$ac_lib
+ AC_MSG_RESULT([$MYTHES_LIBS])
+ use_included_mythes=no])
+ done
+ if test $use_included_mythes != no ; then
+ AC_MSG_RESULT([not found])
+ fi
+ break])
+ AC_LANG_POP(C++)
+ fi
+ if test $use_included_mythes = yes ; then
+ mythes_h_location="<mythes.hxx>"
+ MYTHES_INCLUDES='-I$(top_srcdir)/3rdparty/mythes/1.2.5/'
+ MYTHES_LIBS='$(top_builddir)/3rdparty/mythes/liblyxmythes.a'
+ lyx_included_libs="$lyx_included_libs mythes"
+ fi
+ AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$use_included_mythes = xyes)
+ AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$mythes_h_location,[Location of mythes.hxx])
+ AC_SUBST(MYTHES_INCLUDES)
+ AC_SUBST(MYTHES_LIBS)
+ AC_MSG_CHECKING([whether to use included MyThes library])
+ AC_MSG_RESULT([$use_included_mythes])