lib/configure.m4

   1 #! /bin/sh
   2 dnl Use 'make' to create configure from this m4 script.
   3 # This script is a hand-made configure script. It contains a lot of
   4 # code stolen from GNU autoconf. I removed all the code that was not
   5 # useful for configuring a LyX installation.
   6
   7
   8 dnl ######### Begin M4 macros #########################################
   9 dnl This is a template for my stripped-down configure script.
  10 dnl First, a few convenient macros.
  11 changequote([,])dnl
  12 dnl
  13 dnl
  14 dnl MSG_CHECKING(FEATURE-DESCRIPTION,PREFIX)
  15 dnl
  16 define(MSG_CHECKING,
  17 [echo $ac_n "$2checking $1""... $ac_c"])dnl
  18 dnl
  19 dnl
  20 dnl MSG_RESULT(RESULT-DESCRIPTION)
  21 dnl
  22 define(MSG_RESULT,
  23 [echo "$ac_t""$1"])dnl
  24 dnl
  25 dnl
  26 dnl SEARCH_PROG(FEATURE-DESCRIPTION,VARIABLE-NAME,PROGRAMS-LIST,
  27 dnl             ACTION-IF-FOUND,ACTION-IF-NOT-FOUND)
  28 dnl
  29 define(SEARCH_PROG,[dnl
  30 changequote([,])dnl
  31 MSG_CHECKING($1)
  32 MSG_RESULT(($3))
  33 $2=
  34 for ac_prog in $3
  35 do
  36 # Extract the first word of "$ac_prog", so it can be a program name with args.
  37 set dummy $ac_prog ; ac_word=$[2]
  38 if test -n "$ac_word"; then
  39   MSG_CHECKING([for \"$ac_word\"],[+])
  40   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS=":"
  41   for ac_dir in $PATH; do
  42     test -z "$ac_dir" && ac_dir=.
  43     if test -x [$ac_dir/$ac_word]; then
  44       $2="$ac_prog"
  45       break
  46     fi
  47   done
  48   IFS="$ac_save_ifs"
  49
  50   if test -n "[$]$2"; then
  51     ac_result=yes
  52   else
  53     ac_result=no
  54   fi
  55   ifelse($4,,,[$4])
  56   MSG_RESULT($ac_result)
  57   test -n "[$]$2" && break
  58 fi
  59 done
  60
  61 if test -z "[$]$2" ; then
  62   $2=none
  63 ifelse($5,,,[  $5
  64 ])dnl
  65 fi
  66 changequote(,)dnl
  67 ])dnl
  68 dnl
  69 dnl
  70 dnl PROVIDE_DEFAULT_FILE(FILE, DEFAULT-VALUE)
  71 dnl
  72 define(PROVIDE_DEFAULT_FILE,[dnl
  73 # if $1 does not exist (because LaTeX did not run),
  74 # then provide a standard version.
  75 if test ! -f $1 ; then
  76   cat >$1 <<EOF
  77 $2
  78 EOF
  79 fi])
  80 changequote(,)dnl
  81 dnl ######### End M4 macros #############################################
  82
  83
  84 ####some configuration variables
  85 lyx_check_config=yes
  86 lyx_keep_temps=no
  87 srcdir=
  88
  89 #### Parse the command line
  90 for ac_option do
  91   case "$ac_option" in
  92     -help | --help | -h)
  93       cat << EOF
  94 Usage: configure [options]
  95 Options:
  96   --help                   show this help lines
  97   --keep-temps             keep temporary files (for debug. purposes)
  98   --without-latex-config   do not run LaTeX to determine configuration
  99 EOF
 100       exit 0;;
 101     --without-latex-config)
 102       lyx_check_config=no ;;
 103     --keep-temps)
 104       lyx_keep_temps=yes ;;
 105   esac
 106 done
 107
 108
 109 #### Checking for some echo oddities
 110 if (echo "testing\c"; echo 1,2,3) | grep c >/dev/null; then
 111   # Stardent Vistra SVR4 grep lacks -e, says ghazi@caip.rutgers.edu.
 112   if (echo -n testing; echo 1,2,3) | sed s/-n/xn/ | grep xn >/dev/null; then
 113     ac_n= ac_c='
 114 ' ac_t='        '
 115   else
 116     ac_n=-n ac_c= ac_t=
 117   fi
 118 else
 119   ac_n= ac_c='\c' ac_t=
 120 fi
 121
 122
 123 #### I do not really know why this is useful, but we might as well keep it.
 124 # NLS nuisances.
 125 # Only set these to C if already set.  These must not be set unconditionally
 126 # because not all systems understand e.g. LANG=C (notably SCO).
 127 # Fixing LC_MESSAGES prevents Solaris sh from translating var values in `set'!
 128 # Non-C LC_CTYPE values break the ctype check.
 129 if test "${LANG+set}"   = set; then LANG=C;   export LANG;   fi
 130 if test "${LC_ALL+set}" = set; then LC_ALL=C; export LC_ALL; fi
 131 if test "${LC_MESSAGES+set}" = set; then LC_MESSAGES=C; export LC_MESSAGES; fi
 132 if test "${LC_CTYPE+set}"    = set; then LC_CTYPE=C;    export LC_CTYPE;    fi
 133
 134
 135 #### Guess the directory in which configure is located.
 136 changequote([,])dnl
 137 ac_prog=[$]0
 138 changequote(,)dnl
 139 srcdir=`echo $ac_prog|sed 's%/[^/][^/]*$%%'`
 140 srcdir=`echo "${srcdir}" | sed 's%\([^/]\)/*$%\1%'`
 141 test "x$srcdir" = "x$ac_prog" && srcdir=.
 142 if test ! -r ${srcdir}/chkconfig.ltx ; then
 143   echo "configure: error: cannot find chkconfig.ltx script"
 144   exit 1
 145 fi
 146
 147
 148 #### Create the build directories if necessary
 149 for dir in bind clipart doc examples images kbd layouts reLyX \
 150     scripts templates ui ; do
 151   test ! -d $dir && mkdir $dir
 152 done
 153
 154
 155 #### Searching some useful programs
 156 define(CHECKLATEX2E,[
 157 ## Check whether this is really LaTeX2e
 158 rm -f chklatex.ltx
 159 cat >chklatex.ltx <<EOF
 160 \\nonstopmode\\makeatletter
 161 \\ifx\\undefined\\documentclass\\else
 162   \\message{ThisIsLaTeX2e}
 163 \\fi
 164 \\@@end
 165 EOF
 166 if eval ${LATEX} chklatex.ltx </dev/null 2>/dev/null \
 167                        | grep 'ThisIsLaTeX2e' >/dev/null; then
 168   :
 169 else
 170   LATEX=
 171   ac_result="not useable"
 172 fi
 173 rm -f chklatex.ltx chklatex.log])dnl
 174 dnl
 175 # Search LaTeX2e
 176 SEARCH_PROG([for a LaTeX2e program],LATEX,latex latex2e,CHECKLATEX2E,dnl
 177   [lyx_check_config=no])
 178 if test x$lyx_check_config != x ; then
 179 SEARCH_PROG([for the pdflatex program],PDFLATEX,pdflatex,CHECKLATEX2E)
 180 fi
 181
 182 # Search for an installed reLyX or a ready-to-install one
 183 save_PATH=${PATH}
 184 PATH=${PATH}:./reLyX/
 185 SEARCH_PROG([for reLyX LaTeX-to-LyX translator],RELYX,reLyX)
 186 PATH=${save_PATH}
 187
 188 # Search something to process a literate document
 189 SEARCH_PROG([for a Literate programming processor],LITERATE,"noweave -delay -index \$\$FName > \$\$OutName")
 190 if test "$LITERATE" = "none"; then LITERATE_EXT="none"; else LITERATE_EXT="nw"; fi
 191
 192 # Search for a Postscript interpreter
 193 SEARCH_PROG([for a Postscript interpreter],GS, gs)
 194
 195 # Search something to preview postscript
 196 SEARCH_PROG([for a Postscript previewer],GHOSTVIEW,gv ghostview)
 197
 198 # Search for a program to preview pdf
 199 SEARCH_PROG([for a PDF preview],PDF_VIEWER,xpdf acroread gv ghostview)
 200
 201 # Search something to preview dvi
 202 SEARCH_PROG([for a DVI previewer],DVI_VIEWER, xdvi)
 203
 204 # Search something to preview html
 205 SEARCH_PROG([for a HTML previewer],HTML_VIEWER, netscape)
 206
 207 # Search for a program to convert ps to pdf
 208 SEARCH_PROG([for a PS to PDF converter],ps_to_pdf_command,ps2pdf)
 209 test $ps_to_pdf_command = "ps2pdf" && ps_to_pdf_command="ps2pdf \$\$FName"
 210
 211 # Search for a program to convert dvi to ps
 212 SEARCH_PROG([for a DVI to PS converter],dvi_to_ps_command,dvips)
 213 test $dvi_to_ps_command = "dvips" && dvi_to_ps_command="dvips -o \$\$OutName \$\$FName"
 214
 215 # Search a *roff program (used to translate tables in ASCII export)
 216 SEARCH_PROG([for a *roff formatter],ROFF,groff nroff)
 217 ascii_roff_command=$ROFF
 218 test $ROFF = "groff" && ascii_roff_command="groff -t -Tlatin1 \$\$FName"
 219 test $ROFF = "nroff" && ascii_roff_command="tbl \$\$FName | nroff"
 220
 221 # Search the ChkTeX program
 222 SEARCH_PROG([for ChkTeX],CHKTEX,chktex)
 223 chktex_command=$CHKTEX
 224 test $CHKTEX = "chktex" && chktex_command="$CHKTEX -n1 -n3 -n6 -n9 -n22 -n25 -n30 -n38"
 225
 226 # Search for a spellchecker
 227 SEARCH_PROG([for a spell-checker], SPELL,ispell)
 228
 229 # Search a Fax handling program
 230 SEARCH_PROG([for a fax driver], FAX, sendfax faxsend fax)
 231 if test $FAX = sendfax ; then
 232   fax_command="sendfax -n -h '\$\$Host' -c '\$\$Comment' -x '\$\$Enterprise' -d '\$\$Name'@'\$\$Phone' '\$\$FName'"
 233 elif test $FAX = faxsend ; then
 234   fax_command="faxsend '\$\$Phone' '\$\$FName'"
 235 elif test $FAX = fax ; then
 236   fax_command="fax send '\$\$Phone' '\$\$FName'"
 237 else
 238   fax_command="none"
 239 fi
 240
 241 # Search for LinuxDoc support
 242 SEARCH_PROG([for SGML-tools 1.x (LinuxDoc)], LINUXDOC, sgml2lyx)
 243 chk_linuxdoc=no
 244 if test $LINUXDOC != none; then
 245   chk_linuxdoc=yes
 246   linuxdoc_cmd="\\def\\haslinuxdoc{yes}"
 247 fi
 248
 249 case $LINUXDOC in
 250   sgml2lyx)
 251     linuxdoc_to_latex_command="sgml2latex \$\$FName"
 252     linuxdoc_to_dvi_command="sgml2latex -o dvi \$\$FName"
 253     linuxdoc_to_html_command="sgml2html \$\$FName"
 254     linuxdoc_to_lyx_command="sgml2lyx";;
 255   none)
 256     linuxdoc_to_latex_command="none"
 257     linuxdoc_to_dvi_command="none"
 258     linuxdoc_to_html_command="none"
 259     linuxdoc_to_lyx_command="none";;
 260 esac
 261
 262 # Search for DocBook support
 263 SEARCH_PROG([for SGML-tools 2.x (DocBook) or db2x scripts], DOCBOOK, sgmltools db2dvi)
 264 chk_docbook=no
 265 if test $DOCBOOK != none; then
 266   chk_docbook=yes
 267   docbook_cmd="\\def\\hasdocbook{yes}"
 268 fi
 269
 270 case $DOCBOOK in
 271   sgmltools)
 272     docbook_to_dvi_command="sgmltools -b dvi \$\$FName"
 273     docbook_to_html_command="sgmltools -b html \$\$FName";;
 274   db2dvi)
 275     docbook_to_dvi_command="db2dvi \$\$FName"
 276     docbook_to_html_command="db2html \$\$FName";;
 277   none)
 278     docbook_to_dvi_command="none"
 279     docbook_to_html_command="none";;
 280 esac
 281
 282 # Search for a spool command
 283 SEARCH_PROG([for a spool command], LPR, lp lpr)
 284 case $LPR in
 285   lp) print_spool_command=lp
 286       print_spool_printerprefix="-d ";;
 287  lpr) print_spool_command=lpr
 288       print_spool_printerprefix="-P";;
 289    *) :;; # leave to empty values
 290 esac
 291
 292 # Search for a latex to html converter
 293 SEARCH_PROG([for an HTML converter], TOHTML, tth latex2html hevea)
 294 latex_to_html_command = $TOHTML
 295 case $TOHTML in
 296         tth) latex_to_html_command="tth -t -e2 -L\$\$BaseName < \$\$FName > \$\$OutName";;
 297  latex2html) latex_to_html_command="latex2html -no_subdir -split 0 -show_section_numbers \$\$FName";;
 298       hevea) latex_to_html_command="hevea -s \$\$FName";;
 299 esac
 300
 301 #### Explore the LaTeX configuration
 302 MSG_CHECKING(LaTeX configuration)
 303 # First, remove the files that we want to re-create
 304 rm -f textclass.lst packages.lst chkconfig.sed
 305 if test ${lyx_check_config} = no ; then
 306   MSG_RESULT(default values)
 307 else
 308   MSG_RESULT(auto)
 309   rm -f wrap_chkconfig.ltx chkconfig.vars chkconfig.classes chklayouts.tex
 310   cat >wrap_chkconfig.ltx <<EOF
 311 \\newcommand\\srcdir{${srcdir}}
 312 ${linuxdoc_cmd}
 313 ${docbook_cmd}
 314 \\input{${srcdir}/chkconfig.ltx}
 315 EOF
 316   ## Construct the list of classes to test for.
 317   # build the list of available layout files and convert it to commands
 318   # for chkconfig.ltx
 319   for file in ./layouts/*.layout ${srcdir}/layouts/*.layout ; do
 320     case $file in
 321       */\*.layout) ;;
 322       *) test -r "$file" && echo $file ;;
 323     esac
 324   done | sed -e 's%^.*layouts/\(.*\)\.layout$%\\TestDocClass{\1}%'\
 325              > chklayouts.tex
 326 changequote([,])dnl
 327   [eval] ${LATEX} wrap_chkconfig.ltx 2>/dev/null | grep '^\+'
 328   [eval] `cat chkconfig.vars | sed 's/-/_/g'`
 329 changequote(,)dnl
 330 fi
 331
 332 # Do we have all the files we need? Useful if latex did not run
 333 changequote([,])dnl
 334 echo creating textclass.lst
 335 PROVIDE_DEFAULT_FILE(textclass.lst,dnl
 336 [# This file declares layouts and their associated definition files
 337 # (include dir. relative to the place where this file is).
 338 # It contains only default values, since chkconfig.ltx could not be run
 339 # for some reason. Run ./configure if you need to update it after a
 340 # configuration change.
 341 article article article
 342 report  report  report
 343 book    book    book
 344 linuxdoc        linuxdoc        linuxdoc
 345 letter  letter  letter])
 346
 347 PROVIDE_DEFAULT_FILE(chkconfig.sed,[s/@.*@/???/g])
 348
 349 echo creating packages.lst
 350 PROVIDE_DEFAULT_FILE(packages.lst,dnl
 351 [# This file should contain the list of LaTeX packages that have been
 352 # recognized by LyX. Unfortunately, since configure could not find
 353 # your LaTeX2e program, the tests have not been run. Run ./configure
 354 # if you need to update it after a configuration change.
 355 ])
 356 changequote(,)dnl
 357
 358 echo creating doc/LaTeXConfig.lyx
 359 echo "s/@chk_linuxdoc@/$chk_linuxdoc/g" >> chkconfig.sed
 360 echo "s/@chk_docbook@/$chk_docbook/g" >> chkconfig.sed
 361 sed -f chkconfig.sed ${srcdir}/doc/LaTeXConfig.lyx.in >doc/LaTeXConfig.lyx
 362
 363 echo creating lyxrc.defaults
 364 rm -f lyxrc.defaults
 365 cat >lyxrc.defaults <<EOF
 366 # This file has been automatically generated by LyX' lib/configure
 367 # script. It contains default settings that have been determined by
 368 # examining your system. PLEASE DO NOT MODIFY ANYTHING HERE! If you
 369 # want to customize LyX, make a copy of the file LYXDIR/lyxrc as
 370 # ~/.lyx/lyxrc and edit this file instead. Any setting in lyxrc will
 371 # override the values given here.
 372 \\converter tex dvi "$LATEX" ""
 373 \\converter tex pdf "$PDFLATEX" ""
 374 \\converter dvi ps "$dvi_to_ps_command" ""
 375 \\converter ps pdf "$ps_to_pdf_command" ""
 376 \\converter sgml tex "$linuxdoc_to_latex_command" ""
 377 \\converter sgml dvi "$linuxdoc_to_dvi_command" ""
 378 \\converter sgml html "$linuxdoc_to_html_command" ""
 379 \\converter docbook dvi "$docbook_to_dvi_command" ""
 380 \\converter docbook html "$docbook_to_html_command" ""
 381 \\converter tex html "$latex_to_html_command"
 382         "originaldir,needaux"
 383 \\converter $LITERATE_EXT tex "$LITERATE" ""
 384
 385 \\viewer dvi "$DVI_VIEWER"
 386 \\viewer html "$HTML_VIEWER"
 387 \\viewer pdf "$PDF_VIEWER"
 388 \\viewer ps "$GHOSTVIEW -swap"
 389 \\viewer eps "$GHOSTVIEW"
 390
 391 \\relyx_command "$RELYX"
 392 \\linuxdoc_to_lyx_command "$linuxdoc_to_lyx_command"
 393 \\literate_extension "$LITERATE_EXT"
 394 \\ps_command "$GS"
 395 \\ascii_roff_command "$ascii_roff_command"
 396 \\chktex_command "$chktex_command"
 397 \\spell_command "$SPELL"
 398 \\fax_command "$fax_command"
 399 \\print_spool_command "$print_spool_command"
 400 \\print_spool_printerprefix "$print_spool_printerprefix"
 401 \\font_encoding "$chk_fontenc"
 402 EOF
 403
 404 # Remove superfluous files if we are not writing in the main lib
 405 # directory
 406 for file in lyxrc.defaults textclass.lst packages.lst \
 407             doc/LaTeXConfig.lyx ; do
 408   # we rename the file first, so that we avoid comparing a file with itself
 409   mv $file $file.new
 410   if test -r $srcdir/$file && diff $file.new $srcdir/$file >/dev/null 2>/dev/null ;
 411   then
 412     echo "removing $file, which is identical to the system global version"
 413     rm -f $file.new
 414   else
 415     mv $file.new $file
 416   fi
 417 done
 418
 419
 420 # Final clean-up
 421 if test $lyx_keep_temps = no ; then
 422 rm -f chkconfig.sed chkconfig.vars wrap_chkconfig.* chklayouts.tex \
 423       missfont.log
 424 fi