+# This directory should be used if some test uses lyx-executable
+set(LYX_TESTS_USERDIR "${TOP_BINARY_DIR}/Testing/.lyx")
+file(MAKE_DIRECTORY "${LYX_TESTS_USERDIR}")
+
+if(COMMAND cmake_policy)
+ cmake_policy(SET CMP0003 OLD)
+ cmake_policy(SET CMP0005 OLD)
+endif()
+
+set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
+
+# Supress regeneration
+set(CMAKE_SUPPRESS_REGENERATION FALSE)
+
+if(NOT help AND NOT HELP)
+ # 'project' triggers the searching for a compiler
+ project(${LYX_PROJECT})
+endif()
+
+if(UNIX)
+ set(ARCH_TRIPLET )
+ FIND_PROGRAM(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
+ if(DPKG_ARCHITECTURE_EXECUTABLE)
+ EXECUTE_PROCESS(COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
+ OUTPUT_VARIABLE ARCH_TRIPLET
+ ERROR_VARIABLE ERROR_ARCH_TRIPLET
+ OUTPUT_STRIP_TRAILING_WHITESPACE)
+ endif()
+endif()
+if(ARCH_TRIPLET)
+ set(SYSTEM_LIB_DIRS /usr/lib /usr/lib/${ARCH_TRIPLET} /usr/local/lib)
+else()
+ set(SYSTEM_LIB_DIRS /usr/lib /usr/local/lib)
+endif()
+
+include(LyXMacros)
+
+# Usage LYX_OPTION
+# 1. parameter: option name without prefix 'LYX_'
+# 2. parameter: description
+# 3. parameter: default value, ON or OFF
+# 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
+
+
+LYX_OPTION_INIT()
+
+# Options for all compilers/systems
+LYX_OPTION(CPACK "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
+LYX_OPTION(LOCALVERSIONING "Add version info to created package name (only used if LYX_CPACK option set)" OFF ALL)
+LYX_OPTION(INSTALL "Build install projects/rules (implies a bunch of other options)" OFF ALL)
+LYX_OPTION(NLS "Enable Native Language Support (NLS)" ON ALL)
+LYX_OPTION(ASPELL "Require aspell" OFF ALL)
+LYX_OPTION(ENCHANT "Require Enchant" OFF ALL)
+LYX_OPTION(HUNSPELL "Require Hunspell" OFF ALL)
+LYX_OPTION(DEVEL_VERSION "Build developer version" OFF ALL)
+LYX_OPTION(RELEASE "Build release version, build debug when disabled" OFF ALL)
+LYX_OPTION(DEBUG "Enforce debug build" OFF ALL)
+LYX_OPTION(NO_OPTIMIZE "Don't use any optimization/debug flags" OFF ALL)
+LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" ON ALL)
+LYX_OPTION(PCH "Use precompiled headers" OFF ALL)
+LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
+LYX_OPTION(MERGE_REBUILD "Rebuild generated files from merged files build" OFF ALL)
+LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
+LYX_OPTION(INSTALL_PREFIX "Install path for LyX" OFF ALL)
+LYX_OPTION(BUNDLE "Build bundle (experimental) " OFF ALL)
+
+# GCC specific
+LYX_OPTION(PROFILE "Build profile version" OFF GCC)
+LYX_OPTION(EXTERNAL_BOOST "Use external boost" OFF GCC)
+LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
+LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
+LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++ pedantic debug mode" OFF GCC)
+LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
+LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
+LYX_OPTION(PROFILE "Build with options for gprof" OFF GCC)
+LYX_OPTION(ENABLE_CXX11 "Build with options for c++11-mode" OFF GCC)
+
+# MSVC specific
+LYX_OPTION(CONSOLE "Show console on Windows, enforce with =FORCE" ON MSVC)
+LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
+LYX_OPTION(WALL "Enable all warnings" OFF MSVC)
+LYX_OPTION(CONFIGURE_CHECKS "Also run configure checks for MSVC" OFF MSVC)
+LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
+
+# APPLE specific
+LYX_OPTION(DMG "Build as Mac bundle, needed for .dmg (experimental) " OFF MAC)
+LYX_OPTION(COCOA "Use Cocoa on Mac" OFF MAC)
+
+
+if(help OR HELP)
+ message(STATUS)
+ message(STATUS "Available options: (dis/enable with -DLYX_*=OFF/ON)")
+ message(STATUS)
+ LYX_OPTION_LIST_ALL(help)
+ message(STATUS)
+ RETURN()
+endif()
+
+# Check option dependencies
+
+if(LYX_DMG)
+ set(LYX_BUNDLE ON)
+ set(LYX_CPACK ON)
+endif()
+
+if(LYX_CPACK)
+ set(LYX_INSTALL ON)
+endif()
+
+if(LYX_INSTALL)
+ set(LYX_NLS ON)
+ if (WIN32)
+ set(LYX_HUNSPELL ON)
+ endif()
+ if(LYX_CONSOLE MATCHES "FORCE")
+ set(LYX_CONSOLE ON)
+ else()
+ set(LYX_CONSOLE OFF)
+ endif()
+ set(LYX_PACKAGE_SUFFIX ON)
+ if(NOT LYX_DEBUG)
+ set(LYX_RELEASE ON)
+ endif()
+ set(LYX_PROFILE OFF)
+endif()
+
+
+if(LYX_MERGE_FILES)
+ set(LYX_PCH OFF)
+else()
+ set(LYX_MERGE_REBUILD OFF)
+endif()
+
+if(LYX_DEPENDENCIES_DOWNLOAD)
+ message(STATUS)
+ set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
+ message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
+ set(deps_files lyx20-deps-msvc2010-x86.zip)
+ set(deps_server http://downloads.sourceforge.net/project/lyx/Win_installers/Dependencies)
+ foreach(it ${deps_files})
+ set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
+ find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
+ if(NOT already_downloaded)
+ message(STATUS "Downloading ${it} ...")
+ file(DOWNLOAD ${deps_server}/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS STATUS status LOG log)
+ list(GET status 0 status_code)
+ list(GET status 1 status_string)
+ if(NOT status_code EQUAL 0)
+ file(REMOVE ${LYX_DEPENDENCIES_DIR}/${it})
+ message(FATAL_ERROR "error: downloading '${it}' failed. status_code: ${status_code}, status_string: ${status_string}. \nLog: ${log} ")
+ endif()
+ execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
+ WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
+ endif()
+ endforeach()
+ set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
+endif()
+
+
+
+message(STATUS)
+
+set(EXECUTABLE_OUTPUT_PATH ${TOP_BINARY_DIR}/bin)
+if(WIN32)
+ set(LIBRARY_OUTPUT_PATH ${EXECUTABLE_OUTPUT_PATH})
+else()
+ set(LIBRARY_OUTPUT_PATH ${TOP_BINARY_DIR}/lib)
+endif()
+
+
+set(LYX_GCC11_MODE)
+if(UNIX OR MINGW)
+ execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
+ message(STATUS "Using GCC version ${GCC_VERSION}")
+ if(NOT GCC_VERSION VERSION_LESS 4.4)
+ set(LYX_USE_TR1 1)
+ # GCC <= 4.5 does not support regex: there are linker errors
+ # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
+ set(LYX_USE_TR1_REGEX 0)
+ endif()
+ if (LYX_ENABLE_CXX11)
+ if(GCC_VERSION VERSION_GREATER 4.7)
+ set(LYX_GCC11_MODE "-std=gnu++11")
+ elseif(GCC_VERSION VERSION_GREATER 4.2)
+ set(LYX_GCC11_MODE "-std=gnu++0x")
+ endif()
+ endif()
+else()
+ if(MSVC10)
+ set(LYX_USE_TR1 1)
+ #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
+ endif()
+endif()
+
+
+set(VERSION_INFO "CMake Build")
+
+# Try to get some informations from configure.ac
+
+include(LyXPaths)
+file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
+
+if(WIN32)
+ set(USE_WINDOWS_PACKAGING ON)
+elseif(APPLE)
+ set(USE_MACOSX_PACKAGING ON)
+else()
+ set(USE_POSIX_PACKAGING ON)
+endif()
+
+macro(setstripped _varname)
+ if(${ARGC} GREATER 1)
+ string(STRIP "${ARGV1}" _v)
+ if(USE_POSIX_PACKAGING)
+ string(TOLOWER ${_v} ${_varname})
+ else()
+ set(${_varname} ${_v})
+ endif()
+ else()
+ set(${_varname})
+ endif()
+endmacro(setstripped)
+
+foreach(_c_l ${_config_lines} )
+ if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
+ setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
+ setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
+ setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
+ if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\)\(\\.\([0-9]+\)\)?.*$")
+ set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
+ set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
+ set(LYX_PATCH_VERSION ${CMAKE_MATCH_4})
+ set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
+ set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
+ set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
+ endif()
+ endif()
+ if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
+ set(LYX_DATE "${CMAKE_MATCH_1}")
+ endif()
+endforeach(_c_l)
+
+if (LYX_LOCALVERSIONING)
+ # Find the revision number and for later use
+ FIND_PROGRAM(LYX_GITVERSION git)
+ #message(STATUS "gitversion = ${LYX_GITVERSION}")
+ if(LYX_GITVERSION)
+ EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} "describe" WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE LYX_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
+ if (LYX_PACKAGE_RELEASE MATCHES "^2\\.0\\.0\\-\([0-9]+\)\\-.*$")
+ # We will add offset of 40000 to get appropriate value to
+ # previous svn.
+ # We use this value than also to set the package-patch-value
+ MATH(EXPR tmp_REVISION_VERSION "(${CMAKE_MATCH_1}+40000)")
+ set(LYX_REVISION_VERSION "${LYX_PATCH_VERSION}-${tmp_REVISION_VERSION}git")
+ set(ENABLE_DIST ON)
+ endif()
+ else()
+ set(LYX_REVISION_VERSION git) #TODO use date
+ endif()
+else()
+ set(LYX_REVISION_VERSION ${LYX_PATCH_VERSION})
+endif()
+
+if(LYX_PROGRAM_SUFFIX)
+ set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
+else()
+ set(PROGRAM_SUFFIX "")
+endif()
+
+add_custom_target(lyx_version ALL
+ COMMAND ${CMAKE_COMMAND} -DTOP_SRC_DIR=${TOP_SRC_DIR} -DTOP_CMAKE_PATH=${TOP_CMAKE_PATH} -DTOP_BINARY_DIR=${TOP_BINARY_DIR} -DLYX_DATE=${LYX_DATE} -P ${TOP_SCRIPT_PATH}/LyXGetVersion.cmake
+ )
+set_target_properties(lyx_version PROPERTIES FOLDER "applications")
+
+if(APPLE)
+ set(osx_bundle_program_name ${PACKAGE_BASE}${PROGRAM_SUFFIX})
+ configure_file("${CMAKE_CURRENT_SOURCE_DIR}/development/MacOSX/Info.plist.in" "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
+endif()
+
+if(LYX_BUNDLE)
+ set(LYX_CPACK ON)
+ message(STATUS)
+ message(STATUS "Bundle creation is enabled (experimental):")
+ message(STATUS " make")
+ message(STATUS " make install/strip")
+ message(STATUS " make package")
+ if(APPLE)
+ set(LYX_BUILD_BUNDLE MACOSX_BUNDLE)
+ set(CPACK_BUNDLE_NAME ${PACKAGE_BASE}${PROGRAM_SUFFIX})
+ set(CPACK_BUNDLE_PLIST "${CMAKE_CURRENT_BINARY_DIR}/Info.plist")
+ set(LYX_DATA_SUBDIR ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app/Contents/Resources/ CACHE STRING "Bundle Contents dir" FORCE)
+ set(MACOSX_BUNDLE_STARTUP_COMMAND ${PACKAGE_BASE}${PROGRAM_SUFFIX}.app)
+ if(NOT LYX_INSTALL_PREFIX)
+ set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LyX CACHE PATH "Mac bundle dir" FORCE)
+ set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
+ endif()
+ # Change the owner so that the install can work
+ install(CODE "set(BU_CHMOD_BUNDLE_ITEMS 1)")
+ elseif(UNIX)
+ message(STATUS "To embed Qt in this bundle don't build with your system Qt:")
+ message(STATUS " - fix PATH so a other qmake is found by cmake")
+ message(STATUS " - fix LD_LIBRARY_PATH so lyx doesn't use system's Qt")
+ elseif(WIN32)
+ message(STATUS "A zipped-only release could be created by building the 'PACKAGE' project")
+ endif()
+endif()
+
+if(LYX_INSTALL_PREFIX)
+ set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
+ set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
+endif()
+set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
+
+if(LYX_PACKAGE_SUFFIX)
+ set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
+else()
+ set(PACKAGE ${PACKAGE_BASE})
+endif()
+
+
+if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
+ # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
+ if (UNIX)
+ # don't use the default "/usr/local"
+ # but respect the user-choice on the command-line
+ if(LYX_INSTALL_SUFFIX)
+ set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
+ else()
+ set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
+ endif()
+ endif()
+ if(WIN32)
+ set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
+ endif()
+endif()
+if(IS_ABSOLUTE)
+ set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_INSTALL_PREFIX})
+else()
+ set(CMAKE_INSTALL_PREFIX_ABSOLUTE ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_PREFIX})
+endif()
+
+
+
+if(NOT LYX_DATA_SUBDIR)
+ if (WIN32)
+ set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
+ else()
+ set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
+ endif()
+endif()
+
+set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
+set(LYX_LOCALEDIR "locale")
+set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
+set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
+
+
+if(LYX_INSTALL AND WIN32)
+ message(STATUS "Configuring NSIS files")
+ configure_file(development/Win32/packaging/installer/lyx.nsi.cmake ${CMAKE_BINARY_DIR}/installer/lyx.nsi @ONLY)
+ configure_file(development/Win32/packaging/installer/settings.nsh.cmake ${CMAKE_BINARY_DIR}/installer/settings-cmake.nsh @ONLY)
+ configure_file(development/Win32/packaging/installer/include/declarations.nsh.cmake ${CMAKE_BINARY_DIR}/installer/declarations-cmake.nsh @ONLY)
+ message(STATUS "NSIS files are created in ${CMAKE_BINARY_DIR}/installer")
+endif()
+
+if(NOT GROUP_CODE)
+ #set(GROUP_CODE "The Golden Code")
+ set(GROUP_CODE flat)
+endif()
+
+# lyx's source files
+set(LYX_CPP_FILES *.cpp)
+set(LYX_HPP_FILES *.h)
+set(LYX_MOC_FILES moc_*.cpp)
+
+include(ProjectSourceGroup)
+