po/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2008-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6 #
   7
   8 project(po)
   9
  10 include_directories(${TOP_SRC_DIR}/po)
  11
  12 SET(_lyxname ${PACKAGE})
  13 SET(_py_sources)
  14 macro(add_gettext_python  _par _dir)
  15   set(_sources)
  16   foreach(_arg ${ARGN})
  17     file(GLOB _s1 ${TOP_SRC_DIR}/${_dir}/${_arg})
  18     list(SORT _s1)
  19     list(APPEND _sources ${_s1})
  20   endforeach(_arg)
  21   if (${_par} MATCHES "layouttranslations")
  22     SET(_dst "${CMAKE_CURRENT_BINARY_DIR}/${_par}")
  23   else ()
  24     SET(_dst "${CMAKE_CURRENT_BINARY_DIR}/${_par}_l10n.pot")
  25   endif()
  26   SET(_tmp_src_files "${CMAKE_CURRENT_BINARY_DIR}/${_par}_tmp_files")
  27   SET(_src_files "${CMAKE_CURRENT_BINARY_DIR}/${_par}_files")
  28   file(WRITE ${_tmp_src_files} "")
  29   foreach(_s ${_sources})
  30     FILE(APPEND ${_tmp_src_files} "${_s}\n")
  31   endforeach()
  32   if(${_par} MATCHES "^\(.*\)_[0-9]+$")
  33     set(_par1 ${CMAKE_MATCH_1})
  34   else()
  35     set(_par1 ${_par})
  36   endif()
  37   ADD_CUSTOM_COMMAND(
  38     OUTPUT ${_src_files}
  39     COMMAND ${CMAKE_COMMAND} -E copy_if_different ${_tmp_src_files} ${_src_files}
  40     DEPENDS ${_tmp_src_files}
  41   )
  42   if (${_par} MATCHES "layouttranslations")
  43     ADD_CUSTOM_COMMAND(
  44       OUTPUT "${_dst}"
  45       PRE_BUILD
  46       COMMAND  ${CMAKE_COMMAND} -E copy_if_different "${TOP_SRC_DIR}/lib/layouttranslations" "${_dst}"
  47       COMMAND ${LYX_PYTHON_EXECUTABLE}
  48       ARGS "${TOP_SRC_DIR}/po/lyx_pot.py" -b "${TOP_SRC_DIR}" -o "${_dst}" -t ${_par1} "--src_file=${_src_files}"
  49       COMMAND  ${CMAKE_COMMAND} -E copy_if_different "${_dst}" "${TOP_SRC_DIR}/lib/layouttranslations"
  50       DEPENDS ${_sources} ${_src_files} "${TOP_SRC_DIR}/lib/layouttranslations"
  51       COMMENT "${LYX_PYTHON_EXECUTABLE} ${TOP_SRC_DIR}/po/lyx_pot.py -b ${TOP_SRC_DIR} -o  ${_dst} -t ${_par1} --src_file=${_src_files}"
  52       )
  53     ADD_CUSTOM_TARGET(layouttranslations1 DEPENDS "${_dst}")
  54     if (LYX_DATA_SUBDIR STREQUAL "")
  55       install(FILES "${TOP_SRC_DIR}/lib/layouttranslations" DESTINATION .)
  56     else()
  57       install(FILES "${TOP_SRC_DIR}/lib/layouttranslations" DESTINATION ${LYX_DATA_SUBDIR})
  58     endif()
  59   else()
  60     ADD_CUSTOM_COMMAND(
  61       OUTPUT "${_dst}"
  62       PRE_BUILD
  63       COMMAND ${LYX_PYTHON_EXECUTABLE}
  64       ARGS "${TOP_SRC_DIR}/po/lyx_pot.py" -b "${TOP_SRC_DIR}" -o "${_dst}" -t ${_par1} "--src_file=${_src_files}"
  65       DEPENDS ${_sources} ${_src_files}
  66       COMMENT "${LYX_PYTHON_EXECUTABLE} ${TOP_SRC_DIR}/po/lyx_pot.py -b ${TOP_SRC_DIR} -o  ${_dst} -t ${_par1} --src_file=${_src_files}"
  67       )
  68     LIST(APPEND _py_sources "${_dst}")
  69   endif()
  70   SET_SOURCE_FILES_PROPERTIES("${_dst}" GENERATED)
  71   SET_SOURCE_FILES_PROPERTIES("${_src_files}" GENERATED)
  72 endmacro(add_gettext_python)
  73
  74 SET_SOURCE_FILES_PROPERTIES("${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot" GENERATED)
  75 SET_SOURCE_FILES_PROPERTIES("${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot" GENERATED)
  76 SET_SOURCE_FILES_PROPERTIES("${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot" GENERATED)
  77
  78 add_gettext_python(qt4 src/frontends/qt4/ui *.ui)
  79 add_gettext_python(layouts lib/layouts *.layout *.inc *.module)
  80 add_gettext_python(languages lib languages)
  81 add_gettext_python(latexfonts lib latexfonts)
  82 add_gettext_python(encodings lib encodings)
  83 add_gettext_python(ui lib/ui *.ui *.inc)
  84 add_gettext_python(external lib external_templates)
  85 add_gettext_python(formats lib configure.py)
  86 add_gettext_python(layouttranslations lib/layouts *.layout *.inc *.module)
  87
  88 ADD_CUSTOM_COMMAND(
  89     OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot"
  90     COMMAND ${LYX_PYTHON_EXECUTABLE}
  91     ARGS   "${TOP_SRC_DIR}/development/cmake/po/cat.py" ${_py_sources} > "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot"
  92     COMMAND ${LYX_PYTHON_EXECUTABLE}
  93       ARGS   "${TOP_SRC_DIR}/development/cmake/po/dos2unix.py" "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot"
  94     DEPENDS ${_py_sources}
  95     )
  96
  97 ADD_CUSTOM_COMMAND(
  98     OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot"
  99     COMMAND ${GETTEXT_MSGUNIQ_EXECUTABLE}
 100     ARGS -o "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot" "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot"
 101     DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot"
 102     )
 103
 104 SET(_potfiles_dep)
 105
 106 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/POTFILES.in "")
 107 file(GLOB_RECURSE _tmp_potfiles RELATIVE ${TOP_SRC_DIR}/ ${TOP_SRC_DIR}/src/*.h  ${TOP_SRC_DIR}/src/*.cpp  ${TOP_SRC_DIR}/src/*.cpp.in)
 108 list(SORT _tmp_potfiles)
 109 # list(REMOVE_ITEM _tmp_potfiles src/support/Package.cpp)
 110
 111 foreach(_f ${_tmp_potfiles})
 112   # we don't need to select only relevant files because the outcome of xgettext
 113   # will stay the same.
 114   # Relevant files are files containing the string '_(".*")'
 115   LIST(APPEND _potfiles_dep "${TOP_SRC_DIR}/${_f}")
 116   file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/POTFILES.in "${_f}\n")
 117 endforeach(_f)
 118
 119 ADD_CUSTOM_COMMAND(
 120     OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot"
 121     COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot" "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot"
 122     COMMAND ${GETTEXT_XGETTEXT_EXECUTABLE}
 123     ARGS --default-domain=${_lyxname} --directory=${TOP_SRC_DIR} --add-comments=TRANSLATORS: --language=C++ --join-existing --keyword=_ --keyword=N_ --keyword=B_ --keyword=qt_ --files-from="${CMAKE_CURRENT_BINARY_DIR}/POTFILES.in" --copyright-holder="LyX Developers" --msgid-bugs-address=lyx-devel@lists.lyx.org -o "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot"
 124     DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot" ${_potfiles_dep}
 125     )
 126
 127 #
 128 # We have to copy the po-files first,
 129 # otherwise they would be modified (inside the macro GETTEXT_CREATE_TRANSLATIONS())
 130 # This makes the "git pull" on po-files work again
 131 file(GLOB LYX_BASE_PO_FILES RELATIVE ${TOP_SRC_DIR}/po ${TOP_SRC_DIR}/po/*.po)
 132 list(SORT LYX_BASE_PO_FILES)
 133 set(LYX_PO_FILES)
 134 SET(LYX_UPDATED_PO_FILES)
 135 SET(LYX_DEST_PO ${TOP_SRC_DIR}/po)
 136
 137 set(CONFIGURED_LANGUAGES)               # from file LINGUAS
 138 set(INSTALLED_LANGUAGES)                # from names of existing po-files
 139
 140 file(STRINGS "${TOP_SRC_DIR}/po/LINGUAS" _lang_lines)
 141 foreach(_c_l ${_lang_lines})
 142   if(NOT _c_l MATCHES "^#.*")
 143     string(REPLACE " " ";" _c_l ${_c_l}) #Split ${_c_l}
 144     list(APPEND CONFIGURED_LANGUAGES ${_c_l})
 145   endif()
 146 endforeach(_c_l)
 147
 148 foreach(_pofile ${LYX_BASE_PO_FILES})
 149   string(REGEX REPLACE "^(.*)\\.po$" "\\1" _inst_lng ${_pofile})
 150   list(FIND CONFIGURED_LANGUAGES ${_inst_lng} _lng_idx)
 151   if(_lng_idx GREATER -1)
 152     list(APPEND INSTALLED_LANGUAGES "${_inst_lng} ")
 153   endif()
 154   add_custom_command(
 155     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}
 156     COMMAND ${CMAKE_COMMAND} -E copy ${TOP_SRC_DIR}/po/${_pofile} ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}
 157     DEPENDS ${TOP_SRC_DIR}/po/${_pofile}
 158     )
 159   list(APPEND LYX_PO_FILES ${CMAKE_CURRENT_BINARY_DIR}/${_pofile})
 160 endforeach(_pofile)
 161
 162 # We mimic the autoconf behaviour, e.g write this file at "configure" time
 163 file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/installed_translations" ${INSTALLED_LANGUAGES})
 164
 165 install(FILES "${CMAKE_CURRENT_BINARY_DIR}/installed_translations" DESTINATION .)
 166
 167 set(LYX_UPDATED_PO_FILES)
 168 foreach(_pofile ${LYX_BASE_PO_FILES})
 169   if(WIN32)
 170     add_custom_command(
 171       OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}.copied
 172       COMMAND ${LYX_PYTHON_EXECUTABLE}
 173         ARGS   "${TOP_SRC_DIR}/development/cmake/po/unix2dos.py" "${CMAKE_CURRENT_BINARY_DIR}/${_pofile}"
 174       COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_BINARY_DIR}/${_pofile} ${LYX_DEST_PO}/${_pofile}
 175       COMMAND ${CMAKE_COMMAND} -E touch ${_pofile}.copied
 176       DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}
 177       )
 178   else()
 179     add_custom_command(
 180       OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}.copied
 181       COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_BINARY_DIR}/${_pofile} ${LYX_DEST_PO}/${_pofile}
 182       COMMAND ${CMAKE_COMMAND} -E touch ${_pofile}.copied
 183       DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}
 184       )
 185   endif()
 186   list(APPEND LYX_UPDATED_PO_FILES ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}.copied)
 187 endforeach(_pofile)
 188
 189 if(LYX_CPACK OR LYX_INSTALL)
 190   set(_addALLOption ALL)
 191 endif()
 192 GETTEXT_CREATE_TRANSLATIONS(${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot ${_addALLOption} ${LYX_PO_FILES})
 193
 194 # Create a new target to remerge po files
 195 # ALL omitted here, to prevent from automatic creation
 196 ADD_CUSTOM_TARGET(update-po DEPENDS ${LYX_UPDATED_PO_FILES})
 197 add_dependencies(update-po translations)
 198