lib/configure.m4

   1 #! /bin/sh
   2 dnl Use 'make' to create configure from this m4 script.
   3 # This script is a hand-made configure script. It contains a lot of
   4 # code stolen from GNU autoconf. I removed all the code that was not
   5 # useful for configuring a LyX installation.
   6
   7
   8 dnl ######### Begin M4 macros #########################################
   9 dnl This is a template for my stripped-down configure script.
  10 dnl First, a few convenient macros.
  11 changequote([,])dnl
  12 dnl
  13 dnl
  14 dnl MSG_CHECKING(FEATURE-DESCRIPTION,PREFIX)
  15 dnl
  16 define(MSG_CHECKING,
  17 [echo $ac_n "$2checking $1""... $ac_c"])dnl
  18 dnl
  19 dnl
  20 dnl MSG_RESULT(RESULT-DESCRIPTION)
  21 dnl
  22 define(MSG_RESULT,
  23 [echo "$ac_t""$1"])dnl
  24 dnl
  25 dnl
  26 dnl SEARCH_PROG(FEATURE-DESCRIPTION,VARIABLE-NAME,PROGRAMS-LIST,
  27 dnl             ACTION-IF-FOUND,ACTION-IF-NOT-FOUND)
  28 dnl
  29 define(SEARCH_PROG,[dnl
  30 changequote([,])dnl
  31 MSG_CHECKING($1)
  32 MSG_RESULT(($3))
  33 $2=
  34 for ac_prog in $3
  35 do
  36 # Extract the first word of "$ac_prog", so it can be a program name with args.
  37 set dummy $ac_prog ; ac_word=$[2]
  38 if test -n "$ac_word"; then
  39   MSG_CHECKING([for \"$ac_word\"],[+])
  40   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS=":"
  41   for ac_dir in $PATH; do
  42     test -z "$ac_dir" && ac_dir=.
  43     if test -x [$ac_dir/$ac_word]; then
  44       $2="$ac_prog"
  45       break
  46     fi
  47   done
  48   IFS="$ac_save_ifs"
  49
  50   if test -n "[$]$2"; then
  51     ac_result=yes
  52   else
  53     ac_result=no
  54   fi
  55   ifelse($4,,,[$4])
  56   MSG_RESULT($ac_result)
  57   test -n "[$]$2" && break
  58 fi
  59 done
  60
  61 if test -z "[$]$2" ; then
  62   $2=none
  63 ifelse($5,,,[  $5
  64 ])dnl
  65 fi
  66 changequote(,)dnl
  67 ])dnl
  68 dnl
  69 dnl
  70 dnl PROVIDE_DEFAULT_FILE(FILE, DEFAULT-VALUE)
  71 dnl
  72 define(PROVIDE_DEFAULT_FILE,[dnl
  73 # if $1 does not exist (because LaTeX did not run),
  74 # then provide a standard version.
  75 if test ! -f $1 ; then
  76   cat >$1 <<EOF
  77 $2
  78 EOF
  79 fi])
  80 changequote(,)dnl
  81 dnl ######### End M4 macros #############################################
  82
  83
  84 ####some configuration variables
  85 lyx_check_config=yes
  86 lyx_keep_temps=no
  87 srcdir=
  88
  89 #### Parse the command line
  90 for ac_option do
  91   case "$ac_option" in
  92     -help | --help | -h)
  93       cat << EOF
  94 Usage: configure [options]
  95 Options:
  96   --help                   show this help lines
  97   --keep-temps             keep temporary files (for debug. purposes)
  98   --without-latex-config   do not run LaTeX to determine configuration
  99 EOF
 100       exit 0;;
 101     --without-latex-config)
 102       lyx_check_config=no ;;
 103     --keep-temps)
 104       lyx_keep_temps=yes ;;
 105   esac
 106 done
 107
 108
 109 #### Checking for some echo oddities
 110 if (echo "testing\c"; echo 1,2,3) | grep c >/dev/null; then
 111   # Stardent Vistra SVR4 grep lacks -e, says ghazi@caip.rutgers.edu.
 112   if (echo -n testing; echo 1,2,3) | sed s/-n/xn/ | grep xn >/dev/null; then
 113     ac_n= ac_c='
 114 ' ac_t='        '
 115   else
 116     ac_n=-n ac_c= ac_t=
 117   fi
 118 else
 119   ac_n= ac_c='\c' ac_t=
 120 fi
 121
 122
 123 #### I do not really know why this is useful, but we might as well keep it.
 124 # NLS nuisances.
 125 # Only set these to C if already set.  These must not be set unconditionally
 126 # because not all systems understand e.g. LANG=C (notably SCO).
 127 # Fixing LC_MESSAGES prevents Solaris sh from translating var values in `set'!
 128 # Non-C LC_CTYPE values break the ctype check.
 129 if test "${LANG+set}"   = set; then LANG=C;   export LANG;   fi
 130 if test "${LC_ALL+set}" = set; then LC_ALL=C; export LC_ALL; fi
 131 if test "${LC_MESSAGES+set}" = set; then LC_MESSAGES=C; export LC_MESSAGES; fi
 132 if test "${LC_CTYPE+set}"    = set; then LC_CTYPE=C;    export LC_CTYPE;    fi
 133
 134
 135 #### Guess the directory in which configure is located.
 136 changequote([,])dnl
 137 ac_prog=[$]0
 138 changequote(,)dnl
 139 srcdir=`echo $ac_prog|sed 's%/[^/][^/]*$%%'`
 140 srcdir=`echo "${srcdir}" | sed 's%\([^/]\)/*$%\1%'`
 141 test "x$srcdir" = "x$ac_prog" && srcdir=.
 142 if test ! -r ${srcdir}/chkconfig.ltx ; then
 143   echo "configure: error: cannot find chkconfig.ltx script"
 144   exit 1
 145 fi
 146
 147
 148 #### Create the build directories if necessary
 149 for dir in bind clipart doc examples images kbd layouts reLyX \
 150     scripts templates ui ; do
 151   test ! -d $dir && mkdir $dir
 152 done
 153
 154
 155 #### Searching some useful programs
 156 define(CHECKLATEX2E,[
 157 ## Check whether this is really LaTeX2e
 158 rm -f chklatex.ltx
 159 cat >chklatex.ltx <<EOF
 160 \\nonstopmode\\makeatletter
 161 \\ifx\\undefined\\documentclass\\else
 162   \\message{ThisIsLaTeX2e}
 163 \\fi
 164 \\@@end
 165 EOF
 166 if eval ${LATEX} chklatex.ltx </dev/null 2>/dev/null \
 167                        | grep 'ThisIsLaTeX2e' >/dev/null; then
 168   :
 169 else
 170   LATEX=
 171   ac_result="not useable"
 172 fi
 173 rm -f chklatex.ltx chklatex.log])dnl
 174 dnl
 175 # Search LaTeX2e
 176 SEARCH_PROG([for a LaTeX2e program],LATEX,latex latex2e,CHECKLATEX2E,dnl
 177   [lyx_check_config=no])
 178 if test x$lyx_check_config != x ; then
 179 SEARCH_PROG([for the pdflatex program],PDFLATEX,pdflatex,CHECKLATEX2E)
 180 fi
 181
 182 # Search for an installed reLyX or a ready-to-install one
 183 save_PATH=${PATH}
 184 PATH=${PATH}:./reLyX/
 185 SEARCH_PROG([for a LaTeX -> LyX converter],tex_to_lyx_command,reLyX)
 186 PATH=${save_PATH}
 187 test $tex_to_lyx_command = "reLyX" && tex_to_lyx_command="reLyX -f \$\$FName"
 188
 189 SEARCH_PROG([for a Noweb -> LyX converter],literate_to_lyx_command,noweb2lyx)
 190 test $literate_to_lyx_command = "noweb2lyx" && literate_to_lyx_command="noweb2lyx \$\$FName \$\$OutName"
 191
 192 # Search something to process a literate document
 193 SEARCH_PROG([for a Noweb -> LaTeX converter],literate_to_tex_command,noweave)
 194 test $literate_to_tex_command = "noweave" && literate_to_tex_command="noweave -delay -index \$\$FName > \$\$OutName"
 195
 196 SEARCH_PROG([for a HTML -> Latex converter],html_to_latex_command,html2latex)
 197 test $html_to_latex_command = "html2latex" && html_to_latex_command="html2latex \$\$FName"
 198
 199 SEARCH_PROG([for Image converter],image_command,convert)
 200 test $image_command = "convert" && image_command="convert \$\$FName \$\$OutName"
 201
 202 # Search for a Postscript interpreter
 203 SEARCH_PROG([for a Postscript interpreter],GS, gs)
 204
 205 # Search something to preview postscript
 206 SEARCH_PROG([for a Postscript previewer],GHOSTVIEW,gv ghostview)
 207
 208 # Search for a program to preview pdf
 209 SEARCH_PROG([for a PDF preview],PDF_VIEWER,acroread gv ghostview xpdf)
 210
 211 # Search something to preview dvi
 212 SEARCH_PROG([for a DVI previewer],DVI_VIEWER, xdvi)
 213
 214 # Search something to preview html
 215 SEARCH_PROG([for a HTML previewer],HTML_VIEWER, netscape)
 216
 217 # Search for a program to convert ps to pdf
 218 SEARCH_PROG([for a PS to PDF converter],ps_to_pdf_command,ps2pdf)
 219 test $ps_to_pdf_command = "ps2pdf" && ps_to_pdf_command="ps2pdf \$\$FName"
 220
 221 # Search for a program to convert dvi to ps
 222 SEARCH_PROG([for a DVI to PS converter],dvi_to_ps_command,dvips)
 223 test $dvi_to_ps_command = "dvips" && dvi_to_ps_command="dvips -o \$\$OutName \$\$FName"
 224
 225 # Search a *roff program (used to translate tables in ASCII export)
 226 SEARCH_PROG([for a *roff formatter],ROFF,groff nroff)
 227 ascii_roff_command=$ROFF
 228 test $ROFF = "groff" && ascii_roff_command="groff -t -Tlatin1 \$\$FName"
 229 test $ROFF = "nroff" && ascii_roff_command="tbl \$\$FName | nroff"
 230
 231 # Search the ChkTeX program
 232 SEARCH_PROG([for ChkTeX],CHKTEX,chktex)
 233 chktex_command=$CHKTEX
 234 test $CHKTEX = "chktex" && chktex_command="$CHKTEX -n1 -n3 -n6 -n9 -n22 -n25 -n30 -n38"
 235
 236 # Search for a spellchecker
 237 SEARCH_PROG([for a spell-checker], SPELL,ispell)
 238
 239 # Search a Fax handling program
 240 SEARCH_PROG([for a fax driver], FAX, sendfax faxsend fax)
 241 if test $FAX = sendfax ; then
 242   fax_command="sendfax -n -h '\$\$Host' -c '\$\$Comment' -x '\$\$Enterprise' -d '\$\$Name'@'\$\$Phone' '\$\$FName'"
 243 elif test $FAX = faxsend ; then
 244   fax_command="faxsend '\$\$Phone' '\$\$FName'"
 245 elif test $FAX = fax ; then
 246   fax_command="fax send '\$\$Phone' '\$\$FName'"
 247 else
 248   fax_command="none"
 249 fi
 250
 251 # Search for LinuxDoc support
 252 SEARCH_PROG([for SGML-tools 1.x (LinuxDoc)], LINUXDOC, sgml2lyx)
 253 chk_linuxdoc=no
 254 if test $LINUXDOC != none; then
 255   chk_linuxdoc=yes
 256   linuxdoc_cmd="\\def\\haslinuxdoc{yes}"
 257 fi
 258
 259 case $LINUXDOC in
 260   sgml2lyx)
 261     linuxdoc_to_latex_command="sgml2latex \$\$FName"
 262     linuxdoc_to_dvi_command="sgml2latex -o dvi \$\$FName"
 263     linuxdoc_to_html_command="sgml2html \$\$FName"
 264     linuxdoc_to_lyx_command="sgml2lyx \$\$FName";;
 265   none)
 266     linuxdoc_to_latex_command="none"
 267     linuxdoc_to_dvi_command="none"
 268     linuxdoc_to_html_command="none"
 269     linuxdoc_to_lyx_command="none";;
 270 esac
 271
 272 # Search for DocBook support
 273 SEARCH_PROG([for SGML-tools 2.x (DocBook) or db2x scripts], DOCBOOK, sgmltools db2dvi)
 274 chk_docbook=no
 275 if test $DOCBOOK != none; then
 276   chk_docbook=yes
 277   docbook_cmd="\\def\\hasdocbook{yes}"
 278 fi
 279
 280 case $DOCBOOK in
 281   sgmltools)
 282     docbook_to_dvi_command="sgmltools -b dvi \$\$FName"
 283     docbook_to_html_command="sgmltools -b html \$\$FName";;
 284   db2dvi)
 285     docbook_to_dvi_command="db2dvi \$\$FName"
 286     docbook_to_html_command="db2html \$\$FName";;
 287   none)
 288     docbook_to_dvi_command="none"
 289     docbook_to_html_command="none";;
 290 esac
 291
 292 # Search for a spool command
 293 SEARCH_PROG([for a spool command], LPR, lp lpr)
 294 case $LPR in
 295   lp) print_spool_command=lp
 296       print_spool_printerprefix="-d ";;
 297  lpr) print_spool_command=lpr
 298       print_spool_printerprefix="-P";;
 299    *) :;; # leave to empty values
 300 esac
 301
 302 SEARCH_PROG([for a LaTeX -> HTML converter], TOHTML, tth latex2html hevea)
 303 latex_to_html_command = $TOHTML
 304 case $TOHTML in
 305         tth) latex_to_html_command="tth -t -e2 -L\$\$BaseName < \$\$FName > \$\$OutName";;
 306  latex2html) latex_to_html_command="latex2html -no_subdir -split 0 -show_section_numbers \$\$FName";;
 307       hevea) latex_to_html_command="hevea -s \$\$FName";;
 308 esac
 309
 310 #### Explore the LaTeX configuration
 311 MSG_CHECKING(LaTeX configuration)
 312 # First, remove the files that we want to re-create
 313 rm -f textclass.lst packages.lst chkconfig.sed
 314 if test ${lyx_check_config} = no ; then
 315   MSG_RESULT(default values)
 316 else
 317   MSG_RESULT(auto)
 318   rm -f wrap_chkconfig.ltx chkconfig.vars chkconfig.classes chklayouts.tex
 319   cat >wrap_chkconfig.ltx <<EOF
 320 \\newcommand\\srcdir{${srcdir}}
 321 ${linuxdoc_cmd}
 322 ${docbook_cmd}
 323 \\input{${srcdir}/chkconfig.ltx}
 324 EOF
 325   ## Construct the list of classes to test for.
 326   # build the list of available layout files and convert it to commands
 327   # for chkconfig.ltx
 328   for file in ./layouts/*.layout ${srcdir}/layouts/*.layout ; do
 329     case $file in
 330       */\*.layout) ;;
 331       *) test -r "$file" && echo $file ;;
 332     esac
 333   done | sed -e 's%^.*layouts/\(.*\)\.layout$%\\TestDocClass{\1}%'\
 334              > chklayouts.tex
 335 changequote([,])dnl
 336   [eval] ${LATEX} wrap_chkconfig.ltx 2>/dev/null | grep '^\+'
 337   [eval] `cat chkconfig.vars | sed 's/-/_/g'`
 338 changequote(,)dnl
 339 fi
 340
 341 # Do we have all the files we need? Useful if latex did not run
 342 changequote([,])dnl
 343 echo creating textclass.lst
 344 PROVIDE_DEFAULT_FILE(textclass.lst,dnl
 345 [# This file declares layouts and their associated definition files
 346 # (include dir. relative to the place where this file is).
 347 # It contains only default values, since chkconfig.ltx could not be run
 348 # for some reason. Run ./configure if you need to update it after a
 349 # configuration change.
 350 article article article
 351 report  report  report
 352 book    book    book
 353 linuxdoc        linuxdoc        linuxdoc
 354 letter  letter  letter])
 355
 356 PROVIDE_DEFAULT_FILE(chkconfig.sed,[s/@.*@/???/g])
 357
 358 echo creating packages.lst
 359 PROVIDE_DEFAULT_FILE(packages.lst,dnl
 360 [# This file should contain the list of LaTeX packages that have been
 361 # recognized by LyX. Unfortunately, since configure could not find
 362 # your LaTeX2e program, the tests have not been run. Run ./configure
 363 # if you need to update it after a configuration change.
 364 ])
 365 changequote(,)dnl
 366
 367 echo creating doc/LaTeXConfig.lyx
 368 echo "s/@chk_linuxdoc@/$chk_linuxdoc/g" >> chkconfig.sed
 369 echo "s/@chk_docbook@/$chk_docbook/g" >> chkconfig.sed
 370 sed -f chkconfig.sed ${srcdir}/doc/LaTeXConfig.lyx.in >doc/LaTeXConfig.lyx
 371
 372 echo creating lyxrc.defaults
 373 rm -f lyxrc.defaults
 374 cat >lyxrc.defaults <<EOF
 375 # This file has been automatically generated by LyX' lib/configure
 376 # script. It contains default settings that have been determined by
 377 # examining your system. PLEASE DO NOT MODIFY ANYTHING HERE! If you
 378 # want to customize LyX, make a copy of the file LYXDIR/lyxrc as
 379 # ~/.lyx/lyxrc and edit this file instead. Any setting in lyxrc will
 380 # override the values given here.
 381 \\Format latex  tex     LaTeX           L
 382 \\Format dvi    dvi     DVI             D
 383 \\Format ps     ps      Postscript      t
 384 \\Format pdf    pdf     PDF             P
 385 \\Format html   html    HTML            H
 386 \\Format text   txt     ASCII           A
 387 \\Format literate nw    NoWeb           W
 388 \\Format linuxdoc sgml  LinuxDoc        x
 389 \\Format docbook  sgml  DocBook         B
 390 \\Format program  run   Program         r
 391
 392 \\converter latex lyx "$tex_to_lyx_command" ""
 393 \\converter latex dvi "$LATEX" "latex,disable=linuxdoc&docbook"
 394 \\converter latex pdf "$PDFLATEX" "latex,disable=linuxdoc&docbook"
 395 \\converter latex html "$latex_to_html_command"
 396         "originaldir,needaux,disable=linuxdoc&docbook"
 397 \\converter literate lyx "$literate_to_lyx_command" ""
 398 \\converter literate latex "$literate_to_tex_command" ""
 399 \\converter dvi ps "$dvi_to_ps_command" ""
 400 \\converter ps pdf "$ps_to_pdf_command" ""
 401 \\converter linuxdoc lyx "$linuxdoc_to_lyx_command" ""
 402 \\converter linuxdoc latex "$linuxdoc_to_latex_command" ""
 403 \\converter linuxdoc dvi "$linuxdoc_to_dvi_command" ""
 404 \\converter linuxdoc html "$linuxdoc_to_html_command" ""
 405 \\converter docbook dvi "$docbook_to_dvi_command" ""
 406 \\converter docbook html "$docbook_to_html_command" ""
 407 \\converter html latex "$html_to_latex_command"
 408                        "disable=latex&literate&linuxdoc&docbook"
 409
 410 \converter gif eps "$image_command" ""
 411 \converter png eps "$image_command" ""
 412 \converter jpg eps "$image_command" ""
 413 \converter gif png "$image_command" ""
 414
 415 \\viewer dvi "$DVI_VIEWER"
 416 \\viewer html "$HTML_VIEWER"
 417 \\viewer pdf "$PDF_VIEWER"
 418 \\viewer ps "$GHOSTVIEW -swap"
 419 \\viewer eps "$GHOSTVIEW"
 420
 421 \\ps_command "$GS"
 422 \\ascii_roff_command "$ascii_roff_command"
 423 \\chktex_command "$chktex_command"
 424 \\spell_command "$SPELL"
 425 \\fax_command "$fax_command"
 426 \\print_spool_command "$print_spool_command"
 427 \\print_spool_printerprefix "$print_spool_printerprefix"
 428 \\font_encoding "$chk_fontenc"
 429 EOF
 430
 431 # Remove superfluous files if we are not writing in the main lib
 432 # directory
 433 for file in lyxrc.defaults textclass.lst packages.lst \
 434             doc/LaTeXConfig.lyx ; do
 435   # we rename the file first, so that we avoid comparing a file with itself
 436   mv $file $file.new
 437   if test -r $srcdir/$file && diff $file.new $srcdir/$file >/dev/null 2>/dev/null ;
 438   then
 439     echo "removing $file, which is identical to the system global version"
 440     rm -f $file.new
 441   else
 442     mv $file.new $file
 443   fi
 444 done
 445
 446
 447 # Final clean-up
 448 if test $lyx_keep_temps = no ; then
 449 rm -f chkconfig.sed chkconfig.vars wrap_chkconfig.* chklayouts.tex \
 450       missfont.log
 451 fi