src/tex2lyx/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6 #
   7
   8 set(_tex2lyx tex2lyx${PROGRAM_SUFFIX})
   9 project(${_tex2lyx})
  10
  11 # There is no header file lengthcommon.h
  12 set(LINKED_sources ${TOP_SRC_DIR}/src/lengthcommon.cpp)
  13 set(LINKED_headers)
  14
  15 foreach(_src graphics/GraphicsParams insets/ExternalTemplate
  16         insets/ExternalTransforms insets/InsetLayout Author Color Counters
  17         Encoding FloatList Floating FontInfo LaTeXPackages Layout
  18         LayoutFile LayoutModuleList Length Lexer ModuleList TextClass
  19         Spacing version)
  20         list(APPEND LINKED_sources ${TOP_SRC_DIR}/src/${_src}.cpp)
  21         list(APPEND LINKED_headers ${TOP_SRC_DIR}/src/${_src}.h)
  22 endforeach(_src)
  23
  24 file(GLOB tex2lyx_sources ${TOP_SRC_DIR}/src/tex2lyx/${LYX_CPP_FILES})
  25
  26 file(GLOB tex2lyx_headers ${TOP_SRC_DIR}/src/tex2lyx/${LYX_HPP_FILES})
  27
  28 include_directories(BEFORE
  29         ${TOP_SRC_DIR}/src/tex2lyx
  30         ${TOP_SRC_DIR}/src/support/minizip
  31         ${ZLIB_INCLUDE_DIR})
  32
  33 add_definitions(-DTEX2LYX)
  34
  35 if(WIN32)
  36         set(FILE_RC ${TOP_SRC_DIR}/development/cmake/lyx.rc)
  37         message(STATUS "Using icon defined in resource file: ${FILE_RC}")
  38 endif()
  39
  40 if(NOT LYX_MERGE_FILES)
  41         add_executable(${_tex2lyx} ${tex2lyx_sources} ${LINKED_sources} ${tex2lyx_headers} ${LINKED_headers}    ${FILE_RC})
  42 else()
  43         lyx_const_touched_files(_allinone  tex2lyx_sources)
  44         lyx_const_touched_files(_allinone_linked  LINKED_sources)
  45         add_executable(${_tex2lyx} ${_allinone_files} ${_allinone_linked_files} ${FILE_RC})
  46 endif()
  47
  48 target_link_libraries(${_tex2lyx}
  49         support
  50         ${Lyx_Boost_Libraries}
  51         ${QT_QTCORE_LIBRARY}
  52         ${QT_QTGUI_LIBRARY}
  53         ${LIBINTL_LIBRARIES}
  54         ${ICONV_LIBRARY})
  55
  56 if(WIN32)
  57         target_link_libraries(${_tex2lyx} shlwapi ole32 psapi)
  58 endif()
  59
  60 if(APPLE)
  61         target_link_libraries(${_tex2lyx} "-framework AppKit")
  62 endif()
  63
  64
  65 project_source_group("${GROUP_CODE}" tex2lyx_sources tex2lyx_headers)
  66
  67 add_subdirectory(test)
  68
  69 if(LYX_BUNDLE)
  70         install(TARGETS ${_tex2lyx}
  71                 RUNTIME DESTINATION bin
  72                 BUNDLE DESTINATION .)
  73 else()
  74         install(TARGETS ${_tex2lyx} DESTINATION bin)
  75 endif()
  76