src/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 set(_lyx ${PACKAGE_BASE}${PROGRAM_SUFFIX})
   8 project(${_lyx})
   9
  10 include_directories(${TOP_SRC_DIR}/src)
  11
  12 add_subdirectory(frontends)
  13 add_subdirectory(graphics)
  14 add_subdirectory(insets)
  15 add_subdirectory(mathed)
  16 add_subdirectory(support)
  17 add_subdirectory(tex2lyx)
  18 if (UNIX)
  19         add_subdirectory(client)
  20 endif()
  21
  22 file(GLOB lyx_sources ${TOP_SRC_DIR}/src/${LYX_CPP_FILES})
  23 file(GLOB moc_files ${TOP_SRC_DIR}/src/${LYX_MOC_FILES})
  24 list(REMOVE_ITEM  lyx_sources ${moc_files} .)
  25 file(GLOB lyx_headers ${TOP_SRC_DIR}/src/${LYX_HPP_FILES})
  26
  27 list(REMOVE_ITEM lyx_sources
  28         ${TOP_SRC_DIR}/src/Variables.cpp
  29         ${TOP_SRC_DIR}/src/Section.cpp
  30         ${TOP_SRC_DIR}/src/lyxcore.cpp
  31         ${TOP_SRC_DIR}/src/lyxinsets.cpp
  32         ${TOP_SRC_DIR}/src/lyxmathed.cpp)
  33
  34 list(REMOVE_ITEM lyx_headers
  35         ${TOP_SRC_DIR}/src/Variables.h
  36         ${TOP_SRC_DIR}/src/Section.h)
  37
  38 if(NOT APPLE)
  39         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/AppleSpellChecker.cpp)
  40         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/AppleSpellChecker.h)
  41 endif()
  42
  43 if(NOT ASPELL_FOUND)
  44         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/AspellChecker.cpp)
  45         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/AspellChecker.h)
  46 else()
  47         set(dont_merge ${dont_merge} ${TOP_SRC_DIR}/src/AspellChecker.cpp)
  48 endif()
  49
  50 if(NOT ENCHANT_FOUND)
  51         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/EnchantChecker.cpp)
  52         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/EnchantChecker.h)
  53 else()
  54         set(dont_merge ${dont_merge} ${TOP_SRC_DIR}/src/EnchantChecker.cpp)
  55 endif()
  56
  57 if(NOT HUNSPELL_FOUND)
  58         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/HunspellChecker.cpp)
  59         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/HunspellChecker.h)
  60 else()
  61         set(dont_merge ${dont_merge} ${TOP_SRC_DIR}/src/HunspellChecker.cpp)
  62 endif()
  63
  64
  65 lyx_automoc(${TOP_SRC_DIR}/src/Compare.cpp)
  66 if(WIN32)
  67         lyx_automoc(${TOP_SRC_DIR}/src/Server.cpp)
  68 endif()
  69
  70 include_directories(${CMAKE_CURRENT_BINARY_DIR}
  71         ${ZLIB_INCLUDE_DIR} ${QT_INCLUDES})
  72
  73 lyx_add_msvc_pch(lyx)
  74
  75 if (LYX_DEVEL_VERSION)
  76         add_definitions(-DDEVEL_VERSION)
  77 endif()
  78
  79 if(APPLE)
  80         list(APPEND dont_merge ${TOP_SRC_DIR}/src/TexRow.cpp)
  81 endif()
  82
  83
  84 if (LYX_MERGE_FILES)
  85         if(dont_merge)
  86                 list(REMOVE_ITEM lyx_sources ${dont_merge})
  87         endif()
  88         lyx_const_touched_files(_allinone lyx_sources)
  89         set(lyx_sources ${_allinone_files} ${dont_merge})
  90 endif()
  91
  92 if (LYX_VLD)
  93         configure_file(${vld_path}/vld.ini ${CMAKE_CURRENT_BINARY_DIR}/vld.ini COPYONLY)
  94         configure_file(${vld_path}/vld.ini ${CMAKE_CURRENT_BINARY_DIR}/memory_leak_report.txt COPYONLY)
  95         set(vld_files ${CMAKE_CURRENT_BINARY_DIR}/vld.ini ${CMAKE_CURRENT_BINARY_DIR}/memory_leak_report.txt)
  96 endif()
  97
  98 if(WIN32)
  99         set(FILE_RC ${TOP_SRC_DIR}/development/cmake/lyx.rc)
 100         message(STATUS "Using icon defined in resource file: ${FILE_RC}")
 101 endif()
 102
 103 lyx_find_info_files(LyXInfoFiles ${TOP_SRC_DIR}/*)
 104 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/*.txt)
 105 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/*.cmake)
 106 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/*.h)
 107 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/*.msvc)
 108 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/modules/*)
 109 lyx_find_info_files(LyXUiFiles ${TOP_SRC_DIR}/lib/ui/*)
 110
 111 add_executable(${_lyx}
 112         ${WIN32_CONSOLE}
 113         ${lyx_sources}
 114         ${lyx_headers}
 115         ${vld_files}
 116         ${FILE_RC}
 117         ${lyx_info_files}
 118         ${lyx_cmake_files}
 119 )
 120
 121 lyx_add_gcc_pch(${_lyx})
 122
 123 target_link_libraries(${_lyx}
 124         mathed
 125         insets
 126         frontends
 127         frontend_qt4
 128         graphics
 129         support
 130         ${LIBINTL_LIBRARIES}
 131         ${ICONV_LIBRARY}
 132         ${QT_QTMAIN_LIBRARY}
 133         ${vld_dll})
 134
 135
 136 if(HUNSPELL_FOUND)
 137         target_link_libraries(${_lyx} ${HUNSPELL_LIBRARY})
 138 endif()
 139 if(ASPELL_FOUND)
 140         target_link_libraries(${_lyx} ${ASPELL_LIBRARY})
 141 endif()
 142 if(ENCHANT_FOUND)
 143         target_link_libraries(${_lyx} ${ENCHANT_LIBRARY})
 144 endif()
 145
 146 if(APPLE)
 147         target_link_libraries(${_lyx} "-bind_at_load")
 148         target_link_libraries(${_lyx} "-framework Carbon")
 149 endif()
 150
 151 if(MINGW)
 152         target_link_libraries(${_lyx} ole32)
 153 endif()
 154
 155 project_source_group("${GROUP_CODE}" lyx_sources lyx_headers)
 156
 157 install(TARGETS ${_lyx} DESTINATION bin)
 158