m4/po.m4

   1 # po.m4 serial 13 (gettext-0.15)
   2 dnl Copyright (C) 1995-2006 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6 dnl
   7 dnl This file can can be used in projects which are not available under
   8 dnl the GNU General Public License or the GNU Library General Public
   9 dnl License but which still want to provide support for the GNU gettext
  10 dnl functionality.
  11 dnl Please note that the actual code of the GNU gettext library is covered
  12 dnl by the GNU Library General Public License, and the rest of the GNU
  13 dnl gettext package package is covered by the GNU General Public License.
  14 dnl They are *not* in the public domain.
  15
  16 dnl Authors:
  17 dnl   Ulrich Drepper <drepper@cygnus.com>, 1995-2000.
  18 dnl   Bruno Haible <haible@clisp.cons.org>, 2000-2003.
  19
  20 AC_PREREQ(2.50)
  21
  22 dnl Checks for all prerequisites of the po subdirectory.
  23 AC_DEFUN([AM_PO_SUBDIRS],
  24 [
  25   AC_REQUIRE([AC_PROG_MAKE_SET])dnl
  26   AC_REQUIRE([AC_PROG_INSTALL])dnl
  27   AC_REQUIRE([AM_PROG_MKDIR_P])dnl defined by automake
  28   AC_REQUIRE([AM_NLS])dnl
  29
  30   dnl Perform the following tests also if --disable-nls has been given,
  31   dnl because they are needed for "make dist" to work.
  32
  33   dnl Search for GNU msgfmt in the PATH.
  34   dnl The first test excludes Solaris msgfmt and early GNU msgfmt versions.
  35   dnl The second test excludes FreeBSD msgfmt.
  36   AM_PATH_PROG_WITH_TEST(MSGFMT, msgfmt,
  37     [$ac_dir/$ac_word --statistics /dev/null >&]AS_MESSAGE_LOG_FD[ 2>&1 &&
  38      (if $ac_dir/$ac_word --statistics /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi)],
  39     :)
  40   AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
  41
  42   dnl Test whether it is GNU msgfmt >= 0.15.
  43 changequote(,)dnl
  44   case `$MSGFMT --version | sed 1q | sed -e 's,^[^0-9]*,,'` in
  45     '' | 0.[0-9] | 0.[0-9].* | 0.1[0-4] | 0.1[0-4].*) MSGFMT_015=: ;;
  46     *) MSGFMT_015=$MSGFMT ;;
  47   esac
  48 changequote([,])dnl
  49   AC_SUBST([MSGFMT_015])
  50 changequote(,)dnl
  51   case `$GMSGFMT --version | sed 1q | sed -e 's,^[^0-9]*,,'` in
  52     '' | 0.[0-9] | 0.[0-9].* | 0.1[0-4] | 0.1[0-4].*) GMSGFMT_015=: ;;
  53     *) GMSGFMT_015=$GMSGFMT ;;
  54   esac
  55 changequote([,])dnl
  56   AC_SUBST([GMSGFMT_015])
  57
  58   dnl Search for GNU xgettext 0.12 or newer in the PATH.
  59   dnl The first test excludes Solaris xgettext and early GNU xgettext versions.
  60   dnl The second test excludes FreeBSD xgettext.
  61   AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext,
  62     [$ac_dir/$ac_word --omit-header --copyright-holder= --msgid-bugs-address= /dev/null >&]AS_MESSAGE_LOG_FD[ 2>&1 &&
  63      (if $ac_dir/$ac_word --omit-header --copyright-holder= --msgid-bugs-address= /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi)],
  64     :)
  65   dnl Remove leftover from FreeBSD xgettext call.
  66   rm -f messages.po
  67
  68   dnl Test whether it is GNU xgettext >= 0.15.
  69 changequote(,)dnl
  70   case `$XGETTEXT --version | sed 1q | sed -e 's,^[^0-9]*,,'` in
  71     '' | 0.[0-9] | 0.[0-9].* | 0.1[0-4] | 0.1[0-4].*) XGETTEXT_015=: ;;
  72     *) XGETTEXT_015=$XGETTEXT ;;
  73   esac
  74 changequote([,])dnl
  75   AC_SUBST([XGETTEXT_015])
  76
  77   dnl Search for GNU msgmerge 0.11 or newer in the PATH.
  78   AM_PATH_PROG_WITH_TEST(MSGMERGE, msgmerge,
  79     [$ac_dir/$ac_word --update -q /dev/null /dev/null >&]AS_MESSAGE_LOG_FD[ 2>&1], :)
  80
  81   dnl Installation directories.
  82   dnl Autoconf >= 2.60 defines localedir. For older versions of autoconf, we
  83   dnl have to define it here, so that it can be used in po/Makefile.
  84   test -n "$localedir" || localedir='${datadir}/locale'
  85   AC_SUBST([localedir])
  86
  87   AC_CONFIG_COMMANDS([po-directories], [[
  88     for ac_file in $CONFIG_FILES; do
  89       # Support "outfile[:infile[:infile...]]"
  90       case "$ac_file" in
  91         *:*) ac_file=`echo "$ac_file"|sed 's%:.*%%'` ;;
  92       esac
  93       # PO directories have a Makefile.in generated from Makefile.in.in.
  94       case "$ac_file" in */Makefile.in)
  95         # Adjust a relative srcdir.
  96         ac_dir=`echo "$ac_file"|sed 's%/[^/][^/]*$%%'`
  97         ac_dir_suffix="/`echo "$ac_dir"|sed 's%^\./%%'`"
  98         ac_dots=`echo "$ac_dir_suffix"|sed 's%/[^/]*%../%g'`
  99         # In autoconf-2.13 it is called $ac_given_srcdir.
 100         # In autoconf-2.50 it is called $srcdir.
 101         test -n "$ac_given_srcdir" || ac_given_srcdir="$srcdir"
 102         case "$ac_given_srcdir" in
 103           .)  top_srcdir=`echo $ac_dots|sed 's%/$%%'` ;;
 104           /*) top_srcdir="$ac_given_srcdir" ;;
 105           *)  top_srcdir="$ac_dots$ac_given_srcdir" ;;
 106         esac
 107         # Treat a directory as a PO directory if and only if it has a
 108         # POTFILES.in file. This allows packages to have multiple PO
 109         # directories under different names or in different locations.
 110         if test -f "$ac_given_srcdir/$ac_dir/POTFILES.in"; then
 111           rm -f "$ac_dir/POTFILES"
 112           test -n "$as_me" && echo "$as_me: creating $ac_dir/POTFILES" || echo "creating $ac_dir/POTFILES"
 113           cat "$ac_given_srcdir/$ac_dir/POTFILES.in" | sed -e "/^#/d" -e "/^[   ]*\$/d" -e "s,.*,     $top_srcdir/& \\\\," | sed -e "\$s/\(.*\) \\\\/\1/" > "$ac_dir/POTFILES"
 114           POMAKEFILEDEPS="POTFILES.in"
 115           # Remove POTFILES.in if it is empty, such that it can be
 116           # correctly rebuilt later.
 117           if test -s "$ac_given_srcdir/$ac_dir/POTFILES.in"; then
 118             : ;
 119           else
 120             rm -f "$ac_given_srcdir/$ac_dir/POTFILES.in"
 121           fi
 122           # ALL_LINGUAS, POFILES, UPDATEPOFILES, DUMMYPOFILES, GMOFILES depend
 123           # on $ac_dir but don't depend on user-specified configuration
 124           # parameters.
 125           if test -f "$ac_given_srcdir/$ac_dir/LINGUAS"; then
 126             # The LINGUAS file contains the set of available languages.
 127             if test -n "$OBSOLETE_ALL_LINGUAS"; then
 128               test -n "$as_me" && echo "$as_me: setting ALL_LINGUAS in configure.in is obsolete" || echo "setting ALL_LINGUAS in configure.in is obsolete"
 129             fi
 130             ALL_LINGUAS_=`sed -e "/^#/d" -e "s/#.*//" "$ac_given_srcdir/$ac_dir/LINGUAS"`
 131             # Hide the ALL_LINGUAS assigment from automake < 1.5.
 132             eval 'ALL_LINGUAS''=$ALL_LINGUAS_'
 133             POMAKEFILEDEPS="$POMAKEFILEDEPS LINGUAS"
 134           else
 135             # The set of available languages was given in configure.in.
 136             # Hide the ALL_LINGUAS assigment from automake < 1.5.
 137             eval 'ALL_LINGUAS''=$OBSOLETE_ALL_LINGUAS'
 138           fi
 139           # Compute POFILES
 140           # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).po)
 141           # Compute UPDATEPOFILES
 142           # as      $(foreach lang, $(ALL_LINGUAS), $(lang).po-update)
 143           # Compute DUMMYPOFILES
 144           # as      $(foreach lang, $(ALL_LINGUAS), $(lang).nop)
 145           # Compute GMOFILES
 146           # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).gmo)
 147           case "$ac_given_srcdir" in
 148             .) srcdirpre= ;;
 149             *) srcdirpre='$(srcdir)/' ;;
 150           esac
 151           POFILES=
 152           UPDATEPOFILES=
 153           DUMMYPOFILES=
 154           GMOFILES=
 155           for lang in $ALL_LINGUAS; do
 156             POFILES="$POFILES $srcdirpre$lang.po"
 157             UPDATEPOFILES="$UPDATEPOFILES $lang.po-update"
 158             DUMMYPOFILES="$DUMMYPOFILES $lang.nop"
 159             GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
 160           done
 161           # CATALOGS depends on both $ac_dir and the user's LINGUAS
 162           # environment variable.
 163           INST_LINGUAS=
 164           if test -n "$ALL_LINGUAS"; then
 165             for presentlang in $ALL_LINGUAS; do
 166               useit=no
 167               if test "%UNSET%" != "$LINGUAS"; then
 168                 desiredlanguages="$LINGUAS"
 169               else
 170                 desiredlanguages="$ALL_LINGUAS"
 171               fi
 172               for desiredlang in $desiredlanguages; do
 173                 # Use the presentlang catalog if desiredlang is
 174                 #   a. equal to presentlang, or
 175                 #   b. a variant of presentlang (because in this case,
 176                 #      presentlang can be used as a fallback for messages
 177                 #      which are not translated in the desiredlang catalog).
 178                 case "$desiredlang" in
 179                   "$presentlang"*) useit=yes;;
 180                 esac
 181               done
 182               if test $useit = yes; then
 183                 INST_LINGUAS="$INST_LINGUAS $presentlang"
 184               fi
 185             done
 186           fi
 187           CATALOGS=
 188           if test -n "$INST_LINGUAS"; then
 189             for lang in $INST_LINGUAS; do
 190               CATALOGS="$CATALOGS $lang.gmo"
 191             done
 192           fi
 193           test -n "$as_me" && echo "$as_me: creating $ac_dir/Makefile" || echo "creating $ac_dir/Makefile"
 194           sed -e "/^POTFILES =/r $ac_dir/POTFILES" -e "/^# Makevars/r $ac_given_srcdir/$ac_dir/Makevars" -e "s|@POFILES@|$POFILES|g" -e "s|@UPDATEPOFILES@|$UPDATEPOFILES|g" -e "s|@DUMMYPOFILES@|$DUMMYPOFILES|g" -e "s|@GMOFILES@|$GMOFILES|g" -e "s|@CATALOGS@|$CATALOGS|g" -e "s|@POMAKEFILEDEPS@|$POMAKEFILEDEPS|g" "$ac_dir/Makefile.in" > "$ac_dir/Makefile"
 195           for f in "$ac_given_srcdir/$ac_dir"/Rules-*; do
 196             if test -f "$f"; then
 197               case "$f" in
 198                 *.orig | *.bak | *~) ;;
 199                 *) cat "$f" >> "$ac_dir/Makefile" ;;
 200               esac
 201             fi
 202           done
 203         fi
 204         ;;
 205       esac
 206     done]],
 207    [# Capture the value of obsolete ALL_LINGUAS because we need it to compute
 208     # POFILES, UPDATEPOFILES, DUMMYPOFILES, GMOFILES, CATALOGS. But hide it
 209     # from automake < 1.5.
 210     eval 'OBSOLETE_ALL_LINGUAS''="$ALL_LINGUAS"'
 211     # Capture the value of LINGUAS because we need it to compute CATALOGS.
 212     LINGUAS="${LINGUAS-%UNSET%}"
 213    ])
 214 ])
 215
 216 dnl Postprocesses a Makefile in a directory containing PO files.
 217 AC_DEFUN([AM_POSTPROCESS_PO_MAKEFILE],
 218 [
 219   # When this code is run, in config.status, two variables have already been
 220   # set:
 221   # - OBSOLETE_ALL_LINGUAS is the value of LINGUAS set in configure.in,
 222   # - LINGUAS is the value of the environment variable LINGUAS at configure
 223   #   time.
 224
 225 changequote(,)dnl
 226   # Adjust a relative srcdir.
 227   ac_dir=`echo "$ac_file"|sed 's%/[^/][^/]*$%%'`
 228   ac_dir_suffix="/`echo "$ac_dir"|sed 's%^\./%%'`"
 229   ac_dots=`echo "$ac_dir_suffix"|sed 's%/[^/]*%../%g'`
 230   # In autoconf-2.13 it is called $ac_given_srcdir.
 231   # In autoconf-2.50 it is called $srcdir.
 232   test -n "$ac_given_srcdir" || ac_given_srcdir="$srcdir"
 233   case "$ac_given_srcdir" in
 234     .)  top_srcdir=`echo $ac_dots|sed 's%/$%%'` ;;
 235     /*) top_srcdir="$ac_given_srcdir" ;;
 236     *)  top_srcdir="$ac_dots$ac_given_srcdir" ;;
 237   esac
 238
 239   # Find a way to echo strings without interpreting backslash.
 240   if test "X`(echo '\t') 2>/dev/null`" = 'X\t'; then
 241     gt_echo='echo'
 242   else
 243     if test "X`(printf '%s\n' '\t') 2>/dev/null`" = 'X\t'; then
 244       gt_echo='printf %s\n'
 245     else
 246       echo_func () {
 247         cat <<EOT
 248 $*
 249 EOT
 250       }
 251       gt_echo='echo_func'
 252     fi
 253   fi
 254
 255   # A sed script that extracts the value of VARIABLE from a Makefile.
 256   sed_x_variable='
 257 # Test if the hold space is empty.
 258 x
 259 s/P/P/
 260 x
 261 ta
 262 # Yes it was empty. Look if we have the expected variable definition.
 263 /^[      ]*VARIABLE[     ]*=/{
 264   # Seen the first line of the variable definition.
 265   s/^[   ]*VARIABLE[     ]*=//
 266   ba
 267 }
 268 bd
 269 :a
 270 # Here we are processing a line from the variable definition.
 271 # Remove comment, more precisely replace it with a space.
 272 s/#.*$/ /
 273 # See if the line ends in a backslash.
 274 tb
 275 :b
 276 s/\\$//
 277 # Print the line, without the trailing backslash.
 278 p
 279 tc
 280 # There was no trailing backslash. The end of the variable definition is
 281 # reached. Clear the hold space.
 282 s/^.*$//
 283 x
 284 bd
 285 :c
 286 # A trailing backslash means that the variable definition continues in the
 287 # next line. Put a nonempty string into the hold space to indicate this.
 288 s/^.*$/P/
 289 x
 290 :d
 291 '
 292 changequote([,])dnl
 293
 294   # Set POTFILES to the value of the Makefile variable POTFILES.
 295   sed_x_POTFILES=`$gt_echo "$sed_x_variable" | sed -e '/^ *#/d' -e 's/VARIABLE/POTFILES/g'`
 296   POTFILES=`sed -n -e "$sed_x_POTFILES" < "$ac_file"`
 297   # Compute POTFILES_DEPS as
 298   #   $(foreach file, $(POTFILES), $(top_srcdir)/$(file))
 299   POTFILES_DEPS=
 300   for file in $POTFILES; do
 301     POTFILES_DEPS="$POTFILES_DEPS "'$(top_srcdir)/'"$file"
 302   done
 303   POMAKEFILEDEPS=""
 304
 305   if test -n "$OBSOLETE_ALL_LINGUAS"; then
 306     test -n "$as_me" && echo "$as_me: setting ALL_LINGUAS in configure.in is obsolete" || echo "setting ALL_LINGUAS in configure.in is obsolete"
 307   fi
 308   if test -f "$ac_given_srcdir/$ac_dir/LINGUAS"; then
 309     # The LINGUAS file contains the set of available languages.
 310     ALL_LINGUAS_=`sed -e "/^#/d" -e "s/#.*//" "$ac_given_srcdir/$ac_dir/LINGUAS"`
 311     POMAKEFILEDEPS="$POMAKEFILEDEPS LINGUAS"
 312   else
 313     # Set ALL_LINGUAS to the value of the Makefile variable LINGUAS.
 314     sed_x_LINGUAS=`$gt_echo "$sed_x_variable" | sed -e '/^ *#/d' -e 's/VARIABLE/LINGUAS/g'`
 315     ALL_LINGUAS_=`sed -n -e "$sed_x_LINGUAS" < "$ac_file"`
 316   fi
 317   # Hide the ALL_LINGUAS assigment from automake < 1.5.
 318   eval 'ALL_LINGUAS''=$ALL_LINGUAS_'
 319   # Compute POFILES
 320   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).po)
 321   # Compute UPDATEPOFILES
 322   # as      $(foreach lang, $(ALL_LINGUAS), $(lang).po-update)
 323   # Compute DUMMYPOFILES
 324   # as      $(foreach lang, $(ALL_LINGUAS), $(lang).nop)
 325   # Compute GMOFILES
 326   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).gmo)
 327   # Compute PROPERTIESFILES
 328   # as      $(foreach lang, $(ALL_LINGUAS), $(top_srcdir)/$(DOMAIN)_$(lang).properties)
 329   # Compute CLASSFILES
 330   # as      $(foreach lang, $(ALL_LINGUAS), $(top_srcdir)/$(DOMAIN)_$(lang).class)
 331   # Compute QMFILES
 332   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).qm)
 333   # Compute MSGFILES
 334   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(frob $(lang)).msg)
 335   # Compute RESOURCESDLLFILES
 336   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(frob $(lang))/$(DOMAIN).resources.dll)
 337   case "$ac_given_srcdir" in
 338     .) srcdirpre= ;;
 339     *) srcdirpre='$(srcdir)/' ;;
 340   esac
 341   POFILES=
 342   UPDATEPOFILES=
 343   DUMMYPOFILES=
 344   GMOFILES=
 345   PROPERTIESFILES=
 346   CLASSFILES=
 347   QMFILES=
 348   MSGFILES=
 349   RESOURCESDLLFILES=
 350   for lang in $ALL_LINGUAS; do
 351     POFILES="$POFILES $srcdirpre$lang.po"
 352     UPDATEPOFILES="$UPDATEPOFILES $lang.po-update"
 353     DUMMYPOFILES="$DUMMYPOFILES $lang.nop"
 354     GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
 355     PROPERTIESFILES="$PROPERTIESFILES \$(top_srcdir)/\$(DOMAIN)_$lang.properties"
 356     CLASSFILES="$CLASSFILES \$(top_srcdir)/\$(DOMAIN)_$lang.class"
 357     QMFILES="$QMFILES $srcdirpre$lang.qm"
 358     frobbedlang=`echo $lang | sed -e 's/\..*$//' -e 'y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/'`
 359     MSGFILES="$MSGFILES $srcdirpre$frobbedlang.msg"
 360     frobbedlang=`echo $lang | sed -e 's/_/-/g' -e 's/^sr-CS/sr-SP/' -e 's/@latin$/-Latn/' -e 's/@cyrillic$/-Cyrl/' -e 's/^sr-SP$/sr-SP-Latn/' -e 's/^uz-UZ$/uz-UZ-Latn/'`
 361     RESOURCESDLLFILES="$RESOURCESDLLFILES $srcdirpre$frobbedlang/\$(DOMAIN).resources.dll"
 362   done
 363   # CATALOGS depends on both $ac_dir and the user's LINGUAS
 364   # environment variable.
 365   INST_LINGUAS=
 366   if test -n "$ALL_LINGUAS"; then
 367     for presentlang in $ALL_LINGUAS; do
 368       useit=no
 369       if test "%UNSET%" != "$LINGUAS"; then
 370         desiredlanguages="$LINGUAS"
 371       else
 372         desiredlanguages="$ALL_LINGUAS"
 373       fi
 374       for desiredlang in $desiredlanguages; do
 375         # Use the presentlang catalog if desiredlang is
 376         #   a. equal to presentlang, or
 377         #   b. a variant of presentlang (because in this case,
 378         #      presentlang can be used as a fallback for messages
 379         #      which are not translated in the desiredlang catalog).
 380         case "$desiredlang" in
 381           "$presentlang"*) useit=yes;;
 382         esac
 383       done
 384       if test $useit = yes; then
 385         INST_LINGUAS="$INST_LINGUAS $presentlang"
 386       fi
 387     done
 388   fi
 389   CATALOGS=
 390   JAVACATALOGS=
 391   QTCATALOGS=
 392   TCLCATALOGS=
 393   CSHARPCATALOGS=
 394   if test -n "$INST_LINGUAS"; then
 395     for lang in $INST_LINGUAS; do
 396       CATALOGS="$CATALOGS $lang.gmo"
 397       JAVACATALOGS="$JAVACATALOGS \$(DOMAIN)_$lang.properties"
 398       QTCATALOGS="$QTCATALOGS $lang.qm"
 399       frobbedlang=`echo $lang | sed -e 's/\..*$//' -e 'y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/'`
 400       TCLCATALOGS="$TCLCATALOGS $frobbedlang.msg"
 401       frobbedlang=`echo $lang | sed -e 's/_/-/g' -e 's/^sr-CS/sr-SP/' -e 's/@latin$/-Latn/' -e 's/@cyrillic$/-Cyrl/' -e 's/^sr-SP$/sr-SP-Latn/' -e 's/^uz-UZ$/uz-UZ-Latn/'`
 402       CSHARPCATALOGS="$CSHARPCATALOGS $frobbedlang/\$(DOMAIN).resources.dll"
 403     done
 404   fi
 405
 406   sed -e "s|@POTFILES_DEPS@|$POTFILES_DEPS|g" -e "s|@POFILES@|$POFILES|g" -e "s|@UPDATEPOFILES@|$UPDATEPOFILES|g" -e "s|@DUMMYPOFILES@|$DUMMYPOFILES|g" -e "s|@GMOFILES@|$GMOFILES|g" -e "s|@PROPERTIESFILES@|$PROPERTIESFILES|g" -e "s|@CLASSFILES@|$CLASSFILES|g" -e "s|@QMFILES@|$QMFILES|g" -e "s|@MSGFILES@|$MSGFILES|g" -e "s|@RESOURCESDLLFILES@|$RESOURCESDLLFILES|g" -e "s|@CATALOGS@|$CATALOGS|g" -e "s|@JAVACATALOGS@|$JAVACATALOGS|g" -e "s|@QTCATALOGS@|$QTCATALOGS|g" -e "s|@TCLCATALOGS@|$TCLCATALOGS|g" -e "s|@CSHARPCATALOGS@|$CSHARPCATALOGS|g" -e 's,^#distdir:,distdir:,' < "$ac_file" > "$ac_file.tmp"
 407   if grep -l '@TCLCATALOGS@' "$ac_file" > /dev/null; then
 408     # Add dependencies that cannot be formulated as a simple suffix rule.
 409     for lang in $ALL_LINGUAS; do
 410       frobbedlang=`echo $lang | sed -e 's/\..*$//' -e 'y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/'`
 411       cat >> "$ac_file.tmp" <<EOF
 412 $frobbedlang.msg: $lang.po
 413         @echo "\$(MSGFMT) -c --tcl -d \$(srcdir) -l $lang $srcdirpre$lang.po"; \
 414         \$(MSGFMT) -c --tcl -d "\$(srcdir)" -l $lang $srcdirpre$lang.po || { rm -f "\$(srcdir)/$frobbedlang.msg"; exit 1; }
 415 EOF
 416     done
 417   fi
 418   if grep -l '@CSHARPCATALOGS@' "$ac_file" > /dev/null; then
 419     # Add dependencies that cannot be formulated as a simple suffix rule.
 420     for lang in $ALL_LINGUAS; do
 421       frobbedlang=`echo $lang | sed -e 's/_/-/g' -e 's/^sr-CS/sr-SP/' -e 's/@latin$/-Latn/' -e 's/@cyrillic$/-Cyrl/' -e 's/^sr-SP$/sr-SP-Latn/' -e 's/^uz-UZ$/uz-UZ-Latn/'`
 422       cat >> "$ac_file.tmp" <<EOF
 423 $frobbedlang/\$(DOMAIN).resources.dll: $lang.po
 424         @echo "\$(MSGFMT) -c --csharp -d \$(srcdir) -l $lang $srcdirpre$lang.po -r \$(DOMAIN)"; \
 425         \$(MSGFMT) -c --csharp -d "\$(srcdir)" -l $lang $srcdirpre$lang.po -r "\$(DOMAIN)" || { rm -f "\$(srcdir)/$frobbedlang.msg"; exit 1; }
 426 EOF
 427     done
 428   fi
 429   if test -n "$POMAKEFILEDEPS"; then
 430     cat >> "$ac_file.tmp" <<EOF
 431 Makefile: $POMAKEFILEDEPS
 432 EOF
 433   fi
 434   mv "$ac_file.tmp" "$ac_file"
 435 ])