src/tex2lyx/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6 #
   7
   8 project(${_tex2lyx})
   9
  10 # There is no header file lengthcommon.h
  11 set(LINKED_sources ${TOP_SRC_DIR}/src/lengthcommon.cpp)
  12 set(LINKED_headers)
  13
  14 foreach(_src graphics/GraphicsParams insets/ExternalTemplate
  15         insets/ExternalTransforms insets/InsetLayout Author Color Counters
  16         Encoding FloatList Floating FontInfo LaTeXPackages Layout
  17         LayoutFile LayoutModuleList Length Lexer ModuleList TextClass
  18         Spacing version)
  19         list(APPEND LINKED_sources ${TOP_SRC_DIR}/src/${_src}.cpp)
  20         list(APPEND LINKED_headers ${TOP_SRC_DIR}/src/${_src}.h)
  21 endforeach(_src)
  22
  23 file(GLOB tex2lyx_sources ${TOP_SRC_DIR}/src/tex2lyx/${LYX_CPP_FILES})
  24
  25 file(GLOB tex2lyx_headers ${TOP_SRC_DIR}/src/tex2lyx/${LYX_HPP_FILES})
  26
  27 include_directories(BEFORE
  28         ${TOP_SRC_DIR}/src/tex2lyx
  29         ${TOP_SRC_DIR}/src/support/minizip
  30         ${ZLIB_INCLUDE_DIR})
  31
  32 add_definitions(-DTEX2LYX)
  33
  34 if(WIN32)
  35         set(FILE_RC ${TOP_CMAKE_PATH}/lyx.rc)
  36         message(STATUS "Using icon defined in resource file: ${FILE_RC}")
  37 endif()
  38
  39 if(NOT LYX_MERGE_FILES)
  40         add_executable(${_tex2lyx} ${tex2lyx_sources} ${LINKED_sources} ${tex2lyx_headers} ${LINKED_headers}    ${FILE_RC})
  41 else()
  42         lyx_const_touched_files(_allinone  tex2lyx_sources)
  43         lyx_const_touched_files(_allinone_linked  LINKED_sources)
  44         add_executable(${_tex2lyx} ${_allinone_files} ${_allinone_linked_files} ${FILE_RC})
  45 endif()
  46
  47 target_link_libraries(${_tex2lyx}
  48         support
  49         ${Lyx_Boost_Libraries}
  50         ${QT_QTCORE_LIBRARY}
  51         ${QT_QTGUI_LIBRARY}
  52         ${intl_link}
  53         ${ICONV_LIBRARY})
  54
  55 add_dependencies(${_tex2lyx} lyx_version)
  56
  57 if(WIN32)
  58         target_link_libraries(${_tex2lyx} shlwapi ole32 psapi)
  59 endif()
  60
  61 if(APPLE)
  62         target_link_libraries(${_tex2lyx} "-framework AppKit")
  63 endif()
  64
  65
  66 project_source_group("${GROUP_CODE}" tex2lyx_sources tex2lyx_headers)
  67
  68 add_subdirectory(test)
  69
  70 if(LYX_BUNDLE)
  71         install(TARGETS ${_tex2lyx}
  72                 RUNTIME DESTINATION bin
  73                 BUNDLE DESTINATION .)
  74 else()
  75         install(TARGETS ${_tex2lyx} DESTINATION bin)
  76 endif()
  77