lib/configure.m4

   1 #! /bin/sh
   2 dnl Use 'make' to create configure from this m4 script.
   3 # This script is a hand-made configure script. It contains a lot of
   4 # code stolen from GNU autoconf. I removed all the code that was not
   5 # useful for configuring a LyX installation.
   6
   7
   8 dnl ######### Begin M4 macros #########################################
   9 dnl This is a template for my stripped-down configure script.
  10 dnl First, a few convenient macros.
  11 changequote([,])dnl
  12 dnl
  13 dnl
  14 dnl MSG_CHECKING(FEATURE-DESCRIPTION,PREFIX)
  15 dnl
  16 define(MSG_CHECKING,
  17 [echo $ac_n "$2checking $1""... $ac_c"])dnl
  18 dnl
  19 dnl
  20 dnl MSG_RESULT(RESULT-DESCRIPTION)
  21 dnl
  22 define(MSG_RESULT,
  23 [echo "$ac_t""$1"])dnl
  24 dnl
  25 dnl
  26 dnl SEARCH_PROG(FEATURE-DESCRIPTION,VARIABLE-NAME,PROGRAMS-LIST,
  27 dnl             ACTION-IF-FOUND,ACTION-IF-NOT-FOUND)
  28 dnl
  29 define(SEARCH_PROG,[dnl
  30 changequote([,])dnl
  31 MSG_CHECKING($1)
  32 MSG_RESULT(($3))
  33 $2=
  34 for ac_prog in $3
  35 do
  36 # Extract the first word of "$ac_prog", so it can be a program name with args.
  37 set dummy $ac_prog ; ac_word=$[2]
  38 if test -n "$ac_word"; then
  39   MSG_CHECKING([for \"$ac_word\"],[+])
  40   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS=":"
  41   for ac_dir in $PATH; do
  42     test -z "$ac_dir" && ac_dir=.
  43     if test -x [$ac_dir/$ac_word]; then
  44       $2="$ac_prog"
  45       break
  46     fi
  47   done
  48   IFS="$ac_save_ifs"
  49
  50   if test -n "[$]$2"; then
  51     ac_result=yes
  52   else
  53     ac_result=no
  54   fi
  55   ifelse($4,,,[$4])
  56   MSG_RESULT($ac_result)
  57   test -n "[$]$2" && break
  58 fi
  59 done
  60
  61 if test -z "[$]$2" ; then
  62   $2=none
  63 ifelse($5,,,[  $5
  64 ])dnl
  65 fi
  66 changequote(,)dnl
  67 ])dnl
  68 dnl
  69 dnl
  70 dnl PROVIDE_DEFAULT_FILE(FILE, DEFAULT-VALUE)
  71 dnl
  72 define(PROVIDE_DEFAULT_FILE,[dnl
  73 # if $1 does not exist (because LaTeX did not run),
  74 # then provide a standard version.
  75 if test ! -f $1 ; then
  76   cat >$1 <<EOF
  77 $2
  78 EOF
  79 fi])
  80 changequote(,)dnl
  81 dnl ######### End M4 macros #############################################
  82
  83
  84 ####some configuration variables
  85 lyx_check_config=yes
  86 lyx_keep_temps=no
  87 srcdir=
  88 lyx_suffix=
  89
  90 #### Parse the command line
  91 for ac_option do
  92   case "$ac_option" in
  93     -help | --help | -h)
  94       cat << EOF
  95 Usage: configure [options]
  96 Options:
  97   --help                   show this help lines
  98   --keep-temps             keep temporary files (for debug. purposes)
  99   --without-latex-config   do not run LaTeX to determine configuration
 100   --with-lyx-suffix=suffix suffix of binary installed files
 101 EOF
 102       exit 0;;
 103     --without-latex-config)
 104       lyx_check_config=no ;;
 105     --keep-temps)
 106       lyx_keep_temps=yes ;;
 107     --with-lyx-suffix*)
 108       lyx_suffix=`echo "$ac_option" | sed 's,--with-lyx-suffix=,,;s,^,-,'`
 109   esac
 110 done
 111
 112
 113 #### Checking for some echo oddities
 114 if (echo "testing\c"; echo 1,2,3) | grep c >/dev/null; then
 115   # Stardent Vistra SVR4 grep lacks -e, says ghazi@caip.rutgers.edu.
 116   if (echo -n testing; echo 1,2,3) | sed s/-n/xn/ | grep xn >/dev/null; then
 117     ac_n= ac_c='
 118 ' ac_t='        '
 119   else
 120     ac_n=-n ac_c= ac_t=
 121   fi
 122 else
 123   ac_n= ac_c='\c' ac_t=
 124 fi
 125
 126
 127 #### I do not really know why this is useful, but we might as well keep it.
 128 # NLS nuisances.
 129 # Only set these to C if already set.  These must not be set unconditionally
 130 # because not all systems understand e.g. LANG=C (notably SCO).
 131 # Fixing LC_MESSAGES prevents Solaris sh from translating var values in `set'!
 132 # Non-C LC_CTYPE values break the ctype check.
 133 if test "${LANG+set}"   = set; then LANG=C;   export LANG;   fi
 134 if test "${LC_ALL+set}" = set; then LC_ALL=C; export LC_ALL; fi
 135 if test "${LC_MESSAGES+set}" = set; then LC_MESSAGES=C; export LC_MESSAGES; fi
 136 if test "${LC_CTYPE+set}"    = set; then LC_CTYPE=C;    export LC_CTYPE;    fi
 137
 138
 139 #### Guess the directory in which configure is located.
 140 changequote([,])dnl
 141 ac_prog=[$]0
 142 changequote(,)dnl
 143 srcdir=`echo $ac_prog|sed 's%/[^/][^/]*$%%'`
 144 srcdir=`echo "${srcdir}" | sed 's%\([^/]\)/*$%\1%'`
 145 test "x$srcdir" = "x$ac_prog" && srcdir=.
 146 if test ! -r ${srcdir}/chkconfig.ltx ; then
 147   echo "configure: error: cannot find chkconfig.ltx script"
 148   exit 1
 149 fi
 150
 151 #### Adjust PATH for Win32 (Cygwin)
 152 if test "x$OSTYPE" = xcygwin; then
 153   echo "configure: cygwin detected; path correction"
 154   srcdir=`cygpath -w "${srcdir}" | tr '\\\\' /`
 155   echo "srcdir=${srcdir}"
 156 fi
 157
 158 #### Create the build directories if necessary
 159 for dir in bind clipart doc examples images kbd layouts reLyX \
 160     scripts templates ui ; do
 161   test ! -d $dir && mkdir $dir
 162 done
 163
 164
 165 #### Searching some useful programs
 166 define(CHECKLATEX2E,[
 167 ## Check whether this is really LaTeX2e
 168 rm -f chklatex.ltx
 169 cat >chklatex.ltx <<EOF
 170 \\nonstopmode\\makeatletter
 171 \\ifx\\undefined\\documentclass\\else
 172   \\message{ThisIsLaTeX2e}
 173 \\fi
 174 \\@@end
 175 EOF
 176 if eval ${LATEX} chklatex.ltx </dev/null 2>/dev/null \
 177                        | grep 'ThisIsLaTeX2e' >/dev/null; then
 178   :
 179 else
 180   LATEX=
 181   ac_result="not useable"
 182 fi
 183 rm -f chklatex.ltx chklatex.log])dnl
 184 dnl
 185 # Search LaTeX2e
 186 SEARCH_PROG([for a LaTeX2e program],LATEX,latex latex2e,CHECKLATEX2E,dnl
 187   [lyx_check_config=no])
 188 if test x$lyx_check_config != x ; then
 189 SEARCH_PROG([for the pdflatex program],PDFLATEX,pdflatex,CHECKLATEX2E)
 190 fi
 191
 192 # Search for an installed reLyX or a ready-to-install one
 193 save_PATH=${PATH}
 194 PATH=${PATH}:./reLyX/
 195 SEARCH_PROG([for a LaTeX -> LyX converter],tex_to_lyx_command,reLyX)
 196 PATH=${save_PATH}
 197 test $tex_to_lyx_command = "reLyX" && tex_to_lyx_command="reLyX -f \$\$i"
 198 tex_to_lyx_command=`echo $tex_to_lyx_command | sed "s,reLyX,reLyX$lyx_suffix,"`
 199
 200 SEARCH_PROG([for a Noweb -> LyX converter],literate_to_lyx_command,noweb2lyx)
 201 test $literate_to_lyx_command = "noweb2lyx" && literate_to_lyx_command="noweb2lyx \$\$i \$\$o"
 202 literate_to_lyx_command=`echo $literate_to_lyx_command | sed "s,noweb2lyx,noweb2lyx$lyx_suffix,"`
 203
 204 # Search something to process a literate document
 205 SEARCH_PROG([for a Noweb -> LaTeX converter],literate_to_tex_command,noweave)
 206 test $literate_to_tex_command = "noweave" && literate_to_tex_command="noweave -delay -index \$\$i > \$\$o"
 207
 208 SEARCH_PROG([for a HTML -> Latex converter],html_to_latex_command,html2latex)
 209 test $html_to_latex_command = "html2latex" && html_to_latex_command="html2latex \$\$i"
 210
 211 SEARCH_PROG([for a MSWord -> Latex converter],word_to_latex_command,wvCleanLatex word2x)
 212 test "$word_to_latex_command" = "wvCleanLatex" && word_to_latex_command="wvCleanLatex \$\$i \$\$o"
 213 test "$word_to_latex_command" = "word2x" && word_to_latex_command="word2x -f latex \$\$i"
 214
 215 SEARCH_PROG([for Image converter],image_command,convert)
 216 test $image_command = "convert" && image_command="convert \$\$i \$\$o"
 217
 218 # Search for a Postscript interpreter
 219 SEARCH_PROG([for a Postscript interpreter],GS, gs)
 220
 221 # Search something to preview postscript
 222 SEARCH_PROG([for a Postscript previewer],GHOSTVIEW,gv ghostview)
 223
 224 # Search for a program to preview pdf
 225 SEARCH_PROG([for a PDF preview],PDF_VIEWER,acroread gv ghostview xpdf)
 226
 227 # Search something to preview dvi
 228 SEARCH_PROG([for a DVI previewer],DVI_VIEWER, xdvi windvi yap)
 229
 230 # Search something to preview html
 231 SEARCH_PROG([for a HTML previewer],HTML_VIEWER, netscape)
 232
 233 # Search for a program to convert ps to pdf
 234 SEARCH_PROG([for a PS to PDF converter],ps_to_pdf_command,ps2pdf)
 235 test $ps_to_pdf_command = "ps2pdf" && ps_to_pdf_command="ps2pdf \$\$i"
 236
 237 # Search for a program to convert dvi to ps
 238 SEARCH_PROG([for a DVI to PS converter],dvi_to_ps_command,dvips)
 239 test $dvi_to_ps_command = "dvips" && dvi_to_ps_command="dvips -o \$\$o \$\$i"
 240
 241 # Search for a program to convert dvi to pdf
 242 SEARCH_PROG([for a DVI to PDF converter],dvi_to_pdf_command,dvipdfm)
 243 test $dvi_to_pdf_command = "dvipdfm" && dvi_to_pdf_command="dvipdfm \$\$i"
 244
 245 # Search a *roff program (used to translate tables in ASCII export)
 246 SEARCH_PROG([for a *roff formatter],ROFF,groff nroff)
 247 ascii_roff_command=$ROFF
 248 test $ROFF = "groff" && ascii_roff_command="groff -t -Tlatin1 \$\$FName"
 249 test $ROFF = "nroff" && ascii_roff_command="tbl \$\$FName | nroff"
 250
 251 # Search the ChkTeX program
 252 SEARCH_PROG([for ChkTeX],CHKTEX,chktex)
 253 chktex_command=$CHKTEX
 254 test $CHKTEX = "chktex" && chktex_command="$CHKTEX -n1 -n3 -n6 -n9 -n22 -n25 -n30 -n38"
 255
 256 # Search for a spellchecker
 257 SEARCH_PROG([for a spell-checker], SPELL,ispell)
 258
 259 dnl # Search a Fax handling program
 260 dnl SEARCH_PROG([for a fax driver], FAX, sendfax faxsend fax)
 261 dnl if test $FAX = sendfax ; then
 262 dnl   fax_command="sendfax -n -h '\$\$Host' -c '\$\$Comment' -x '\$\$Enterprise' -d '\$\$Name'@'\$\$Phone' '\$\$FName'"
 263 dnl elif test $FAX = faxsend ; then
 264 dnl   fax_command="faxsend '\$\$Phone' '\$\$FName'"
 265 dnl elif test $FAX = fax ; then
 266 dnl   fax_command="fax send '\$\$Phone' '\$\$FName'"
 267 dnl else
 268 dnl   fax_command="none"
 269 dnl fi
 270
 271 # Search a GUI Fax program
 272 SEARCH_PROG([for a fax program], fax_command, ksendfax)
 273 test $fax_command = "ksendfax" && fax_command="ksendfax \$\$i"
 274
 275 # Search for LinuxDoc support
 276 SEARCH_PROG([for SGML-tools 1.x (LinuxDoc)], LINUXDOC, sgml2lyx)
 277 chk_linuxdoc=no
 278 if test $LINUXDOC != none; then
 279   chk_linuxdoc=yes
 280   linuxdoc_cmd="\\def\\haslinuxdoc{yes}"
 281 fi
 282
 283 case $LINUXDOC in
 284   sgml2lyx)
 285     linuxdoc_to_latex_command="sgml2latex \$\$i"
 286     linuxdoc_to_dvi_command="sgml2latex -o dvi \$\$i"
 287     linuxdoc_to_html_command="sgml2html \$\$i"
 288     linuxdoc_to_lyx_command="sgml2lyx \$\$i";;
 289   none)
 290     linuxdoc_to_latex_command="none"
 291     linuxdoc_to_dvi_command="none"
 292     linuxdoc_to_html_command="none"
 293     linuxdoc_to_lyx_command="none";;
 294 esac
 295
 296 # Search for DocBook support
 297 SEARCH_PROG([for SGML-tools 2.x (DocBook) or db2x scripts], DOCBOOK, sgmltools db2dvi)
 298 chk_docbook=no
 299 if test $DOCBOOK != none; then
 300   chk_docbook=yes
 301   docbook_cmd="\\def\\hasdocbook{yes}"
 302 fi
 303
 304 case $DOCBOOK in
 305   sgmltools)
 306     docbook_to_dvi_command="sgmltools -b dvi \$\$i"
 307     docbook_to_html_command="sgmltools -b html \$\$i";;
 308   db2dvi)
 309     docbook_to_dvi_command="db2dvi \$\$i"
 310     docbook_to_html_command="db2html \$\$i";;
 311   none)
 312     docbook_to_dvi_command="none"
 313     docbook_to_html_command="none";;
 314 esac
 315
 316 # Search for a spool command
 317 SEARCH_PROG([for a spool command], LPR, lp lpr)
 318 case $LPR in
 319   lp) print_spool_command=lp
 320       print_spool_printerprefix="-d ";;
 321  lpr) print_spool_command=lpr
 322       print_spool_printerprefix="-P";;
 323    *) :;; # leave to empty values
 324 esac
 325
 326 SEARCH_PROG([for a LaTeX -> HTML converter], TOHTML, tth latex2html hevea)
 327 latex_to_html_command=$TOHTML
 328 case $TOHTML in
 329         tth) latex_to_html_command="tth -t -e2 -L\$\$b < \$\$i > \$\$o";;
 330  latex2html) latex_to_html_command="latex2html -no_subdir -split 0 -show_section_numbers \$\$i";;
 331       hevea) latex_to_html_command="hevea -s \$\$i";;
 332 esac
 333
 334 #### Explore the LaTeX configuration
 335 MSG_CHECKING(LaTeX configuration)
 336 # First, remove the files that we want to re-create
 337 rm -f textclass.lst packages.lst chkconfig.sed
 338 if test ${lyx_check_config} = no ; then
 339   MSG_RESULT(default values)
 340 else
 341   MSG_RESULT(auto)
 342   rm -f wrap_chkconfig.ltx chkconfig.vars chkconfig.classes chklayouts.tex
 343   cat >wrap_chkconfig.ltx <<EOF
 344 \\newcommand\\srcdir{${srcdir}}
 345 ${linuxdoc_cmd}
 346 ${docbook_cmd}
 347 \\input{${srcdir}/chkconfig.ltx}
 348 EOF
 349   ## Construct the list of classes to test for.
 350   # build the list of available layout files and convert it to commands
 351   # for chkconfig.ltx
 352   for file in ./layouts/*.layout ${srcdir}/layouts/*.layout ; do
 353     case $file in
 354       */\*.layout) ;;
 355       *) test -r "$file" && echo $file ;;
 356     esac
 357   done | sed -e 's%^.*layouts/\(.*\)\.layout$%\\TestDocClass{\1}%'\
 358              > chklayouts.tex
 359 changequote([,])dnl
 360   [eval] ${LATEX} wrap_chkconfig.ltx 2>/dev/null | grep '^\+'
 361   [eval] `cat chkconfig.vars | sed 's/-/_/g'`
 362 changequote(,)dnl
 363 fi
 364
 365 # Do we have all the files we need? Useful if latex did not run
 366 changequote([,])dnl
 367 echo creating textclass.lst
 368 PROVIDE_DEFAULT_FILE(textclass.lst,dnl
 369 [# This file declares layouts and their associated definition files
 370 # (include dir. relative to the place where this file is).
 371 # It contains only default values, since chkconfig.ltx could not be run
 372 # for some reason. Run ./configure if you need to update it after a
 373 # configuration change.
 374 article article article
 375 report  report  report
 376 book    book    book
 377 linuxdoc        linuxdoc        linuxdoc
 378 letter  letter  letter])
 379
 380 PROVIDE_DEFAULT_FILE(chkconfig.sed,[s/@.*@/???/g])
 381
 382 echo creating packages.lst
 383 PROVIDE_DEFAULT_FILE(packages.lst,dnl
 384 [# This file should contain the list of LaTeX packages that have been
 385 # recognized by LyX. Unfortunately, since configure could not find
 386 # your LaTeX2e program, the tests have not been run. Run ./configure
 387 # if you need to update it after a configuration change.
 388 ])
 389 changequote(,)dnl
 390
 391 echo creating doc/LaTeXConfig.lyx
 392 echo "s/@chk_linuxdoc@/$chk_linuxdoc/g" >> chkconfig.sed
 393 echo "s/@chk_docbook@/$chk_docbook/g" >> chkconfig.sed
 394 sed -f chkconfig.sed ${srcdir}/doc/LaTeXConfig.lyx.in >doc/LaTeXConfig.lyx
 395
 396 echo creating lyxrc.defaults
 397 rm -f lyxrc.defaults
 398 cat >lyxrc.defaults <<EOF
 399 # This file has been automatically generated by LyX' lib/configure
 400 # script. It contains default settings that have been determined by
 401 # examining your system. PLEASE DO NOT MODIFY ANYTHING HERE! If you
 402 # want to customize LyX, make a copy of the file LYXDIR/lyxrc as
 403 # ~/.lyx/lyxrc and edit this file instead. Any setting in lyxrc will
 404 # override the values given here.
 405 \\Format text     txt   ASCII           A
 406 \\Format textparagraph txt ASCII(paragraphs)    ""
 407 \\Format docbook  sgml  DocBook         B
 408 \\Format dvi      dvi   DVI             D
 409 \\Format eps      eps   EPS             ""
 410 \\Format fax      ""    Fax             ""
 411 \\Format gif      gif   GIF             ""
 412 \\Format html     html  HTML            H
 413 \\Format jpg      jpg   JPEG            ""
 414 \\Format latex    tex   LaTeX           L
 415 \\Format linuxdoc sgml  LinuxDoc        x
 416 \\Format lyx      lyx   LyX             ""
 417 \\Format literate nw    NoWeb           N
 418 \\Format pdf      pdf   PDF             P
 419 \\Format pdf2     pdf  "PDF (pdflatex)" F
 420 \\Format pdf3     pdf  "PDF (dvipdfm)"  m
 421 \\Format png      png   PNG             ""
 422 \\Format ps       ps    Postscript      t
 423 \\Format program  ""    Program         ""
 424 \\Format word     doc   Word            W
 425
 426
 427 \\converter latex dvi "$LATEX \$\$i" "latex"
 428 \\converter latex pdf2 "$PDFLATEX \$\$i" "latex"
 429 \\converter latex html "$latex_to_html_command" "originaldir,needaux"
 430 \\converter literate latex "$literate_to_tex_command" ""
 431 \\converter dvi pdf3 "$dvi_to_pdf_command" ""
 432 \\converter dvi ps "$dvi_to_ps_command" ""
 433 \\converter ps pdf "$ps_to_pdf_command" ""
 434 \\converter ps fax "$fax_command" ""
 435 \\converter linuxdoc lyx "$linuxdoc_to_lyx_command" ""
 436 \\converter linuxdoc latex "$linuxdoc_to_latex_command" ""
 437 \\converter linuxdoc dvi "$linuxdoc_to_dvi_command" ""
 438 \\converter linuxdoc html "$linuxdoc_to_html_command" ""
 439 \\converter docbook dvi "$docbook_to_dvi_command" ""
 440 \\converter docbook html "$docbook_to_html_command" ""
 441
 442 \\converter latex lyx "$tex_to_lyx_command" ""
 443 \\converter literate lyx "$literate_to_lyx_command" ""
 444 \\converter html latex "$html_to_latex_command" ""
 445 \\converter word latex "$word_to_latex_command" ""
 446
 447 \converter gif eps "$image_command" ""
 448 \converter png eps "$image_command" ""
 449 \converter jpg eps "$image_command" ""
 450 \converter gif png "$image_command" ""
 451
 452 \\viewer dvi "$DVI_VIEWER"
 453 \\viewer html "$HTML_VIEWER"
 454 \\viewer pdf "$PDF_VIEWER"
 455 \\viewer ps "$GHOSTVIEW -swap"
 456 \\viewer eps "$GHOSTVIEW"
 457
 458 \\ps_command "$GS"
 459 \\ascii_roff_command "$ascii_roff_command"
 460 \\chktex_command "$chktex_command"
 461 \\spell_command "$SPELL"
 462 dnl \\fax_command "$fax_command"
 463 \\print_spool_command "$print_spool_command"
 464 \\print_spool_printerprefix "$print_spool_printerprefix"
 465 \\font_encoding "$chk_fontenc"
 466 EOF
 467
 468 # Remove superfluous files if we are not writing in the main lib
 469 # directory
 470 for file in lyxrc.defaults textclass.lst packages.lst \
 471             doc/LaTeXConfig.lyx ; do
 472   # we rename the file first, so that we avoid comparing a file with itself
 473   mv $file $file.new
 474   if test -r $srcdir/$file && diff $file.new $srcdir/$file >/dev/null 2>/dev/null ;
 475   then
 476     echo "removing $file, which is identical to the system global version"
 477     rm -f $file.new
 478   else
 479     mv $file.new $file
 480   fi
 481 done
 482
 483
 484 # Final clean-up
 485 if test $lyx_keep_temps = no ; then
 486 rm -f chkconfig.sed chkconfig.vars wrap_chkconfig.* chklayouts.tex \
 487       missfont.log
 488 fi