+
+
+## ------------------------------------------------------------------------
+## Check whether mkdir() is mkdir or _mkdir, and whether it takes
+## one or two arguments.
+##
+## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
+## ------------------------------------------------------------------------
+##
+AC_DEFUN([AC_FUNC_MKDIR],
+[AC_CHECK_FUNCS([mkdir _mkdir])
+AC_CACHE_CHECK([whether mkdir takes one argument],
+ [ac_cv_mkdir_takes_one_arg],
+[AC_TRY_COMPILE([
+#include <sys/stat.h>
+#if HAVE_UNISTD_H
+# include <unistd.h>
+#endif
+], [mkdir (".");],
+[ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
+if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
+ AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
+ [Define if mkdir takes only one argument.])
+fi
+])
+
+
+dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
+dnl (which may be a relative path, and need not refer to any existing
+dnl entity).
+
+dnl On Win32-MSYS build hosts, the returned path is resolved to its true
+dnl native Win32 path name, (but with slashes, not backslashes).
+
+dnl On any other system, it is simply the result which would be obtained
+dnl if PATHNAME represented an existing directory, and the pwd command was
+dnl executed in that directory.
+AC_DEFUN([MSYS_AC_CANONICAL_PATH],
+[ac_dir="$2"
+ ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
+ ac_pwd_w="pwd -W" || ac_pwd_w=pwd
+ until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
+ do
+ ac_dir=`AS_DIRNAME(["$ac_dir"])`
+ done
+ ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
+ ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
+ $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
+ s?/*$[]??'`
+])
+
+dnl this is used by the macro blow to general a proper config.h.in entry
+m4_define([LYX_AH_CHECK_DECL],
+[AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
+ [Define if you have the prototype for function `$1'])])
+
+dnl Check things are declared in headers to avoid errors or warnings.
+dnl Called like LYX_CHECK_DECL(function, header1 header2...)
+dnl Defines HAVE_DECL_{FUNCTION}
+AC_DEFUN([LYX_CHECK_DECL],
+[LYX_AH_CHECK_DECL($1)
+for ac_header in $2
+do
+ AC_MSG_CHECKING([if $1 is declared by header $ac_header])
+ AC_EGREP_HEADER($1, $ac_header,
+ [AC_MSG_RESULT(yes)
+ AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
+ break],
+ [AC_MSG_RESULT(no)])
+done])
+
+dnl Extract the single digits from PACKAGE_VERSION and make them available.
+dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
+dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
+AC_DEFUN([LYX_SET_VERSION_INFO],
+[lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
+ lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
+ lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
+ lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
+ lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
+ lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
+ test "x$lyx_patch" = "x" && lyx_patch=0
+ lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
+ lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
+ AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
+ AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
+ AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
+ AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
+ AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
+ AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
+])