src/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
   8 project(${_lyx})
   9
  10 include_directories(${TOP_SRC_DIR}/src)
  11
  12 add_subdirectory(frontends)
  13 add_subdirectory(graphics)
  14 add_subdirectory(insets)
  15 add_subdirectory(mathed)
  16 add_subdirectory(support)
  17 add_subdirectory(tex2lyx)
  18 if (UNIX)
  19         add_subdirectory(client)
  20 endif()
  21
  22 file(GLOB lyx_sources ${TOP_SRC_DIR}/src/${LYX_CPP_FILES})
  23 file(GLOB moc_files ${TOP_SRC_DIR}/src/${LYX_MOC_FILES})
  24 list(REMOVE_ITEM  lyx_sources ${moc_files} .)
  25 file(GLOB lyx_headers ${TOP_SRC_DIR}/src/${LYX_HPP_FILES})
  26
  27 list(REMOVE_ITEM lyx_sources
  28         ${TOP_SRC_DIR}/src/Variables.cpp
  29         ${TOP_SRC_DIR}/src/Section.cpp
  30         ${TOP_SRC_DIR}/src/lyxcore.cpp
  31         ${TOP_SRC_DIR}/src/lyxinsets.cpp
  32         ${TOP_SRC_DIR}/src/lyxmathed.cpp)
  33
  34 list(REMOVE_ITEM lyx_headers
  35         ${TOP_SRC_DIR}/src/Variables.h
  36         ${TOP_SRC_DIR}/src/Section.h)
  37
  38 if(NOT APPLE)
  39         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/AppleSpellChecker.cpp)
  40         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/AppleSpellChecker.h)
  41 endif()
  42
  43 if(NOT ASPELL_FOUND)
  44         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/AspellChecker.cpp)
  45         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/AspellChecker.h)
  46 else()
  47         set(dont_merge ${dont_merge} ${TOP_SRC_DIR}/src/AspellChecker.cpp)
  48 endif()
  49
  50 if(NOT ENCHANT_FOUND)
  51         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/EnchantChecker.cpp)
  52         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/EnchantChecker.h)
  53 else()
  54         set(dont_merge ${dont_merge} ${TOP_SRC_DIR}/src/EnchantChecker.cpp)
  55 endif()
  56
  57 if(NOT HUNSPELL_FOUND)
  58         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/HunspellChecker.cpp)
  59         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/HunspellChecker.h)
  60 else()
  61         set(dont_merge ${dont_merge} ${TOP_SRC_DIR}/src/HunspellChecker.cpp)
  62 endif()
  63
  64
  65 lyx_automoc(${TOP_SRC_DIR}/src/Compare.cpp)
  66 if(WIN32)
  67         lyx_automoc(${TOP_SRC_DIR}/src/Server.cpp)
  68 endif()
  69
  70 include_directories(${CMAKE_CURRENT_BINARY_DIR}
  71         ${ZLIB_INCLUDE_DIR} ${QT_INCLUDES})
  72
  73 lyx_add_msvc_pch(lyx)
  74
  75 if (LYX_MERGE_FILES)
  76         if(dont_merge)
  77                 list(REMOVE_ITEM lyx_sources ${dont_merge})
  78         endif()
  79         lyx_const_touched_files(_allinone lyx_sources)
  80         set(lyx_sources ${_allinone_files} ${dont_merge})
  81 endif()
  82
  83 if (LYX_VLD)
  84         configure_file(${vld_path}/vld.ini ${CMAKE_CURRENT_BINARY_DIR}/vld.ini COPYONLY)
  85         set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/memory_leak_report.txt PROPERTIES GENERATED TRUE)
  86         set(vld_files ${CMAKE_CURRENT_BINARY_DIR}/vld.ini ${CMAKE_CURRENT_BINARY_DIR}/memory_leak_report.txt)
  87         lyx_add_info_files(VLD ${vld_files})
  88 endif()
  89
  90 if(WIN32)
  91         set(FILE_RC ${TOP_SRC_DIR}/development/cmake/lyx.rc)
  92         message(STATUS "Using icon defined in resource file: ${FILE_RC}")
  93 endif()
  94
  95 lyx_find_info_files(LyXInfoFiles ${TOP_SRC_DIR}/*)
  96 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/*.txt)
  97 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/*.cmake)
  98 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/*.h)
  99 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/*.msvc)
 100 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/modules/*)
 101 lyx_find_info_files(LyXUiFiles ${TOP_SRC_DIR}/lib/ui/*)
 102
 103 if (APPLE AND LYX_BUNDLE)
 104         include(../Install)
 105 endif()
 106
 107 add_executable(${_lyx}
 108         ${WIN32_CONSOLE}
 109         ${LYX_BUILD_BUNDLE}
 110         ${lyx_sources}
 111         ${lyx_headers}
 112         ${vld_files}
 113         ${FILE_RC}
 114         ${lyx_info_files}
 115         ${lyx_cmake_files}
 116         ${OSX_BUNDLE_FILES}
 117 )
 118
 119 add_dependencies(${_lyx} lyx_version)
 120
 121 lyx_add_gcc_pch(${_lyx})
 122
 123 target_link_libraries(${_lyx}
 124         mathed
 125         insets
 126         frontends
 127         frontend_qt4
 128         graphics
 129         support
 130         ${intl_link}
 131         ${ICONV_LIBRARY}
 132         ${QT_QTMAIN_LIBRARY}
 133         ${vld_dll})
 134
 135 if(HUNSPELL_FOUND)
 136         target_link_libraries(${_lyx} ${HUNSPELL_LIBRARY})
 137 endif()
 138 if(ASPELL_FOUND)
 139         target_link_libraries(${_lyx} ${ASPELL_LIBRARY})
 140 endif()
 141 if(ENCHANT_FOUND)
 142         target_link_libraries(${_lyx} ${ENCHANT_LIBRARY})
 143 endif()
 144 if(Magic_FOUND)
 145         target_link_libraries(${_lyx} ${Magic_LIBRARY})
 146 endif()
 147
 148 if(APPLE)
 149         target_link_libraries(${_lyx} "-bind_at_load")
 150         if(LYX_COCOA)
 151                 target_link_libraries(${_lyx} "-framework Cocoa")
 152         else()
 153                 target_link_libraries(${_lyx} "-framework AppKit")
 154         endif()
 155 endif()
 156
 157 if(MINGW)
 158         target_link_libraries(${_lyx} ole32)
 159 endif()
 160
 161 project_source_group("${GROUP_CODE}" lyx_sources lyx_headers)
 162
 163
 164 install(TARGETS ${_lyx}
 165         RUNTIME DESTINATION bin
 166         BUNDLE DESTINATION .)
 167
 168 if(LYX_BUNDLE)
 169         if(NOT APPLE)
 170                 set(installed_lyx ${CMAKE_INSTALL_PREFIX}/bin/${_lyx}${CMAKE_EXECUTABLE_SUFFIX})
 171         else()
 172                 set_target_properties(${_lyx} PROPERTIES MACOSX_BUNDLE_INFO_PLIST "${CMAKE_CURRENT_BINARY_DIR}/../Info.plist")
 173                 set(installed_lyx ${CMAKE_INSTALL_PREFIX}/${_lyx}.app)
 174                 set(LYX_BUNDLE_PROPERTY_MODE "ON")
 175                 include("../Install")
 176         endif()
 177         install(CODE "include(BundleUtilities)
 178                         fixup_bundle(\"${installed_lyx}\" \"\" \"\") " COMPONENT RUNTIME)
 179 endif()
 180