src/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 set(_lyx "${PACKAGE_BASE}${PROGRAM_SUFFIX}")
   8 project(${_lyx})
   9
  10 include_directories(${TOP_SRC_DIR}/src)
  11
  12 add_subdirectory(frontends)
  13 add_subdirectory(graphics)
  14 add_subdirectory(insets)
  15 add_subdirectory(mathed)
  16 add_subdirectory(support)
  17 add_subdirectory(tex2lyx)
  18 if (UNIX)
  19         add_subdirectory(client)
  20 endif()
  21
  22 file(GLOB lyx_sources ${TOP_SRC_DIR}/src/${LYX_CPP_FILES})
  23 file(GLOB moc_files ${TOP_SRC_DIR}/src/${LYX_MOC_FILES})
  24 list(REMOVE_ITEM  lyx_sources ${moc_files} .)
  25 file(GLOB lyx_headers ${TOP_SRC_DIR}/src/${LYX_HPP_FILES})
  26
  27 list(REMOVE_ITEM lyx_sources
  28         ${TOP_SRC_DIR}/src/Variables.cpp
  29         ${TOP_SRC_DIR}/src/Section.cpp
  30         ${TOP_SRC_DIR}/src/lyxcore.cpp
  31         ${TOP_SRC_DIR}/src/lyxinsets.cpp
  32         ${TOP_SRC_DIR}/src/lyxmathed.cpp)
  33
  34 list(REMOVE_ITEM lyx_headers
  35         ${TOP_SRC_DIR}/src/Variables.h
  36         ${TOP_SRC_DIR}/src/Section.h)
  37
  38 if(NOT APPLE)
  39         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/AppleSpellChecker.cpp)
  40         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/AppleSpellChecker.h)
  41 endif()
  42
  43 if(NOT ASPELL_FOUND)
  44         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/AspellChecker.cpp)
  45         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/AspellChecker.h)
  46 else()
  47         set(dont_merge ${dont_merge} ${TOP_SRC_DIR}/src/AspellChecker.cpp)
  48 endif()
  49
  50 if(NOT ENCHANT_FOUND)
  51         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/EnchantChecker.cpp)
  52         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/EnchantChecker.h)
  53 else()
  54         set(dont_merge ${dont_merge} ${TOP_SRC_DIR}/src/EnchantChecker.cpp)
  55 endif()
  56
  57 if(NOT HUNSPELL_FOUND)
  58         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/HunspellChecker.cpp)
  59         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/HunspellChecker.h)
  60 else()
  61         set(dont_merge ${dont_merge} ${TOP_SRC_DIR}/src/HunspellChecker.cpp)
  62 endif()
  63
  64
  65 lyx_automoc(${TOP_SRC_DIR}/src/Compare.cpp)
  66 if(WIN32)
  67         lyx_automoc(${TOP_SRC_DIR}/src/Server.cpp)
  68 endif()
  69
  70 include_directories(${CMAKE_CURRENT_BINARY_DIR}
  71         ${ZLIB_INCLUDE_DIR} ${QT_INCLUDES})
  72
  73 lyx_add_msvc_pch(lyx)
  74
  75 if (LYX_MERGE_FILES)
  76         if(dont_merge)
  77                 list(REMOVE_ITEM lyx_sources ${dont_merge})
  78         endif()
  79         lyx_const_touched_files(_allinone lyx_sources)
  80         set(lyx_sources ${_allinone_files} ${dont_merge})
  81 endif()
  82
  83 if (LYX_VLD)
  84         configure_file(${vld_path}/vld.ini ${CMAKE_CURRENT_BINARY_DIR}/vld.ini COPYONLY)
  85         set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/memory_leak_report.txt PROPERTIES GENERATED TRUE)
  86         set(vld_files ${CMAKE_CURRENT_BINARY_DIR}/vld.ini ${CMAKE_CURRENT_BINARY_DIR}/memory_leak_report.txt)
  87         lyx_add_info_files(VLD ${vld_files})
  88 endif()
  89
  90 if(WIN32)
  91         set(FILE_RC ${TOP_SRC_DIR}/development/cmake/lyx.rc)
  92         message(STATUS "Using icon defined in resource file: ${FILE_RC}")
  93 endif()
  94
  95 lyx_find_info_files(LyXInfoFiles ${TOP_SRC_DIR}/*)
  96 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/*.txt)
  97 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/*.cmake)
  98 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/*.h)
  99 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/*.msvc)
 100 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/modules/*)
 101 lyx_find_info_files(LyXUiFiles ${TOP_SRC_DIR}/lib/ui/*)
 102
 103 if (APPLE AND LYX_BUNDLE)
 104         include(../Install)
 105 endif()
 106
 107 add_executable(${_lyx}
 108         ${WIN32_CONSOLE}
 109         ${LYX_BUILD_BUNDLE}
 110         ${lyx_sources}
 111         ${lyx_headers}
 112         ${vld_files}
 113         ${FILE_RC}
 114         ${lyx_info_files}
 115         ${lyx_cmake_files}
 116         ${OSX_BUNDLE_FILES}
 117 )
 118
 119
 120 lyx_add_gcc_pch(${_lyx})
 121
 122 target_link_libraries(${_lyx}
 123         mathed
 124         insets
 125         frontends
 126         frontend_qt4
 127         graphics
 128         support
 129         ${intl_link}
 130         ${ICONV_LIBRARY}
 131         ${QT_QTMAIN_LIBRARY}
 132         ${vld_dll})
 133
 134 if(HUNSPELL_FOUND)
 135         target_link_libraries(${_lyx} ${HUNSPELL_LIBRARY})
 136 endif()
 137 if(ASPELL_FOUND)
 138         target_link_libraries(${_lyx} ${ASPELL_LIBRARY})
 139 endif()
 140 if(ENCHANT_FOUND)
 141         target_link_libraries(${_lyx} ${ENCHANT_LIBRARY})
 142 endif()
 143 if(Magic_FOUND)
 144         target_link_libraries(${_lyx} ${Magic_LIBRARY})
 145 endif()
 146
 147 if(APPLE)
 148         target_link_libraries(${_lyx} "-bind_at_load")
 149         if(LYX_COCOA)
 150                 target_link_libraries(${_lyx} "-framework Cocoa")
 151         else()
 152                 target_link_libraries(${_lyx} "-framework AppKit")
 153         endif()
 154 endif()
 155
 156 if(MINGW)
 157         target_link_libraries(${_lyx} ole32)
 158 endif()
 159
 160 project_source_group("${GROUP_CODE}" lyx_sources lyx_headers)
 161
 162
 163 install(TARGETS ${_lyx}
 164         RUNTIME DESTINATION bin
 165         BUNDLE DESTINATION .)
 166
 167 if(LYX_BUNDLE)
 168         if(NOT APPLE)
 169                 set(installed_lyx ${CMAKE_INSTALL_PREFIX}/bin/${_lyx}${CMAKE_EXECUTABLE_SUFFIX})
 170         else()
 171                 set_target_properties(${_lyx} PROPERTIES MACOSX_BUNDLE_INFO_PLIST "${CMAKE_CURRENT_BINARY_DIR}/../Info.plist")
 172                 set(installed_lyx ${CMAKE_INSTALL_PREFIX}/${_lyx}.app)
 173                 set(LYX_BUNDLE_PROPERTY_MODE "ON")
 174                 include("../Install")
 175         endif()
 176         install(CODE "include(BundleUtilities)
 177                         fixup_bundle(\"${installed_lyx}\" \"\" \"\") " COMPONENT RUNTIME)
 178 endif()
 179