lib/configure.m4

   1 #! /bin/sh
   2 dnl Use 'make' to create configure from this m4 script.
   3 # This script is a hand-made configure script. It contains a lot of
   4 # code stolen from GNU autoconf. I removed all the code that was not
   5 # useful for configuring a LyX installation.
   6
   7
   8 dnl ######### Begin M4 macros #########################################
   9 dnl This is a template for my stripped-down configure script.
  10 dnl First, a few convenient macros.
  11 changequote([,])dnl
  12 dnl
  13 dnl
  14 dnl MSG_CHECKING(FEATURE-DESCRIPTION,PREFIX)
  15 dnl
  16 define(MSG_CHECKING,
  17 [echo $ac_n "$2checking $1""... $ac_c"])dnl
  18 dnl
  19 dnl
  20 dnl MSG_RESULT(RESULT-DESCRIPTION)
  21 dnl
  22 define(MSG_RESULT,
  23 [echo "$ac_t""$1"])dnl
  24 dnl
  25 dnl
  26 dnl SEARCH_PROG(FEATURE-DESCRIPTION,VARIABLE-NAME,PROGRAMS-LIST,
  27 dnl             ACTION-IF-FOUND,ACTION-IF-NOT-FOUND)
  28 dnl
  29 define(SEARCH_PROG,[dnl
  30 changequote([,])dnl
  31 MSG_CHECKING($1)
  32 MSG_RESULT(($3))
  33 $2=
  34 for ac_prog in $3
  35 do
  36 # Extract the first word of "$ac_prog", so it can be a program name with args.
  37 set dummy $ac_prog ; ac_word=$[2]
  38 if test -n "$ac_word"; then
  39   MSG_CHECKING([for \"$ac_word\"],[+])
  40   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS=":"
  41   for ac_dir in $PATH; do
  42     test -z "$ac_dir" && ac_dir=.
  43     if test -x [$ac_dir/$ac_word]; then
  44       $2="$ac_prog"
  45       break
  46     fi
  47   done
  48   IFS="$ac_save_ifs"
  49
  50   if test -n "[$]$2"; then
  51     ac_result=yes
  52     ifelse($4,,,[$4])
  53   else
  54     ac_result=no
  55   fi
  56   MSG_RESULT($ac_result)
  57   test -n "[$]$2" && break
  58 fi
  59 done
  60
  61 if test -z "[$]$2" ; then
  62   $2=none
  63 ifelse($5,,,[  $5
  64 ])dnl
  65 fi
  66 changequote(,)dnl
  67 ])dnl
  68 dnl
  69 dnl
  70 dnl LYXRC_VAR(VARIABLE_NAME, VALUE)
  71 define(LYXRC_VAR,[dnl
  72 rc_entries="$rc_entries
  73 $1 \"$2\""])
  74 dnl
  75 dnl
  76 dnl LYXRC_PROG(FEATURE-DESCRIPTION,VARIABLE-NAME,PROGRAMS-LIST,
  77 dnl             ACTION-IF-FOUND,ACTION-IF-NOT-FOUND)
  78 define(LYXRC_PROG,[dnl
  79 SEARCH_PROG($1,prog,$3,$4,$5)
  80 LYXRC_VAR($2,$prog)])
  81 dnl
  82 dnl
  83 dnl PROVIDE_DEFAULT_FILE(FILE, DEFAULT-VALUE)
  84 dnl
  85 define(PROVIDE_DEFAULT_FILE,[dnl
  86 # if $1 does not exist (because LaTeX did not run),
  87 # then provide a standard version.
  88 if test ! -f $1 ; then
  89   cat >$1 <<EOF
  90 $2
  91 EOF
  92 fi])
  93 changequote(,)dnl
  94 dnl ######### End M4 macros #############################################
  95
  96
  97 ####some configuration variables
  98 outfile=lyxrc.defaults
  99 rc_entries=
 100 lyx_check_config=yes
 101 lyx_keep_temps=no
 102 srcdir=
 103 version_suffix=
 104
 105 #### Parse the command line
 106 for ac_option do
 107   case "$ac_option" in
 108     -help | --help | -h)
 109       cat << EOF
 110 Usage: configure [options]
 111 Options:
 112   --help                   show this help lines
 113   --keep-temps             keep temporary files (for debug. purposes)
 114   --without-latex-config   do not run LaTeX to determine configuration
 115   --with-version-suffix=suffix suffix of binary installed files
 116 EOF
 117       exit 0;;
 118     --without-latex-config)
 119       lyx_check_config=no ;;
 120     --keep-temps)
 121       lyx_keep_temps=yes ;;
 122     --with-version-suffix*)
 123       version_suffix=`echo "$ac_option" | sed 's,--with-version-suffix=,,'`
 124   esac
 125 done
 126
 127
 128 #### Checking for some echo oddities
 129 if (echo "testing\c"; echo 1,2,3) | grep c >/dev/null; then
 130   # Stardent Vistra SVR4 grep lacks -e, says ghazi@caip.rutgers.edu.
 131   if (echo -n testing; echo 1,2,3) | sed s/-n/xn/ | grep xn >/dev/null; then
 132     ac_n= ac_c='
 133 ' ac_t='        '
 134   else
 135     ac_n=-n ac_c= ac_t=
 136   fi
 137 else
 138   ac_n= ac_c='\c' ac_t=
 139 fi
 140
 141
 142 #### I do not really know why this is useful, but we might as well keep it.
 143 # NLS nuisances.
 144 # Only set these to C if already set.  These must not be set unconditionally
 145 # because not all systems understand e.g. LANG=C (notably SCO).
 146 # Fixing LC_MESSAGES prevents Solaris sh from translating var values in `set'!
 147 # Non-C LC_CTYPE values break the ctype check.
 148 if test "${LANG+set}"   = set; then LANG=C;   export LANG;   fi
 149 if test "${LC_ALL+set}" = set; then LC_ALL=C; export LC_ALL; fi
 150 if test "${LC_MESSAGES+set}" = set; then LC_MESSAGES=C; export LC_MESSAGES; fi
 151 if test "${LC_CTYPE+set}"    = set; then LC_CTYPE=C;    export LC_CTYPE;    fi
 152
 153
 154 #### Guess the directory in which configure is located.
 155 changequote([,])dnl
 156 ac_prog=[$]0
 157 changequote(,)dnl
 158 srcdir=`echo $ac_prog|sed 's%/[^/][^/]*$%%'`
 159 srcdir=`echo "${srcdir}" | sed 's%\([^/]\)/*$%\1%'`
 160 test "x$srcdir" = "x$ac_prog" && srcdir=.
 161 if test ! -r ${srcdir}/chkconfig.ltx ; then
 162   echo "configure: error: cannot find chkconfig.ltx script"
 163   exit 1
 164 fi
 165
 166 #### Adjust PATH for Win32 (Cygwin)
 167 if test "x$OSTYPE" = xcygwin; then
 168   echo "configure: cygwin detected; path correction"
 169   srcdir=`cygpath -w "${srcdir}" | tr '\\\\' /`
 170   echo "srcdir=${srcdir}"
 171 fi
 172
 173 #### Create the build directories if necessary
 174 for dir in bind clipart doc examples help images kbd layouts reLyX \
 175     scripts templates ui xfonts; do
 176   test ! -d $dir && mkdir $dir
 177 done
 178
 179
 180 #### Searching some useful programs
 181 define(CHECKLATEX2E,[
 182 ## Check whether this is really LaTeX2e
 183 rm -f chklatex.ltx
 184 cat >chklatex.ltx <<EOF
 185 \\nonstopmode\\makeatletter
 186 \\ifx\\undefined\\documentclass\\else
 187   \\message{ThisIsLaTeX2e}
 188 \\fi
 189 \\@@end
 190 EOF
 191 if eval ${LATEX} chklatex.ltx </dev/null 2>/dev/null \
 192                        | grep 'ThisIsLaTeX2e' >/dev/null; then
 193   :
 194 else
 195   LATEX=
 196   ac_result="not useable"
 197 fi
 198 rm -f chklatex.ltx chklatex.log])dnl
 199 dnl
 200 # Search LaTeX2e
 201 SEARCH_PROG([for a LaTeX2e program],LATEX,latex latex2e,CHECKLATEX2E,dnl
 202   [lyx_check_config=no])
 203 latex_to_dvi=$LATEX
 204 test -z "$latex_to_dvi" && latex_to_dvi="none"
 205
 206 # Search for pdflatex
 207 if test ${lyx_check_config} = no ; then
 208   latex_to_pdf=none
 209 else
 210   SEARCH_PROG([for the pdflatex program],latex_to_pdf,pdflatex)
 211 fi
 212
 213 test $latex_to_dvi != "none" && latex_to_dvi="$latex_to_dvi \$\$i"
 214 test $latex_to_pdf != "none" && latex_to_pdf="$latex_to_pdf \$\$i"
 215
 216 # Search for an installed reLyX or a ready-to-install one
 217 save_PATH=${PATH}
 218 PATH=${PATH}:./reLyX/
 219 SEARCH_PROG([for a LaTeX -> LyX converter],tex_to_lyx_command,reLyX)
 220 PATH=${save_PATH}
 221 test $tex_to_lyx_command = "reLyX" && tex_to_lyx_command="reLyX -f \$\$i"
 222 tex_to_lyx_command=`echo $tex_to_lyx_command | sed "s,reLyX,reLyX$version_suffix,"`
 223
 224 SEARCH_PROG([for a Noweb -> LyX converter],literate_to_lyx_command,noweb2lyx)
 225 test $literate_to_lyx_command = "noweb2lyx" && literate_to_lyx_command="noweb2lyx \$\$i \$\$o"
 226 literate_to_lyx_command=`echo $literate_to_lyx_command | sed "s,noweb2lyx,noweb2lyx$version_suffix,"`
 227
 228 # Search something to process a literate document
 229 SEARCH_PROG([for a Noweb -> LaTeX converter],literate_to_tex_command,noweave)
 230 test $literate_to_tex_command = "noweave" && literate_to_tex_command="noweave -delay -index \$\$i > \$\$o"
 231
 232 SEARCH_PROG([for a HTML -> Latex converter],html_to_latex_command,html2latex)
 233 test $html_to_latex_command = "html2latex" && html_to_latex_command="html2latex \$\$i"
 234
 235 SEARCH_PROG([for a MSWord -> Latex converter],word_to_latex_command,wvCleanLatex word2x)
 236 test "$word_to_latex_command" = "wvCleanLatex" && word_to_latex_command="wvCleanLatex \$\$i \$\$o"
 237 test "$word_to_latex_command" = "word2x" && word_to_latex_command="word2x -f latex \$\$i"
 238
 239 SEARCH_PROG([for Image converter],image_command,convert)
 240 test $image_command = "convert" && image_command="convert \$\$i \$\$o"
 241
 242 # Search for a Postscript interpreter
 243 LYXRC_PROG([for a Postscript interpreter], \ps_command, gs)
 244
 245 # Search something to preview postscript
 246 SEARCH_PROG([for a Postscript previewer],GHOSTVIEW,gv ghostview)
 247
 248 # Search for a program to preview pdf
 249 SEARCH_PROG([for a PDF preview],PDF_VIEWER,acroread gv ghostview xpdf)
 250
 251 # Search something to preview dvi
 252 SEARCH_PROG([for a DVI previewer],DVI_VIEWER, xdvi windvi yap)
 253
 254 # Search something to preview html
 255 SEARCH_PROG([for a HTML previewer],HTML_VIEWER, netscape)
 256
 257 # Search for a program to preview latex code
 258 SEARCH_PROG([for a LaTeX preview],LATEX_VIEWER, "xterm -e less")
 259
 260 # Search for a program to convert ps to pdf
 261 SEARCH_PROG([for a PS to PDF converter],ps_to_pdf_command,ps2pdf)
 262 test $ps_to_pdf_command = "ps2pdf" && ps_to_pdf_command="ps2pdf \$\$i"
 263
 264 # Search for a program to convert dvi to ps
 265 SEARCH_PROG([for a DVI to PS converter],dvi_to_ps_command,dvips)
 266 test $dvi_to_ps_command = "dvips" && dvi_to_ps_command="dvips -o \$\$o \$\$i"
 267
 268 # Search for a program to convert dvi to pdf
 269 SEARCH_PROG([for a DVI to PDF converter],dvi_to_pdf_command,dvipdfm)
 270 test $dvi_to_pdf_command = "dvipdfm" && dvi_to_pdf_command="dvipdfm \$\$i"
 271
 272 # Search for a program to convert previewlyx to eps
 273 SEARCH_PROG([for a LyX preview converter],lyxpreview_to_xpm_command,lyxpreview2xpm.sh)
 274 test $lyxpreview_to_xpm_command = "lyxpreview2xpm.sh" && lyxpreview_to_xpm_command="lyxpreview2xpm.sh \$\$i \$\$o"
 275
 276 # Search a *roff program (used to translate tables in ASCII export)
 277 LYXRC_PROG([for a *roff formatter], \ascii_roff_command, dnl
 278   'groff -t -Tlatin1 $$FName' nroff,dnl
 279   test "$prog" = "nroff" && prog='tbl $$FName | nroff')
 280
 281 # Search the ChkTeX program
 282 LYXRC_PROG([for ChkTeX], \chktex_command,dnl
 283    "chktex -n1 -n3 -n6 -n9 -n22 -n25 -n30 -n38")
 284
 285 # Search for a spellchecker
 286 LYXRC_PROG([for a spell-checker], \spell_command, ispell)
 287
 288 dnl # Search a Fax handling program
 289 dnl SEARCH_PROG([for a fax driver], FAX, sendfax faxsend fax)
 290 dnl if test $FAX = sendfax ; then
 291 dnl   fax_command="sendfax -n -h '\$\$Host' -c '\$\$Comment' -x '\$\$Enterprise' -d '\$\$Name'@'\$\$Phone' '\$\$FName'"
 292 dnl elif test $FAX = faxsend ; then
 293 dnl   fax_command="faxsend '\$\$Phone' '\$\$FName'"
 294 dnl elif test $FAX = fax ; then
 295 dnl   fax_command="fax send '\$\$Phone' '\$\$FName'"
 296 dnl else
 297 dnl   fax_command="none"
 298 dnl fi
 299
 300 # Search a GUI Fax program
 301 SEARCH_PROG([for a fax program], fax_command, ksendfax)
 302 test $fax_command = "ksendfax" && fax_command="ksendfax \$\$i"
 303
 304 # Search for LinuxDoc support
 305 SEARCH_PROG([for SGML-tools 1.x (LinuxDoc)], LINUXDOC, sgml2lyx)
 306 chk_linuxdoc=no
 307 if test $LINUXDOC != none; then
 308   chk_linuxdoc=yes
 309   linuxdoc_cmd="\\def\\haslinuxdoc{yes}"
 310 fi
 311
 312 case $LINUXDOC in
 313   sgml2lyx)
 314     linuxdoc_to_latex_command="sgml2latex \$\$i"
 315     linuxdoc_to_dvi_command="sgml2latex -o dvi \$\$i"
 316     linuxdoc_to_html_command="sgml2html \$\$i"
 317     linuxdoc_to_lyx_command="sgml2lyx \$\$i";;
 318   none)
 319     linuxdoc_to_latex_command="none"
 320     linuxdoc_to_dvi_command="none"
 321     linuxdoc_to_html_command="none"
 322     linuxdoc_to_lyx_command="none";;
 323 esac
 324
 325 # Search for DocBook support
 326 SEARCH_PROG([for SGML-tools 2.x (DocBook) or db2x scripts], DOCBOOK, sgmltools db2dvi)
 327 chk_docbook=no
 328 if test $DOCBOOK != none; then
 329   chk_docbook=yes
 330   docbook_cmd="\\def\\hasdocbook{yes}"
 331 fi
 332
 333 case $DOCBOOK in
 334   sgmltools)
 335     docbook_to_dvi_command="sgmltools -b dvi \$\$i"
 336     docbook_to_html_command="sgmltools -b html \$\$i";;
 337   db2dvi)
 338     docbook_to_dvi_command="db2dvi \$\$i"
 339     docbook_to_html_command="db2html \$\$i";;
 340   none)
 341     docbook_to_dvi_command="none"
 342     docbook_to_html_command="none";;
 343 esac
 344
 345 # Search for a spool command
 346 LYXRC_PROG([for a spool command], \print_spool_command, lp lpr)
 347 case $prog in
 348   lp) print_spool_printerprefix="-d ";;
 349  lpr) print_spool_printerprefix="-P";;
 350    *) :;; # leave to empty values
 351 esac
 352 LYXRC_VAR(\print_spool_printerprefix, $print_spool_printerprefix)
 353
 354 SEARCH_PROG([for a LaTeX -> HTML converter], TOHTML, tth latex2html hevea)
 355 latex_to_html_command=$TOHTML
 356 case $TOHTML in
 357         tth) latex_to_html_command="tth -t -e2 -L\$\$b < \$\$i > \$\$o";;
 358  latex2html) latex_to_html_command="latex2html -no_subdir -split 0 -show_section_numbers \$\$i";;
 359       hevea) latex_to_html_command="hevea -s \$\$i";;
 360 esac
 361
 362 #### Explore the LaTeX configuration
 363 MSG_CHECKING(LaTeX configuration)
 364 # First, remove the files that we want to re-create
 365 rm -f textclass.lst packages.lst chkconfig.sed
 366 if test ${lyx_check_config} = no ; then
 367   MSG_RESULT(default values)
 368 else
 369   MSG_RESULT(auto)
 370   rm -f wrap_chkconfig.ltx chkconfig.vars chkconfig.classes chklayouts.tex
 371   cat >wrap_chkconfig.ltx <<EOF
 372 \\newcommand\\srcdir{${srcdir}}
 373 ${linuxdoc_cmd}
 374 ${docbook_cmd}
 375 \\input{${srcdir}/chkconfig.ltx}
 376 EOF
 377   ## Construct the list of classes to test for.
 378   # build the list of available layout files and convert it to commands
 379   # for chkconfig.ltx
 380   for file in ./layouts/*.layout ${srcdir}/layouts/*.layout ; do
 381     case $file in
 382       */\*.layout) ;;
 383       *) test -r "$file" && echo $file ;;
 384     esac
 385   done | sed -e 's%^.*layouts/\(.*\)\.layout$%\\TestDocClass{\1}%'\
 386              > chklayouts.tex
 387 changequote([,])dnl
 388   [eval] ${LATEX} wrap_chkconfig.ltx 2>/dev/null | grep '^\+'
 389   [eval] `cat chkconfig.vars | sed 's/-/_/g'`
 390 changequote(,)dnl
 391 fi
 392
 393 # Do we have all the files we need? Useful if latex did not run
 394 changequote([,])dnl
 395 echo "creating textclass.lst"
 396 PROVIDE_DEFAULT_FILE(textclass.lst,dnl
 397 [# This file declares layouts and their associated definition files
 398 # (include dir. relative to the place where this file is).
 399 # It contains only default values, since chkconfig.ltx could not be run
 400 # for some reason. Run ./configure if you need to update it after a
 401 # configuration change.
 402 article article article
 403 report  report  report
 404 book    book    book
 405 linuxdoc        linuxdoc        linuxdoc
 406 letter  letter  letter])
 407
 408 PROVIDE_DEFAULT_FILE(chkconfig.sed,[s/@.*@/???/g])
 409
 410 echo "creating packages.lst"
 411 PROVIDE_DEFAULT_FILE(packages.lst,dnl
 412 [# This file should contain the list of LaTeX packages that have been
 413 # recognized by LyX. Unfortunately, since configure could not find
 414 # your LaTeX2e program, the tests have not been run. Run ./configure
 415 # if you need to update it after a configuration change.
 416 ])
 417 changequote(,)dnl
 418
 419 echo "creating doc/LaTeXConfig.lyx"
 420 echo "s/@chk_linuxdoc@/$chk_linuxdoc/g" >> chkconfig.sed
 421 echo "s/@chk_docbook@/$chk_docbook/g" >> chkconfig.sed
 422 sed -f chkconfig.sed ${srcdir}/doc/LaTeXConfig.lyx.in >doc/LaTeXConfig.lyx
 423
 424 echo "creating $outfile"
 425 cat >$outfile <<EOF
 426 # This file has been automatically generated by LyX' lib/configure
 427 # script. It contains default settings that have been determined by
 428 # examining your system. PLEASE DO NOT MODIFY ANYTHING HERE! If you
 429 # want to customize LyX, make a copy of the file LYXDIR/lyxrc as
 430 # ~/.lyx/lyxrc and edit this file instead. Any setting in lyxrc will
 431 # override the values given here.
 432 \\Format text     txt   ASCII           A
 433 \\Format textparagraph txt ASCII(paragraphs)    ""
 434 \\Format docbook  sgml  DocBook         B
 435 \\Format bmp      bmp   BMP             ""
 436 \\Format dvi      dvi   DVI             D
 437 \\Format eps      eps   EPS             ""
 438 \\Format fax      ""    Fax             ""
 439 \\Format agr      agr   GRACE           ""
 440 \\Format html     html  HTML            H
 441 \\Format latex    tex   LaTeX           L
 442 \\Format linuxdoc sgml  LinuxDoc        x
 443 \\Format lyx      lyx   LyX             ""
 444 \\Format literate nw    NoWeb           N
 445 \\Format pdf      pdf   PDF             P
 446 \\Format pdf2     pdf  "PDF (pdflatex)" F
 447 \\Format pdf3     pdf  "PDF (dvipdfm)"  m
 448 \\Format png      png   PNG             ""
 449 \\Format ps       ps    Postscript      t
 450 \\Format program  ""    Program         ""
 451 \\Format tgif     obj   TGIF            ""
 452 \\Format tiff     tif   TIFF            ""
 453 \\Format word     doc   Word            W
 454 \\Format xpm      xpm   XPM             ""
 455 \\Format lyxpreview       lyxpreview    LYXPREVIEW              ""
 456
 457 \\converter latex dvi "$latex_to_dvi" "latex"
 458 \\converter latex pdf2 "$latex_to_pdf" "latex"
 459 \\converter latex html "$latex_to_html_command" "originaldir,needaux"
 460 \\converter literate latex "$literate_to_tex_command" ""
 461 \\converter dvi pdf3 "$dvi_to_pdf_command" ""
 462 \\converter dvi ps "$dvi_to_ps_command" ""
 463 \\converter ps pdf "$ps_to_pdf_command" ""
 464 \\converter ps fax "$fax_command" ""
 465 \\converter linuxdoc lyx "$linuxdoc_to_lyx_command" ""
 466 \\converter linuxdoc latex "$linuxdoc_to_latex_command" ""
 467 \\converter linuxdoc dvi "$linuxdoc_to_dvi_command" ""
 468 \\converter linuxdoc html "$linuxdoc_to_html_command" ""
 469 \\converter docbook dvi "$docbook_to_dvi_command" ""
 470 \\converter docbook html "$docbook_to_html_command" ""
 471 \\converter lyxpreview xpm "$lyxpreview_to_xpm_command" ""
 472
 473 \\converter latex lyx "$tex_to_lyx_command" ""
 474 \\converter literate lyx "$literate_to_lyx_command" ""
 475 \\converter html latex "$html_to_latex_command" ""
 476 \\converter word latex "$word_to_latex_command" ""
 477
 478 \\viewer dvi "$DVI_VIEWER"
 479 \\viewer html "$HTML_VIEWER"
 480 \\viewer pdf "$PDF_VIEWER"
 481 \\viewer ps "$GHOSTVIEW -swap"
 482 \\viewer eps "$GHOSTVIEW"
 483 \\viewer latex "$LATEX_VIEWER"
 484
 485 $rc_entries
 486 \\font_encoding "$chk_fontenc"
 487 EOF
 488
 489 ### the graphic converter part with the predefined ones
 490 #### Search for tne nonstandard converting progs
 491 #
 492 SEARCH_PROG([for an FIG -> EPS/XPM converter], FIG2DEV, fig2dev)
 493 if test "$FIG2DEV" = "fig2dev"; then
 494 cat >>$outfile <<EOF
 495 \\converter fig eps "fig2dev -L eps \$\$i \$\$o" ""
 496 \\converter fig xpm "fig2dev -L xpm \$\$i \$\$o" ""
 497 EOF
 498 fi
 499
 500 SEARCH_PROG([for an TIFF -> PS converter], TIFF2PS, tiff2ps)
 501 if test "$TIFF2PS" = "tiff2ps"; then
 502 cat >>$outfile <<EOF
 503 \\converter tiff eps "tiff2ps \$\$i > \$\$o" ""
 504 EOF
 505 fi
 506
 507 SEARCH_PROG([for an TGIF -> EPS/XPM converter], TGIF, tgif)
 508 if test "$TGIF" = "tgif"; then
 509 cat >>$outfile <<EOF
 510 \\converter tgif eps "tgif -print -eps \$\$i" ""
 511 \\converter tgif pdf "tgif -print -pdf \$\$i" ""
 512 \\converter tgif png "tgif -print -png \$\$i" ""
 513 \\converter tgif xpm "tgif -print -stdout -xpm \$\$i > \$\$o" ""
 514 EOF
 515 fi
 516
 517 SEARCH_PROG([for an EPS -> PDF converter], EPSTOPDF, epstopdf)
 518 if test "$EPSTOPDF" = "epstopdf"; then
 519 cat >>$outfile <<EOF
 520 \\converter eps pdf "epstopdf --outfile=\$\$o \$\$i" ""
 521 EOF
 522 fi
 523
 524 SEARCH_PROG([for an EPSI ->  EPS/XPM converter], EPS2EPS, eps2eps)
 525 if test "$EPS2EPS" = "eps2eps"; then
 526 cat >>$outfile <<EOF
 527 \\converter epsi pdf "epstopdf --outfile=\$\$o \$\$i" ""
 528 \\converter epsi eps "eps2eps \$\$i $$o" ""
 529 \\converter epsi xpm "eps2eps -sOutputFile=- \$\$i dummy.eps | convert - \$\$o" ""
 530 EOF
 531 fi
 532
 533 #### Add Grace conversions (xmgrace needs an Xserver, gracebat doesn't.)
 534 SEARCH_PROG([for a Grace -> Image converter], GRACE, gracebat)
 535 if test "$GRACE" = "gracebat"; then
 536 cat >>$outfile <<EOF
 537 \\converter agr eps "gracebat -hardcopy -printfile \$\$o -hdevice EPS \$\$i 2>/dev/null" ""
 538 \\converter agr png "gracebat -hardcopy -printfile \$\$o -hdevice PNG \$\$i 2>/dev/null" ""
 539 \\converter agr xpm "gracebat -hardcopy -printfile - -hdevice PNG \$\$i 2>/dev/null | convert - \$\$o" ""
 540 EOF
 541 fi
 542
 543 ######## X FONTS
 544 # create a fonts.dir file to make X fonts available to LyX
 545 echo "checking for TeX fonts"
 546
 547 fontlist="cmex10 cmmi10 cmr10 cmsy10 eufm10 msam10 msbm10"
 548 rm -f xfonts/fonts.dir xfonts/fonts.scale xfonts/tmpfonts
 549
 550 num=0
 551 touch xfonts/tmpfonts
 552 for font in $fontlist ; do
 553   MSG_CHECKING([for $font])
 554   result=no
 555   for ext in pfb pfa ttf ; do
 556     if filepath=`kpsewhich $font.$ext` ; then
 557       result="yes ($ext)"
 558       rm -f xfonts/$font.$ext
 559       ln -s $filepath xfonts 2>/dev/null
 560       echo "$font.$ext -unknown-$font-medium-r-normal--0-0-0-0-p-0-adobe-fontspecific" >>xfonts/tmpfonts
 561       num=`expr $num + 1`
 562       break
 563     fi
 564   done
 565   MSG_RESULT($result)
 566 done
 567
 568 if test ! $num = 0 ; then
 569   echo $num >xfonts/fonts.scale
 570   cat xfonts/tmpfonts >>xfonts/fonts.scale
 571   cp xfonts/fonts.scale xfonts/fonts.dir
 572 fi
 573 rm -f xfonts/tmpfonts
 574
 575
 576 # Remove superfluous files if we are not writing in the main lib
 577 # directory
 578 for file in $outfile textclass.lst packages.lst \
 579             doc/LaTeXConfig.lyx xfonts/fonts.dir ; do
 580   # we rename the file first, so that we avoid comparing a file with itself
 581   mv $file $file.new
 582   if test -r $srcdir/$file && diff $file.new $srcdir/$file >/dev/null 2>/dev/null ;
 583   then
 584     echo "removing $file, which is identical to the system global version"
 585     rm -f $file.new
 586   else
 587     mv $file.new $file
 588   fi
 589 done
 590
 591
 592 # Final clean-up
 593 if test $lyx_keep_temps = no ; then
 594 rm -f chkconfig.sed chkconfig.vars wrap_chkconfig.* chklayouts.tex \
 595       missfont.log
 596 fi