src/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 project(${_lyx})
   8
   9 include_directories(${TOP_SRC_DIR}/src)
  10
  11 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  12 set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
  13
  14 add_subdirectory(frontends)
  15 add_subdirectory(graphics)
  16 add_subdirectory(insets)
  17 add_subdirectory(mathed)
  18 add_subdirectory(support)
  19 add_subdirectory(tex2lyx)
  20 if (UNIX)
  21         add_subdirectory(client)
  22 endif()
  23
  24 file(GLOB lyx_sources ${TOP_SRC_DIR}/src/${LYX_CPP_FILES})
  25 file(GLOB moc_files ${TOP_SRC_DIR}/src/${LYX_MOC_FILES})
  26 list(REMOVE_ITEM  lyx_sources ${moc_files} .)
  27 file(GLOB lyx_headers ${TOP_SRC_DIR}/src/${LYX_HPP_FILES})
  28
  29 list(REMOVE_ITEM lyx_sources
  30         ${TOP_SRC_DIR}/src/Variables.cpp
  31         ${TOP_SRC_DIR}/src/Section.cpp
  32         ${TOP_SRC_DIR}/src/lyxcore.cpp
  33         ${TOP_SRC_DIR}/src/lyxinsets.cpp
  34         ${TOP_SRC_DIR}/src/lyxmathed.cpp)
  35
  36 list(REMOVE_ITEM lyx_headers
  37         ${TOP_SRC_DIR}/src/Variables.h
  38         ${TOP_SRC_DIR}/src/Section.h)
  39
  40 if(NOT APPLE)
  41         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/AppleSpellChecker.cpp)
  42         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/AppleSpellChecker.h)
  43 endif()
  44
  45 if(NOT ASPELL_FOUND)
  46         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/AspellChecker.cpp)
  47         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/AspellChecker.h)
  48 else()
  49         set(dont_merge ${dont_merge} ${TOP_SRC_DIR}/src/AspellChecker.cpp)
  50 endif()
  51
  52 if(NOT ENCHANT_FOUND)
  53         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/EnchantChecker.cpp)
  54         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/EnchantChecker.h)
  55 else()
  56         set(dont_merge ${dont_merge} ${TOP_SRC_DIR}/src/EnchantChecker.cpp)
  57 endif()
  58
  59 if(NOT HUNSPELL_FOUND)
  60         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/HunspellChecker.cpp)
  61         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/HunspellChecker.h)
  62 else()
  63         set(dont_merge ${dont_merge} ${TOP_SRC_DIR}/src/HunspellChecker.cpp)
  64 endif()
  65
  66
  67 lyx_automoc(${TOP_SRC_DIR}/src/Compare.cpp)
  68 if(WIN32)
  69         lyx_automoc(${TOP_SRC_DIR}/src/Server.cpp)
  70 endif()
  71
  72 include_directories(${CMAKE_CURRENT_BINARY_DIR}
  73         ${ZLIB_INCLUDE_DIR} ${QT_INCLUDES})
  74
  75 lyx_add_msvc_pch(lyx)
  76
  77 if (LYX_MERGE_FILES)
  78         if(dont_merge)
  79                 list(REMOVE_ITEM lyx_sources ${dont_merge})
  80         endif()
  81         lyx_const_touched_files(_allinone lyx_sources)
  82         set(lyx_sources ${_allinone_files} ${dont_merge})
  83 endif()
  84
  85 if (LYX_VLD)
  86         configure_file(${vld_path}/vld.ini ${CMAKE_CURRENT_BINARY_DIR}/vld.ini COPYONLY)
  87         set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/memory_leak_report.txt PROPERTIES GENERATED TRUE)
  88         set(vld_files ${CMAKE_CURRENT_BINARY_DIR}/vld.ini ${CMAKE_CURRENT_BINARY_DIR}/memory_leak_report.txt)
  89         lyx_add_info_files(VLD ${vld_files})
  90 endif()
  91
  92 if(WIN32)
  93         set(FILE_RC ${TOP_CMAKE_PATH}/lyx.rc)
  94         message(STATUS "Using icon defined in resource file: ${FILE_RC}")
  95 endif()
  96
  97 lyx_find_info_files(LyXInfoFiles ${TOP_SRC_DIR}/*)
  98 lyx_find_info_files(LyXCMakeFiles ${TOP_CMAKE_PATH}/*.txt)
  99 lyx_find_info_files(LyXCMakeFiles ${TOP_CMAKE_PATH}/*.cmake)
 100 lyx_find_info_files(LyXCMakeFiles ${TOP_CMAKE_PATH}/*.h)
 101 lyx_find_info_files(LyXCMakeFiles ${TOP_CMAKE_PATH}/*.msvc)
 102 lyx_find_info_files(LyXCMakeFiles ${TOP_MODULE_PATH}/*)
 103 lyx_find_info_files(LyXCMakeFiles ${TOP_SCRIPT_PATH}/*)
 104 lyx_find_info_files(LyXUiFiles ${TOP_SRC_DIR}/lib/ui/*)
 105
 106 if (APPLE AND LYX_BUNDLE)
 107         include(../Install)
 108 endif()
 109
 110 add_executable(${_lyx}
 111         ${WIN32_CONSOLE}
 112         ${LYX_BUILD_BUNDLE}
 113         ${lyx_sources}
 114         ${lyx_headers}
 115         ${vld_files}
 116         ${FILE_RC}
 117         ${lyx_info_files}
 118         ${lyx_cmake_files}
 119         ${OSX_BUNDLE_FILES}
 120 )
 121
 122 add_dependencies(${_lyx} lyx_version)
 123
 124 set_target_properties(${_lyx} PROPERTIES FOLDER "applications/LyX")
 125
 126 qt_use_modules(${_lyx} Core Gui)
 127
 128 lyx_add_gcc_pch(${_lyx})
 129
 130 target_link_libraries(${_lyx}
 131         mathed
 132         insets
 133         frontends
 134         frontend_qt4
 135         graphics
 136         support
 137         ${intl_link}
 138         ${ICONV_LIBRARY}
 139         ${QT_QTMAIN_LIBRARY}
 140         ${vld_dll})
 141
 142 if(HUNSPELL_FOUND)
 143         target_link_libraries(${_lyx} ${HUNSPELL_LIBRARY})
 144 endif()
 145 if(ASPELL_FOUND)
 146         target_link_libraries(${_lyx} ${ASPELL_LIBRARY})
 147 endif()
 148 if(ENCHANT_FOUND)
 149         target_link_libraries(${_lyx} ${ENCHANT_LIBRARY})
 150 endif()
 151 if(Magic_FOUND)
 152         target_link_libraries(${_lyx} ${Magic_LIBRARY})
 153 endif()
 154
 155 if(APPLE)
 156         target_link_libraries(${_lyx} "-bind_at_load")
 157         if(LYX_COCOA)
 158                 target_link_libraries(${_lyx} "-framework Cocoa")
 159         else()
 160                 target_link_libraries(${_lyx} "-framework AppKit")
 161         endif()
 162 endif()
 163
 164 if(MINGW)
 165         target_link_libraries(${_lyx} ole32)
 166 endif()
 167
 168 project_source_group("${GROUP_CODE}" lyx_sources lyx_headers)
 169
 170
 171 install(TARGETS ${_lyx}
 172         RUNTIME DESTINATION bin
 173         BUNDLE DESTINATION .)
 174
 175 if(LYX_BUNDLE)
 176         if(NOT APPLE)
 177                 set(installed_lyx ${CMAKE_INSTALL_PREFIX}/bin/${_lyx}${CMAKE_EXECUTABLE_SUFFIX})
 178         else()
 179                 set_target_properties(${_lyx} PROPERTIES MACOSX_BUNDLE_INFO_PLIST "${CMAKE_CURRENT_BINARY_DIR}/../Info.plist")
 180                 set(installed_lyx ${CMAKE_INSTALL_PREFIX}/${_lyx}.app)
 181                 set(LYX_BUNDLE_PROPERTY_MODE "ON")
 182                 include("../Install")
 183         endif()
 184         install(CODE "include(BundleUtilities)
 185                         fixup_bundle(\"${installed_lyx}\" \"\" \"\") " COMPONENT RUNTIME)
 186 endif()
 187