src/frontends/qt4/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 project(frontend_qt)
   8
   9 file(GLOB frontends_qt_sources ${TOP_SRC_DIR}/src/frontends/qt4/${LYX_CPP_FILES})
  10 if (LYX_USE_FILEDIALOG MATCHES "NATIVE")
  11   set_property(SOURCE "${TOP_SRC_DIR}/src/frontends/qt4/FileDialog.cpp" PROPERTY COMPILE_FLAGS -DUSE_NATIVE_FILEDIALOG=1)
  12 endif()
  13 file(GLOB moc_files ${TOP_SRC_DIR}/src/frontends/qt4/${LYX_MOC_FILES})
  14
  15 list(REMOVE_ITEM frontends_qt_sources ${moc_files} .)
  16 list(REMOVE_ITEM frontends_qt_sources ${TOP_SRC_DIR}/src/frontends/qt4/liblyxqt4.cpp)
  17 list(REMOVE_ITEM frontends_qt_sources ${TOP_SRC_DIR}/src/frontends/qt4/Resources.cpp)
  18
  19 file(GLOB frontends_qt_headers ${TOP_SRC_DIR}/src/frontends/qt4/${LYX_HPP_FILES})
  20 file(GLOB frontend_qt_UI ${TOP_SRC_DIR}/src/frontends/qt4/ui/*.ui)
  21
  22 lyx_add_msvc_pch(frontends_qt4)
  23
  24 lyx_automoc(${frontends_qt_sources})
  25
  26 lyx_add_ui_files(frontends_qt_sources ui_files ${frontend_qt_UI})
  27
  28 set(resource_name ${CMAKE_CURRENT_BINARY_DIR}/Resources.qrc)
  29
  30 add_custom_command(
  31         OUTPUT  ${resource_name}
  32         COMMAND ${CMAKE_COMMAND}
  33                 -DIMAGES_DIR=${TOP_SRC_DIR}/lib/images
  34                 -DRESOURCE_NAME=${resource_name}
  35                 -DMAPPED_DIR=${TOP_SRC_DIR}/lib/
  36                 -DSUFFIX=${LYX_INSTALL_SUFFIX}
  37                 -P ${TOP_SCRIPT_PATH}/LyXCreateImagesResource.cmake
  38         )
  39
  40 qt_add_resources(resource_files ${resource_name})
  41
  42 add_definitions(-DQT_GENUINE_STR -DLYX_BUILD_QT_FRONTEND)
  43
  44 include_directories(
  45         ${TOP_SRC_DIR}/src/frontends/qt4
  46         ${QT_INCLUDES}
  47         ${CMAKE_CURRENT_BINARY_DIR})
  48
  49 if(LYX_MERGE_FILES)
  50         lyx_const_touched_files(_allinone frontends_qt_sources)
  51         set(depends_moc_uic ${frontends_qt_headers} ${ui_files})
  52         set_source_files_properties(_allinone_const.C PROPERTIES OBJECT_DEPENDS "${depends_moc_uic}")
  53         set_source_files_properties(_allinone_touched.C PROPERTIES OBJECT_DEPENDS "${depends_moc_uic}")
  54         add_library(frontend_qt ${library_type}
  55                 ${_allinone_files} ${frontends_qt_headers} ${ui_files} ${resource_files})
  56 else()
  57         add_library(frontend_qt ${library_type} ${frontends_qt_sources} ${frontends_qt_headers} ${ui_files} ${resource_files})
  58 endif()
  59 set_target_properties(frontend_qt PROPERTIES FOLDER "applications/LyX")
  60
  61 if(Qt5Core_FOUND AND APPLE)
  62        qt_use_modules(frontend_qt Core Gui Widgets Concurrent Svg MacExtras)
  63 else()
  64        if (Qt5WinExtras_FOUND)
  65            qt_use_modules(frontend_qt Core Gui Widgets Concurrent Svg WinExtras)
  66        else()
  67            qt_use_modules(frontend_qt Core Gui Widgets Concurrent Svg)
  68        endif()
  69 endif()
  70 target_link_libraries(frontend_qt
  71         frontends
  72         ${QT_QTCORE_LIBRARY}
  73         ${QT_QTGUI_LIBRARY})
  74
  75 lyx_add_gcc_pch(frontend_qt)
  76
  77 if(WIN32)
  78         target_link_libraries(frontend_qt gdi32)
  79 endif()
  80
  81 project_source_group("${GROUP_CODE}" frontends_qt_sources frontends_qt_headers)
  82
  83 source_group("Uic files" FILES ${frontend_qt_UI})
  84