src/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 set(_lyx ${PACKAGE_BASE}${PROGRAM_SUFFIX})
   8 project(${_lyx})
   9
  10 include_directories(${TOP_SRC_DIR}/src)
  11
  12 add_subdirectory(frontends)
  13 add_subdirectory(graphics)
  14 add_subdirectory(insets)
  15 add_subdirectory(mathed)
  16 add_subdirectory(support)
  17 add_subdirectory(tex2lyx)
  18 if (UNIX)
  19         add_subdirectory(client)
  20 endif()
  21
  22 file(GLOB lyx_sources ${TOP_SRC_DIR}/src/${LYX_CPP_FILES})
  23 file(GLOB moc_files ${TOP_SRC_DIR}/src/${LYX_MOC_FILES})
  24 list(REMOVE_ITEM  lyx_sources ${moc_files} .)
  25 file(GLOB lyx_headers ${TOP_SRC_DIR}/src/${LYX_HPP_FILES})
  26
  27 list(REMOVE_ITEM lyx_sources
  28         ${TOP_SRC_DIR}/src/Variables.cpp
  29         ${TOP_SRC_DIR}/src/Section.cpp
  30         ${TOP_SRC_DIR}/src/lyxcore.cpp
  31         ${TOP_SRC_DIR}/src/lyxinsets.cpp
  32         ${TOP_SRC_DIR}/src/lyxmathed.cpp)
  33
  34 list(REMOVE_ITEM lyx_headers
  35         ${TOP_SRC_DIR}/src/Variables.h
  36         ${TOP_SRC_DIR}/src/Section.h)
  37
  38 if(NOT APPLE)
  39         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/AppleSpellChecker.cpp)
  40         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/AppleSpellChecker.h)
  41 endif()
  42
  43 if(NOT ASPELL_FOUND)
  44         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/AspellChecker.cpp)
  45         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/AspellChecker.h)
  46 else()
  47         set(dont_merge ${dont_merge} ${TOP_SRC_DIR}/src/AspellChecker.cpp)
  48 endif()
  49
  50 if(NOT ENCHANT_FOUND)
  51         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/EnchantChecker.cpp)
  52         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/EnchantChecker.h)
  53 else()
  54         set(dont_merge ${dont_merge} ${TOP_SRC_DIR}/src/EnchantChecker.cpp)
  55 endif()
  56
  57 if(NOT HUNSPELL_FOUND)
  58         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/HunspellChecker.cpp)
  59         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/HunspellChecker.h)
  60 else()
  61         set(dont_merge ${dont_merge} ${TOP_SRC_DIR}/src/HunspellChecker.cpp)
  62 endif()
  63
  64
  65 lyx_automoc(${TOP_SRC_DIR}/src/Compare.cpp)
  66 if(WIN32)
  67         lyx_automoc(${TOP_SRC_DIR}/src/Server.cpp)
  68 endif()
  69
  70 include_directories(${CMAKE_CURRENT_BINARY_DIR}
  71         ${ZLIB_INCLUDE_DIR} ${QT_INCLUDES})
  72
  73 lyx_add_msvc_pch(lyx)
  74
  75 if (LYX_DEVEL_VERSION)
  76         add_definitions(-DDEVEL_VERSION)
  77 endif()
  78
  79
  80 if (LYX_MERGE_FILES)
  81         if(dont_merge)
  82                 list(REMOVE_ITEM lyx_sources ${dont_merge})
  83         endif()
  84         lyx_const_touched_files(_allinone lyx_sources)
  85         set(lyx_sources ${_allinone_files} ${dont_merge})
  86 endif()
  87
  88 if (LYX_VLD)
  89         configure_file(${vld_path}/vld.ini ${CMAKE_CURRENT_BINARY_DIR}/vld.ini COPYONLY)
  90         configure_file(${vld_path}/vld.ini ${CMAKE_CURRENT_BINARY_DIR}/memory_leak_report.txt COPYONLY)
  91         set(vld_files ${CMAKE_CURRENT_BINARY_DIR}/vld.ini ${CMAKE_CURRENT_BINARY_DIR}/memory_leak_report.txt)
  92 endif()
  93
  94 if(WIN32)
  95         set(FILE_RC ${TOP_SRC_DIR}/development/cmake/lyx.rc)
  96         message(STATUS "Using icon defined in resource file: ${FILE_RC}")
  97 endif()
  98
  99 lyx_find_info_files(LyXInfoFiles ${TOP_SRC_DIR}/*)
 100 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/*.txt)
 101 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/*.cmake)
 102 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/*.h)
 103 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/*.msvc)
 104 lyx_find_info_files(LyXCMakeFiles ${TOP_SRC_DIR}/development/cmake/modules/*)
 105 lyx_find_info_files(LyXUiFiles ${TOP_SRC_DIR}/lib/ui/*)
 106
 107 add_executable(${_lyx}
 108         ${WIN32_CONSOLE}
 109         ${LYX_BUNDLE}
 110         ${lyx_sources}
 111         ${lyx_headers}
 112         ${vld_files}
 113         ${FILE_RC}
 114         ${lyx_info_files}
 115         ${lyx_cmake_files}
 116 )
 117
 118 if(LYX_BUNDLE)
 119         set(MACOSX_BUNDLE_STRATUP_COMMAND ${_lyx})
 120 endif()
 121
 122 lyx_add_gcc_pch(${_lyx})
 123
 124 target_link_libraries(${_lyx}
 125         mathed
 126         insets
 127         frontends
 128         frontend_qt4
 129         graphics
 130         support
 131         ${LIBINTL_LIBRARIES}
 132         ${ICONV_LIBRARY}
 133         ${QT_QTMAIN_LIBRARY}
 134         ${vld_dll})
 135
 136
 137 if(HUNSPELL_FOUND)
 138         target_link_libraries(${_lyx} ${HUNSPELL_LIBRARY})
 139 endif()
 140 if(ASPELL_FOUND)
 141         target_link_libraries(${_lyx} ${ASPELL_LIBRARY})
 142 endif()
 143 if(ENCHANT_FOUND)
 144         target_link_libraries(${_lyx} ${ENCHANT_LIBRARY})
 145 endif()
 146
 147 if(APPLE)
 148         target_link_libraries(${_lyx} "-bind_at_load")
 149         if(LYX_COCOA)
 150                 target_link_libraries(${_lyx} "-framework Cocoa")
 151         else()
 152                 target_link_libraries(${_lyx} "-framework Carbon")
 153         endif()
 154 endif()
 155
 156 if(MINGW)
 157         target_link_libraries(${_lyx} ole32)
 158 endif()
 159
 160 project_source_group("${GROUP_CODE}" lyx_sources lyx_headers)
 161
 162 if(LYX_BUNDLE)
 163         install(TARGETS ${_lyx}
 164                 RUNTIME DESTINATION bin
 165                 BUNDLE DESTINATION .)
 166 else()
 167         install(TARGETS ${_lyx} DESTINATION bin)
 168 endif()