po/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2008-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6 #
   7
   8 project(po)
   9
  10 include_directories(${TOP_SRC_DIR}/po)
  11
  12 SET(_lyxname ${PACKAGE})
  13 SET(_py_sources)
  14 macro(add_gettext_python  _par _dir)
  15   set(_sources)
  16   foreach(_arg ${ARGN})
  17     file(GLOB _s1 ${TOP_SRC_DIR}/${_dir}/${_arg})
  18     list(SORT _s1)
  19     list(APPEND _sources ${_s1})
  20   endforeach(_arg)
  21   if (${_par} MATCHES "layouttranslations")
  22     SET(_dst "${CMAKE_CURRENT_BINARY_DIR}/${_par}")
  23   else ()
  24     SET(_dst "${CMAKE_CURRENT_BINARY_DIR}/${_par}_l10n.pot")
  25   endif()
  26   SET(_tmp_src_files "${CMAKE_CURRENT_BINARY_DIR}/${_par}_tmp_files")
  27   SET(_src_files "${CMAKE_CURRENT_BINARY_DIR}/${_par}_files")
  28   file(WRITE ${_tmp_src_files} "")
  29   foreach(_s ${_sources})
  30     FILE(APPEND ${_tmp_src_files} "${_s}\n")
  31   endforeach()
  32   if(${_par} MATCHES "^\(.*\)_[0-9]+$")
  33     set(_par1 ${CMAKE_MATCH_1})
  34   else()
  35     set(_par1 ${_par})
  36   endif()
  37   ADD_CUSTOM_COMMAND(
  38     OUTPUT ${_src_files}
  39     COMMAND ${CMAKE_COMMAND} -E copy_if_different ${_tmp_src_files} ${_src_files}
  40     DEPENDS ${_tmp_src_files}
  41   )
  42   if (${_par} MATCHES "layouttranslations")
  43     ADD_CUSTOM_COMMAND(
  44       OUTPUT "${_dst}"
  45       PRE_BUILD
  46       COMMAND  ${CMAKE_COMMAND} -E copy_if_different "${TOP_SRC_DIR}/lib/layouttranslations" "${_dst}"
  47       COMMAND ${LYX_PYTHON_EXECUTABLE}
  48       ARGS "${TOP_SRC_DIR}/po/lyx_pot.py" -b "${TOP_SRC_DIR}" -o "${_dst}" -t ${_par1} "--src_file=${_src_files}"
  49       COMMAND  ${CMAKE_COMMAND} -E copy_if_different "${_dst}" "${TOP_SRC_DIR}/lib/layouttranslations"
  50       DEPENDS ${_sources} ${_src_files} "${TOP_SRC_DIR}/lib/layouttranslations"
  51       COMMENT "${LYX_PYTHON_EXECUTABLE} ${TOP_SRC_DIR}/po/lyx_pot.py -b ${TOP_SRC_DIR} -o  ${_dst} -t ${_par1} --src_file=${_src_files}"
  52       )
  53     ADD_CUSTOM_TARGET(layouttranslations1 DEPENDS "${_dst}")
  54         set_target_properties(layouttranslations1 PROPERTIES FOLDER "i18n")
  55     if (LYX_DATA_SUBDIR STREQUAL "")
  56       install(FILES "${TOP_SRC_DIR}/lib/layouttranslations" DESTINATION .)
  57     else()
  58       install(FILES "${TOP_SRC_DIR}/lib/layouttranslations" DESTINATION ${LYX_DATA_SUBDIR})
  59     endif()
  60   else()
  61     ADD_CUSTOM_COMMAND(
  62       OUTPUT "${_dst}"
  63       PRE_BUILD
  64       COMMAND ${LYX_PYTHON_EXECUTABLE}
  65       ARGS "${TOP_SRC_DIR}/po/lyx_pot.py" -b "${TOP_SRC_DIR}" -o "${_dst}" -t ${_par1} "--src_file=${_src_files}"
  66       DEPENDS ${_sources} ${_src_files}
  67       COMMENT "${LYX_PYTHON_EXECUTABLE} ${TOP_SRC_DIR}/po/lyx_pot.py -b ${TOP_SRC_DIR} -o  ${_dst} -t ${_par1} --src_file=${_src_files}"
  68       )
  69     LIST(APPEND _py_sources "${_dst}")
  70   endif()
  71   SET_SOURCE_FILES_PROPERTIES("${_dst}" GENERATED)
  72   SET_SOURCE_FILES_PROPERTIES("${_src_files}" GENERATED)
  73 endmacro(add_gettext_python)
  74
  75 SET_SOURCE_FILES_PROPERTIES("${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot" GENERATED)
  76 SET_SOURCE_FILES_PROPERTIES("${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot" GENERATED)
  77 SET_SOURCE_FILES_PROPERTIES("${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot" GENERATED)
  78
  79 add_gettext_python(qt4 src/frontends/qt4/ui *.ui)
  80 add_gettext_python(layouts lib/layouts *.layout *.inc *.module)
  81 add_gettext_python(languages lib languages)
  82 add_gettext_python(latexfonts lib latexfonts)
  83 add_gettext_python(encodings lib encodings)
  84 add_gettext_python(ui lib/ui *.ui *.inc)
  85 add_gettext_python(external lib external_templates)
  86 add_gettext_python(formats lib configure.py)
  87 add_gettext_python(layouttranslations lib/layouts *.layout *.inc *.module)
  88
  89 ADD_CUSTOM_COMMAND(
  90     OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot"
  91     COMMAND ${LYX_PYTHON_EXECUTABLE}
  92     ARGS   "${TOP_CMAKE_PATH}/po/cat.py" ${_py_sources} > "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat_tmp.pot"
  93     COMMAND ${LYX_PYTHON_EXECUTABLE}
  94       ARGS   "${TOP_CMAKE_PATH}/po/dos2unix.py" "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat_tmp.pot"
  95     COMMAND ${CMAKE_COMMAND} -E copy_if_different
  96       "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat_tmp.pot" "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot"
  97     DEPENDS ${_py_sources}
  98     )
  99
 100 ADD_CUSTOM_COMMAND(
 101     OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot"
 102     COMMAND ${GETTEXT_MSGUNIQ_EXECUTABLE}
 103     ARGS -o "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt_tmp.pot" "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot"
 104     COMMAND ${CMAKE_COMMAND} -E copy_if_different
 105       "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt_tmp.pot" "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot"
 106     DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot"
 107     )
 108
 109 SET(_potfiles_dep)
 110
 111 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/POTFILES.in.tmp "")
 112 file(GLOB_RECURSE _tmp_potfiles RELATIVE ${TOP_SRC_DIR}/ ${TOP_SRC_DIR}/src/*.h  ${TOP_SRC_DIR}/src/*.cpp  ${TOP_SRC_DIR}/src/*.cpp.in)
 113 list(SORT _tmp_potfiles)
 114 # list(REMOVE_ITEM _tmp_potfiles src/support/Package.cpp)
 115
 116 foreach(_f ${_tmp_potfiles})
 117   # we don't need to select only relevant files because the outcome of xgettext
 118   # will stay the same.
 119   # Relevant files are files containing the string '_(".*")'
 120   LIST(APPEND _potfiles_dep "${TOP_SRC_DIR}/${_f}")
 121   file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/POTFILES.in.tmp "${_f}\n")
 122 endforeach(_f)
 123
 124 execute_process(
 125   COMMAND ${CMAKE_COMMAND} -E copy_if_different "${CMAKE_CURRENT_BINARY_DIR}/POTFILES.in.tmp" "${CMAKE_CURRENT_BINARY_DIR}/POTFILES.in"
 126   )
 127
 128 ADD_CUSTOM_COMMAND(
 129     OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot"
 130     COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot" "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot"
 131     COMMAND ${GETTEXT_XGETTEXT_EXECUTABLE}
 132       --default-domain=${_lyxname} --directory=${TOP_SRC_DIR}
 133       --add-comments=TRANSLATORS:
 134       --language=C++ --join-existing --keyword=_ --keyword=N_ --keyword=B_ --keyword=qt_
 135       --files-from=${CMAKE_CURRENT_BINARY_DIR}/POTFILES.in
 136       --copyright-holder="LyX Developers" --msgid-bugs-address=lyx-devel@lists.lyx.org
 137       -o "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot"
 138     DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot" ${_potfiles_dep}
 139     )
 140
 141 #
 142 # We have to copy the po-files first,
 143 # otherwise they would be modified (inside the macro GETTEXT_CREATE_TRANSLATIONS())
 144 # This makes the "git pull" on po-files work again
 145 file(GLOB LYX_BASE_PO_FILES RELATIVE ${TOP_SRC_DIR}/po ${TOP_SRC_DIR}/po/*.po)
 146 list(SORT LYX_BASE_PO_FILES)
 147 set(LYX_PO_FILES)
 148 SET(LYX_UPDATED_PO_FILES)
 149 SET(LYX_DEST_PO ${TOP_SRC_DIR}/po)
 150
 151 set(CONFIGURED_LANGUAGES)               # from file LINGUAS
 152 set(INSTALLED_LANGUAGES)                # from names of existing po-files
 153
 154 file(STRINGS "${TOP_SRC_DIR}/po/LINGUAS" _lang_lines)
 155 foreach(_c_l ${_lang_lines})
 156   if(NOT _c_l MATCHES "^#.*")
 157     string(REPLACE " " ";" _c_l ${_c_l}) #Split ${_c_l}
 158     list(APPEND CONFIGURED_LANGUAGES ${_c_l})
 159   endif()
 160 endforeach(_c_l)
 161
 162 foreach(_pofile ${LYX_BASE_PO_FILES})
 163   string(REGEX REPLACE "^(.*)\\.po$" "\\1" _inst_lng ${_pofile})
 164   list(FIND CONFIGURED_LANGUAGES ${_inst_lng} _lng_idx)
 165   if(_lng_idx GREATER -1)
 166     list(APPEND INSTALLED_LANGUAGES ${_inst_lng})
 167   endif()
 168   add_custom_command(
 169     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}
 170     COMMAND ${CMAKE_COMMAND} -E copy ${TOP_SRC_DIR}/po/${_pofile} ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}
 171     DEPENDS ${TOP_SRC_DIR}/po/${_pofile}
 172     )
 173   list(APPEND LYX_PO_FILES ${CMAKE_CURRENT_BINARY_DIR}/${_pofile})
 174 endforeach(_pofile)
 175
 176 FIND_PROGRAM(LYX_GITVERSION git)
 177 set(LYX_UPDATED_GMO_FILES)
 178 foreach(_gmo_base ${INSTALLED_LANGUAGES})
 179   set(_gmo ${_gmo_base}.gmo)
 180   set(_tobeupdated "${CMAKE_CURRENT_BINARY_DIR}/${_gmo}.tobeupdated")
 181   list(APPEND LYX_UPDATED_GMO_FILES "${_tobeupdated}")
 182   if(LYX_GITVERSION)
 183     add_custom_command(
 184       OUTPUT "${_tobeupdated}"
 185           COMMAND "${LYX_GITVERSION}" "status" "--porcelain" "${_gmo_base}.po" ">" "${_tobeupdated}"
 186           COMMAND ${LYX_PYTHON_EXECUTABLE} "${TOP_CMAKE_PATH}/po/update-gmo.py"
 187                 "${_tobeupdated}"
 188                 "${CMAKE_CURRENT_BINARY_DIR}/${_gmo}"
 189                 "${LYX_DEST_PO}/${_gmo}"
 190           WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
 191       DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${_gmo}"
 192       )
 193   else()
 194     add_custom_command(
 195       OUTPUT "${_tobeupdated}"
 196       COMMAND ${CMAKE_COMMAND} -E copy_if_different "${CMAKE_CURRENT_BINARY_DIR}/${_gmo}" "${LYX_DEST_PO}/${_gmo}"
 197       COMMAND ${CMAKE_COMMAND} -E touch "${_tobeupdated}"
 198       DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${_gmo}"
 199     )
 200   endif()
 201 endforeach()
 202
 203 set(LYX_UPDATED_PO_FILES)
 204 foreach(_pofile ${LYX_BASE_PO_FILES})
 205   if(WIN32)
 206     add_custom_command(
 207       OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}.copied
 208       COMMAND ${LYX_PYTHON_EXECUTABLE}
 209         ARGS   "${TOP_CMAKE_PATH}/po/unix2dos.py" "${CMAKE_CURRENT_BINARY_DIR}/${_pofile}"
 210       COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_BINARY_DIR}/${_pofile} ${LYX_DEST_PO}/${_pofile}
 211       COMMAND ${CMAKE_COMMAND} -E touch ${_pofile}.copied
 212       DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}
 213       )
 214   else()
 215     add_custom_command(
 216       OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}.copied
 217       COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_BINARY_DIR}/${_pofile} ${LYX_DEST_PO}/${_pofile}
 218       COMMAND ${CMAKE_COMMAND} -E touch ${_pofile}.copied
 219       DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}
 220       )
 221   endif()
 222   list(APPEND LYX_UPDATED_PO_FILES ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}.copied)
 223 endforeach(_pofile)
 224
 225 if(LYX_CPACK OR LYX_INSTALL)
 226   set(_addALLOption ALL)
 227 endif()
 228 GETTEXT_CREATE_TRANSLATIONS(${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot ${_addALLOption} ${LYX_PO_FILES})
 229
 230 # Create a new target to remerge po files
 231 # ALL omitted here, to prevent from automatic creation
 232 ADD_CUSTOM_TARGET(update-gmo DEPENDS ${LYX_UPDATED_GMO_FILES})
 233 ADD_CUSTOM_TARGET(update-po DEPENDS ${LYX_UPDATED_PO_FILES} ${LYX_UPDATED_GMO_FILES})
 234 set_target_properties(update-po update-gmo PROPERTIES FOLDER "i18n")
 235 add_dependencies(update-po translations)
 236