src/frontends/qt4/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 project(frontend_qt4)
   8
   9 file(GLOB frontends_qt4_sources ${TOP_SRC_DIR}/src/frontends/qt4/${LYX_CPP_FILES})
  10 file(GLOB moc_files ${TOP_SRC_DIR}/src/frontends/qt4/${LYX_MOC_FILES})
  11
  12 list(REMOVE_ITEM frontends_qt4_sources ${moc_files} .)
  13 list(REMOVE_ITEM frontends_qt4_sources ${TOP_SRC_DIR}/src/frontends/qt4/liblyxqt4.cpp)
  14 list(REMOVE_ITEM frontends_qt4_sources ${TOP_SRC_DIR}/src/frontends/qt4/Resources.cpp)
  15
  16 file(GLOB frontends_qt4_headers ${TOP_SRC_DIR}/src/frontends/qt4/${LYX_HPP_FILES})
  17 file(GLOB frontend_qt4_UI ${TOP_SRC_DIR}/src/frontends/qt4/ui/*.ui)
  18
  19 lyx_add_msvc_pch(frontends_qt4)
  20
  21 lyx_automoc(${frontends_qt4_sources})
  22
  23 lyx_add_ui_files(frontends_qt4_sources ui_files ${frontend_qt4_UI})
  24
  25 file(GLOB_RECURSE frontend_qt4_images_png      ${TOP_SRC_DIR}/lib/images/*.png)
  26 file(GLOB_RECURSE frontend_qt4_images_gif      ${TOP_SRC_DIR}/lib/images/*.gif)
  27 set(resource_name ${CMAKE_CURRENT_BINARY_DIR}/Resources.qrc)
  28 set(frontend_qt4_images ${frontend_qt4_images_png} ${frontend_qt4_images_gif})
  29 lyx_qt_resources_file(${resource_name} "${TOP_SRC_DIR}/lib/" frontend_qt4_images)
  30 qt4_add_resources(resource_files ${resource_name})
  31
  32
  33 add_definitions(-DQT_GENUINE_STR -DLYX_BUILD_QT4_FRONTEND)
  34
  35 include_directories(
  36         ${TOP_SRC_DIR}/src/frontends/qt4
  37         ${QT_INCLUDES}
  38         ${CMAKE_CURRENT_BINARY_DIR})
  39
  40 if (LYX_DEVEL_VERSION)
  41         add_definitions(-DDEVEL_VERSION)
  42 endif()
  43
  44 if(LYX_MERGE_FILES)
  45         lyx_const_touched_files(_allinone frontends_qt4_sources)
  46         set(depends_moc_uic ${frontends_qt4_headers} ${ui_files})
  47         set_source_files_properties(_allinone_const.C PROPERTIES OBJECT_DEPENDS "${depends_moc_uic}")
  48         set_source_files_properties(_allinone_touched.C PROPERTIES OBJECT_DEPENDS "${depends_moc_uic}")
  49         add_library(frontend_qt4 ${library_type}
  50                 ${_allinone_files} ${frontends_qt4_headers} ${ui_files} ${resource_files})
  51 else()
  52         add_library(frontend_qt4 ${library_type} ${frontends_qt4_sources} ${frontends_qt4_headers} ${ui_files} ${resource_files})
  53 endif()
  54
  55
  56 target_link_libraries(frontend_qt4
  57         frontends
  58         ${QT_QTCORE_LIBRARY}
  59         ${QT_QTGUI_LIBRARY})
  60
  61 lyx_add_gcc_pch(frontend_qt4)
  62
  63 if(WIN32)
  64         target_link_libraries(frontend_qt4 Gdi32)
  65 endif()
  66
  67 project_source_group("${GROUP_CODE}" frontends_qt4_sources frontends_qt4_headers)
  68
  69 source_group("Uic files" FILES ${frontend_qt4_UI})
  70