src/support/tests/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2012 Kornel Benko, kornel@lyx.org
   5 #
   6
   7 project(supporttest)
   8
   9 macro(sources _program)
  10         set(_tmplist)
  11         foreach(_tmp ${ARGN})
  12                 list(APPEND _tmplist "${TOP_SRC_DIR}/src/support/tests/${_tmp}")
  13         endforeach()
  14         set(${_program}_SOURCES ${_tmplist})
  15         add_executable(${_program} ${_tmplist})
  16         target_link_libraries(${_program} support
  17                 ${Lyx_Boost_Libraries} ${QT_QTGUI_LIBRARY} ${QT_QTCORE_LIBRARY}
  18                 ${ZLIB_LIBRARY} ${ICONV_LIBRARY})
  19                 lyx_target_link_libraries(${_program} Magic)
  20                 if(CYGWIN)
  21                         target_link_libraries(${_program} shlwapi)
  22                 endif()
  23 endmacro()
  24
  25 file(GLOB test_sources ${TOP_SRC_DIR}/src/support/tests/${LYX_CPP_FILES})
  26
  27 include_directories(
  28         ${TOP_SRC_DIR}/src/support/tests
  29         ${QT_INCLUDES}
  30         ${ICONV_INCLUDE_DIR}
  31         ${ZLIB_INCLUDE_DIR})
  32
  33
  34 set(check_PROGRAMS check_convert check_filetools check_lstrings check_trivstring)
  35
  36 file(MAKE_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/regfiles")
  37
  38 set(_depends)
  39 foreach(_src ${check_PROGRAMS})
  40         sources(${_src} ${_src}.cpp dummy_functions.cpp boost.cpp)
  41         string(REPLACE "check_" "" _srcx ${_src})
  42         set(src_data_file "${TOP_SRC_DIR}/src/support/tests/regfiles/${_srcx}")
  43         if (MSVC AND EXISTS "${src_data_file}.MSVC")
  44                 set(src_data_file "${src_data_file}.MSVC")
  45         endif()
  46         set(created_data_file "${CMAKE_CURRENT_BINARY_DIR}/regfiles/${_src}_data")
  47         add_test(NAME support/${_srcx}
  48           COMMAND ${CMAKE_COMMAND} -DCommand=$<TARGET_FILE:${_src}>
  49                                    -DInput=${src_data_file}
  50                                    -DOutput=${created_data_file}
  51                                    -P "${TOP_SRC_DIR}/src/support/tests/supporttest.cmake")
  52
  53         set_target_properties(${_src} PROPERTIES FOLDER "tests/support")
  54         add_dependencies(lyx_run_tests ${_src})
  55 endforeach()
  56
  57