lib/configure.m4

   1 #! /bin/sh
   2 dnl Use 'make' to create configure from this m4 script.
   3 # This script is a hand-made configure script. It contains a lot of
   4 # code stolen from GNU autoconf. I removed all the code that was not
   5 # useful for configuring a LyX installation.
   6
   7
   8 dnl ######### Begin M4 macros #########################################
   9 dnl This is a template for my stripped-down configure script.
  10 dnl First, a few convenient macros.
  11 changequote([,])dnl
  12 dnl
  13 dnl
  14 dnl MSG_CHECKING(FEATURE-DESCRIPTION,PREFIX)
  15 dnl
  16 define(MSG_CHECKING,
  17 [echo $ac_n "$2checking $1""... $ac_c"])dnl
  18 dnl
  19 dnl
  20 dnl MSG_RESULT(RESULT-DESCRIPTION)
  21 dnl
  22 define(MSG_RESULT,
  23 [echo "$ac_t""$1"])dnl
  24 dnl
  25 dnl
  26 dnl SEARCH_PROG(FEATURE-DESCRIPTION,VARIABLE-NAME,PROGRAMS-LIST,
  27 dnl             ACTION-IF-FOUND,ACTION-IF-NOT-FOUND)
  28 dnl
  29 define(SEARCH_PROG,[dnl
  30 changequote([,])dnl
  31 MSG_CHECKING($1)
  32 MSG_RESULT(($3))
  33 $2=
  34 for ac_prog in $3
  35 do
  36 # Extract the first word of "$ac_prog", so it can be a program name with args.
  37 set dummy $ac_prog ; ac_word=$[2]
  38 if test -n "$ac_word"; then
  39   MSG_CHECKING([for \"$ac_word\"],[+])
  40   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS=":"
  41   for ac_dir in $PATH; do
  42     test -z "$ac_dir" && ac_dir=.
  43     if test -x [$ac_dir/$ac_word]; then
  44       $2="$ac_prog"
  45       break
  46     fi
  47   done
  48   IFS="$ac_save_ifs"
  49
  50   if test -n "[$]$2"; then
  51     ac_result=yes
  52     ifelse($4,,,[$4])
  53   else
  54     ac_result=no
  55   fi
  56   MSG_RESULT($ac_result)
  57   test -n "[$]$2" && break
  58 fi
  59 done
  60
  61 if test -z "[$]$2" ; then
  62   $2=none
  63 ifelse($5,,,[  $5
  64 ])dnl
  65 fi
  66 changequote(,)dnl
  67 ])dnl
  68 dnl
  69 dnl
  70 dnl LYXRC_VAR(VARIABLE_NAME, VALUE)
  71 define(LYXRC_VAR,[dnl
  72 rc_entries="$rc_entries
  73 $1 \"$2\""])
  74 dnl
  75 dnl
  76 dnl LYXRC_PROG(FEATURE-DESCRIPTION,VARIABLE-NAME,PROGRAMS-LIST,
  77 dnl             ACTION-IF-FOUND,ACTION-IF-NOT-FOUND)
  78 define(LYXRC_PROG,[dnl
  79 SEARCH_PROG($1,prog,$3,$4,$5)
  80 LYXRC_VAR($2,$prog)])
  81 dnl
  82 dnl
  83 dnl PROVIDE_DEFAULT_FILE(FILE, DEFAULT-VALUE)
  84 dnl
  85 define(PROVIDE_DEFAULT_FILE,[dnl
  86 # if $1 does not exist (because LaTeX did not run),
  87 # then provide a standard version.
  88 if test ! -f $1 ; then
  89   cat >$1 <<EOF
  90 $2
  91 EOF
  92 fi])
  93 changequote(,)dnl
  94 dnl ######### End M4 macros #############################################
  95
  96
  97 ####some configuration variables
  98 outfile=lyxrc.defaults
  99 rc_entries=
 100 lyx_check_config=yes
 101 lyx_keep_temps=no
 102 srcdir=
 103 lyx_suffix=
 104
 105 #### Parse the command line
 106 for ac_option do
 107   case "$ac_option" in
 108     -help | --help | -h)
 109       cat << EOF
 110 Usage: configure [options]
 111 Options:
 112   --help                   show this help lines
 113   --keep-temps             keep temporary files (for debug. purposes)
 114   --without-latex-config   do not run LaTeX to determine configuration
 115   --with-lyx-suffix=suffix suffix of binary installed files
 116 EOF
 117       exit 0;;
 118     --without-latex-config)
 119       lyx_check_config=no ;;
 120     --keep-temps)
 121       lyx_keep_temps=yes ;;
 122     --with-lyx-suffix*)
 123       lyx_suffix=`echo "$ac_option" | sed 's,--with-lyx-suffix=,,;s,^,-,'`
 124   esac
 125 done
 126
 127
 128 #### Checking for some echo oddities
 129 if (echo "testing\c"; echo 1,2,3) | grep c >/dev/null; then
 130   # Stardent Vistra SVR4 grep lacks -e, says ghazi@caip.rutgers.edu.
 131   if (echo -n testing; echo 1,2,3) | sed s/-n/xn/ | grep xn >/dev/null; then
 132     ac_n= ac_c='
 133 ' ac_t='        '
 134   else
 135     ac_n=-n ac_c= ac_t=
 136   fi
 137 else
 138   ac_n= ac_c='\c' ac_t=
 139 fi
 140
 141
 142 #### I do not really know why this is useful, but we might as well keep it.
 143 # NLS nuisances.
 144 # Only set these to C if already set.  These must not be set unconditionally
 145 # because not all systems understand e.g. LANG=C (notably SCO).
 146 # Fixing LC_MESSAGES prevents Solaris sh from translating var values in `set'!
 147 # Non-C LC_CTYPE values break the ctype check.
 148 if test "${LANG+set}"   = set; then LANG=C;   export LANG;   fi
 149 if test "${LC_ALL+set}" = set; then LC_ALL=C; export LC_ALL; fi
 150 if test "${LC_MESSAGES+set}" = set; then LC_MESSAGES=C; export LC_MESSAGES; fi
 151 if test "${LC_CTYPE+set}"    = set; then LC_CTYPE=C;    export LC_CTYPE;    fi
 152
 153
 154 #### Guess the directory in which configure is located.
 155 changequote([,])dnl
 156 ac_prog=[$]0
 157 changequote(,)dnl
 158 srcdir=`echo $ac_prog|sed 's%/[^/][^/]*$%%'`
 159 srcdir=`echo "${srcdir}" | sed 's%\([^/]\)/*$%\1%'`
 160 test "x$srcdir" = "x$ac_prog" && srcdir=.
 161 if test ! -r ${srcdir}/chkconfig.ltx ; then
 162   echo "configure: error: cannot find chkconfig.ltx script"
 163   exit 1
 164 fi
 165
 166 #### Adjust PATH for Win32 (Cygwin)
 167 if test "x$OSTYPE" = xcygwin; then
 168   echo "configure: cygwin detected; path correction"
 169   srcdir=`cygpath -w "${srcdir}" | tr '\\\\' /`
 170   echo "srcdir=${srcdir}"
 171 fi
 172
 173 #### Create the build directories if necessary
 174 for dir in bind clipart doc examples help images kbd layouts reLyX \
 175     scripts templates ui ; do
 176   test ! -d $dir && mkdir $dir
 177 done
 178
 179
 180 #### Searching some useful programs
 181 define(CHECKLATEX2E,[
 182 ## Check whether this is really LaTeX2e
 183 rm -f chklatex.ltx
 184 cat >chklatex.ltx <<EOF
 185 \\nonstopmode\\makeatletter
 186 \\ifx\\undefined\\documentclass\\else
 187   \\message{ThisIsLaTeX2e}
 188 \\fi
 189 \\@@end
 190 EOF
 191 if eval ${LATEX} chklatex.ltx </dev/null 2>/dev/null \
 192                        | grep 'ThisIsLaTeX2e' >/dev/null; then
 193   :
 194 else
 195   LATEX=
 196   ac_result="not useable"
 197 fi
 198 rm -f chklatex.ltx chklatex.log])dnl
 199 dnl
 200 # Search LaTeX2e
 201 SEARCH_PROG([for a LaTeX2e program],LATEX,latex latex2e,CHECKLATEX2E,dnl
 202   [lyx_check_config=no])
 203 latex_to_dvi=$LATEX
 204 test -z "$latex_to_dvi" && latex_to_dvi="none"
 205
 206 # Search for pdflatex
 207 if test ${lyx_check_config} = no ; then
 208   latex_to_pdf=none
 209 else
 210   SEARCH_PROG([for the pdflatex program],latex_to_pdf,pdflatex)
 211 fi
 212
 213 test $latex_to_dvi != "none" && latex_to_dvi="$latex_to_dvi \$\$i"
 214 test $latex_to_pdf != "none" && latex_to_pdf="$latex_to_pdf \$\$i"
 215
 216 # Search for an installed reLyX or a ready-to-install one
 217 save_PATH=${PATH}
 218 PATH=${PATH}:./reLyX/
 219 SEARCH_PROG([for a LaTeX -> LyX converter],tex_to_lyx_command,reLyX)
 220 PATH=${save_PATH}
 221 test $tex_to_lyx_command = "reLyX" && tex_to_lyx_command="reLyX -f \$\$i"
 222 tex_to_lyx_command=`echo $tex_to_lyx_command | sed "s,reLyX,reLyX$lyx_suffix,"`
 223
 224 SEARCH_PROG([for a Noweb -> LyX converter],literate_to_lyx_command,noweb2lyx)
 225 test $literate_to_lyx_command = "noweb2lyx" && literate_to_lyx_command="noweb2lyx \$\$i \$\$o"
 226 literate_to_lyx_command=`echo $literate_to_lyx_command | sed "s,noweb2lyx,noweb2lyx$lyx_suffix,"`
 227
 228 # Search something to process a literate document
 229 SEARCH_PROG([for a Noweb -> LaTeX converter],literate_to_tex_command,noweave)
 230 test $literate_to_tex_command = "noweave" && literate_to_tex_command="noweave -delay -index \$\$i > \$\$o"
 231
 232 SEARCH_PROG([for a HTML -> Latex converter],html_to_latex_command,html2latex)
 233 test $html_to_latex_command = "html2latex" && html_to_latex_command="html2latex \$\$i"
 234
 235 SEARCH_PROG([for a MSWord -> Latex converter],word_to_latex_command,wvCleanLatex word2x)
 236 test "$word_to_latex_command" = "wvCleanLatex" && word_to_latex_command="wvCleanLatex \$\$i \$\$o"
 237 test "$word_to_latex_command" = "word2x" && word_to_latex_command="word2x -f latex \$\$i"
 238
 239 SEARCH_PROG([for Image converter],image_command,convert)
 240 test $image_command = "convert" && image_command="convert \$\$i \$\$o"
 241
 242 # Search for a Postscript interpreter
 243 LYXRC_PROG([for a Postscript interpreter], \ps_command, gs)
 244
 245 # Search something to preview postscript
 246 SEARCH_PROG([for a Postscript previewer],GHOSTVIEW,gv ghostview)
 247
 248 # Search for a program to preview pdf
 249 SEARCH_PROG([for a PDF preview],PDF_VIEWER,acroread gv ghostview xpdf)
 250
 251 # Search something to preview dvi
 252 SEARCH_PROG([for a DVI previewer],DVI_VIEWER, xdvi windvi yap)
 253
 254 # Search something to preview html
 255 SEARCH_PROG([for a HTML previewer],HTML_VIEWER, netscape)
 256
 257 # Search for a program to convert ps to pdf
 258 SEARCH_PROG([for a PS to PDF converter],ps_to_pdf_command,ps2pdf)
 259 test $ps_to_pdf_command = "ps2pdf" && ps_to_pdf_command="ps2pdf \$\$i"
 260
 261 # Search for a program to convert dvi to ps
 262 SEARCH_PROG([for a DVI to PS converter],dvi_to_ps_command,dvips)
 263 test $dvi_to_ps_command = "dvips" && dvi_to_ps_command="dvips -o \$\$o \$\$i"
 264
 265 # Search for a program to convert dvi to pdf
 266 SEARCH_PROG([for a DVI to PDF converter],dvi_to_pdf_command,dvipdfm)
 267 test $dvi_to_pdf_command = "dvipdfm" && dvi_to_pdf_command="dvipdfm \$\$i"
 268
 269 # Search a *roff program (used to translate tables in ASCII export)
 270 LYXRC_PROG([for a *roff formatter], \ascii_roff_command, dnl
 271   'groff -t -Tlatin1 $$FName' nroff,dnl
 272   test "$prog" = "nroff" && prog='tbl $$FName | nroff')
 273
 274 # Search the ChkTeX program
 275 LYXRC_PROG([for ChkTeX], \chktex_command,dnl
 276    "chktex -n1 -n3 -n6 -n9 -n22 -n25 -n30 -n38")
 277
 278 # Search for a spellchecker
 279 LYXRC_PROG([for a spell-checker], \spell_command, ispell)
 280
 281 dnl # Search a Fax handling program
 282 dnl SEARCH_PROG([for a fax driver], FAX, sendfax faxsend fax)
 283 dnl if test $FAX = sendfax ; then
 284 dnl   fax_command="sendfax -n -h '\$\$Host' -c '\$\$Comment' -x '\$\$Enterprise' -d '\$\$Name'@'\$\$Phone' '\$\$FName'"
 285 dnl elif test $FAX = faxsend ; then
 286 dnl   fax_command="faxsend '\$\$Phone' '\$\$FName'"
 287 dnl elif test $FAX = fax ; then
 288 dnl   fax_command="fax send '\$\$Phone' '\$\$FName'"
 289 dnl else
 290 dnl   fax_command="none"
 291 dnl fi
 292
 293 # Search a GUI Fax program
 294 SEARCH_PROG([for a fax program], fax_command, ksendfax)
 295 test $fax_command = "ksendfax" && fax_command="ksendfax \$\$i"
 296
 297 # Search for LinuxDoc support
 298 SEARCH_PROG([for SGML-tools 1.x (LinuxDoc)], LINUXDOC, sgml2lyx)
 299 chk_linuxdoc=no
 300 if test $LINUXDOC != none; then
 301   chk_linuxdoc=yes
 302   linuxdoc_cmd="\\def\\haslinuxdoc{yes}"
 303 fi
 304
 305 case $LINUXDOC in
 306   sgml2lyx)
 307     linuxdoc_to_latex_command="sgml2latex \$\$i"
 308     linuxdoc_to_dvi_command="sgml2latex -o dvi \$\$i"
 309     linuxdoc_to_html_command="sgml2html \$\$i"
 310     linuxdoc_to_lyx_command="sgml2lyx \$\$i";;
 311   none)
 312     linuxdoc_to_latex_command="none"
 313     linuxdoc_to_dvi_command="none"
 314     linuxdoc_to_html_command="none"
 315     linuxdoc_to_lyx_command="none";;
 316 esac
 317
 318 # Search for DocBook support
 319 SEARCH_PROG([for SGML-tools 2.x (DocBook) or db2x scripts], DOCBOOK, sgmltools db2dvi)
 320 chk_docbook=no
 321 if test $DOCBOOK != none; then
 322   chk_docbook=yes
 323   docbook_cmd="\\def\\hasdocbook{yes}"
 324 fi
 325
 326 case $DOCBOOK in
 327   sgmltools)
 328     docbook_to_dvi_command="sgmltools -b dvi \$\$i"
 329     docbook_to_html_command="sgmltools -b html \$\$i";;
 330   db2dvi)
 331     docbook_to_dvi_command="db2dvi \$\$i"
 332     docbook_to_html_command="db2html \$\$i";;
 333   none)
 334     docbook_to_dvi_command="none"
 335     docbook_to_html_command="none";;
 336 esac
 337
 338 # Search for a spool command
 339 LYXRC_PROG([for a spool command], \print_spool_command, lp lpr)
 340 case $prog in
 341   lp) print_spool_printerprefix="-d ";;
 342  lpr) print_spool_printerprefix="-P";;
 343    *) :;; # leave to empty values
 344 esac
 345 LYXRC_VAR(\print_spool_printerprefix, $print_spool_printerprefix)
 346
 347 SEARCH_PROG([for a LaTeX -> HTML converter], TOHTML, tth latex2html hevea)
 348 latex_to_html_command=$TOHTML
 349 case $TOHTML in
 350         tth) latex_to_html_command="tth -t -e2 -L\$\$b < \$\$i > \$\$o";;
 351  latex2html) latex_to_html_command="latex2html -no_subdir -split 0 -show_section_numbers \$\$i";;
 352       hevea) latex_to_html_command="hevea -s \$\$i";;
 353 esac
 354
 355 #### Search for image conversion ####
 356 SEARCH_PROG([for an Image -> EPS converter], TOEPS, convert pnmtops)
 357 case $TOEPS in
 358         convert) bmp_to_eps="convert BMP:\$\$i EPS:\$\$o" fits_to_eps="convert FITS:\$\$i EPS:\$\$o" gif_to_eps="convert GIF:\$\$i EPS:\$\$o" jpg_to_eps="convert JPG:\$\$i EPS:\$\$o" pbm_to_eps="convert PBM:\$\$i EPS:\$\$o" pgm_to_eps="convert PGM:\$\$i EPS:\$\$o" png_to_eps="convert PNG:\$\$i EPS:\$\$o" ppm_to_eps="convert PPM:\$\$i EPS:\$\$o" sgi_to_eps="convert SGI:\$\$i EPS:\$\$o" xwd_to_eps="convert XWD:\$\$i EPS:\$\$o" ;;
 359         pnmtops) gif_to_eps="giftopnm \$\$i | pnmtops > \$\$o" png_to_eps="pngtopnm \$\$i | pnmtops >\$\$o" jpg_to_eps="jpegtopnm \$\$i | pnmtops >\$\$o";;
 360 esac
 361
 362 SEARCH_PROG([for a Image -> PNG converter], TOPNG, convert pnmtopng)
 363 case $TOPNG in
 364         convert) gif_to_png="convert GIF:\$\$i PNG:\$\$o" eps_to_png="convert EPS:\$\$i PNG:\$\$o" jpg_to_png="convert JPG:\$\$i PNG:\$\$o";;
 365         pnmtopng) gif_to_png="giftopnm \$\$i | pnmtopng >\$\$o" eps_to_png="pstopnm \$\$i| pnmtopng >\$\$o" jpg_to_png="jpegtopnm \$\$i | pnmtopng >\$\$o";;
 366 esac
 367
 368 SEARCH_PROG([for a Image -> XPM converter], TOXPM, convert)
 369 if test "$TOXPM" = "convert"; then
 370         gif_to_xpm="convert GIF:\$\$i XPM:\$\$o"
 371         eps_to_xpm="convert EPS:\$\$i XPM:\$\$o"
 372         jpg_to_xpm="convert JPG:\$\$i XPM:\$\$o"
 373         png_to_xpm="convert PNG:\$\$i XPM:\$\$o"
 374         ps_to_xpm="convert PS:\$\$i XPM:\$\$o"
 375 fi
 376
 377 SEARCH_PROG([For an EPS -> PDF converter], EPSTOPDF, epstopdf)
 378 case $EPSTOPDF in
 379         epstopdf) eps_to_pdf="epstopdf --outfile=\$\$o \$\$i";;
 380 esac
 381
 382 #### Explore the LaTeX configuration
 383 MSG_CHECKING(LaTeX configuration)
 384 # First, remove the files that we want to re-create
 385 rm -f textclass.lst packages.lst chkconfig.sed
 386 if test ${lyx_check_config} = no ; then
 387   MSG_RESULT(default values)
 388 else
 389   MSG_RESULT(auto)
 390   rm -f wrap_chkconfig.ltx chkconfig.vars chkconfig.classes chklayouts.tex
 391   cat >wrap_chkconfig.ltx <<EOF
 392 \\newcommand\\srcdir{${srcdir}}
 393 ${linuxdoc_cmd}
 394 ${docbook_cmd}
 395 \\input{${srcdir}/chkconfig.ltx}
 396 EOF
 397   ## Construct the list of classes to test for.
 398   # build the list of available layout files and convert it to commands
 399   # for chkconfig.ltx
 400   for file in ./layouts/*.layout ${srcdir}/layouts/*.layout ; do
 401     case $file in
 402       */\*.layout) ;;
 403       *) test -r "$file" && echo $file ;;
 404     esac
 405   done | sed -e 's%^.*layouts/\(.*\)\.layout$%\\TestDocClass{\1}%'\
 406              > chklayouts.tex
 407 changequote([,])dnl
 408   [eval] ${LATEX} wrap_chkconfig.ltx 2>/dev/null | grep '^\+'
 409   [eval] `cat chkconfig.vars | sed 's/-/_/g'`
 410 changequote(,)dnl
 411 fi
 412
 413 # Do we have all the files we need? Useful if latex did not run
 414 changequote([,])dnl
 415 echo creating textclass.lst
 416 PROVIDE_DEFAULT_FILE(textclass.lst,dnl
 417 [# This file declares layouts and their associated definition files
 418 # (include dir. relative to the place where this file is).
 419 # It contains only default values, since chkconfig.ltx could not be run
 420 # for some reason. Run ./configure if you need to update it after a
 421 # configuration change.
 422 article article article
 423 report  report  report
 424 book    book    book
 425 linuxdoc        linuxdoc        linuxdoc
 426 letter  letter  letter])
 427
 428 PROVIDE_DEFAULT_FILE(chkconfig.sed,[s/@.*@/???/g])
 429
 430 echo creating packages.lst
 431 PROVIDE_DEFAULT_FILE(packages.lst,dnl
 432 [# This file should contain the list of LaTeX packages that have been
 433 # recognized by LyX. Unfortunately, since configure could not find
 434 # your LaTeX2e program, the tests have not been run. Run ./configure
 435 # if you need to update it after a configuration change.
 436 ])
 437 changequote(,)dnl
 438
 439 echo creating doc/LaTeXConfig.lyx
 440 echo "s/@chk_linuxdoc@/$chk_linuxdoc/g" >> chkconfig.sed
 441 echo "s/@chk_docbook@/$chk_docbook/g" >> chkconfig.sed
 442 sed -f chkconfig.sed ${srcdir}/doc/LaTeXConfig.lyx.in >doc/LaTeXConfig.lyx
 443
 444 echo creating $outfile
 445 cat >$outfile <<EOF
 446 # This file has been automatically generated by LyX' lib/configure
 447 # script. It contains default settings that have been determined by
 448 # examining your system. PLEASE DO NOT MODIFY ANYTHING HERE! If you
 449 # want to customize LyX, make a copy of the file LYXDIR/lyxrc as
 450 # ~/.lyx/lyxrc and edit this file instead. Any setting in lyxrc will
 451 # override the values given here.
 452 \\Format text     txt   ASCII           A
 453 \\Format textparagraph txt ASCII(paragraphs)    ""
 454 \\Format docbook  sgml  DocBook         B
 455 \\Format bmp      bmp   BMP             ""
 456 \\Format dvi      dvi   DVI             D
 457 \\Format eps      eps   EPS             ""
 458 \\Format epsi     epsi  EPSI            ""
 459 \\Format fax      ""    Fax             ""
 460 \\Format fits     fits  FITS            ""
 461 \\Format gif      gif   GIF             ""
 462 \\Format grace    agr   GRACE           ""
 463 \\Format html     html  HTML            H
 464 \\Format jpg      jpg   JPEG            ""
 465 \\Format latex    tex   LaTeX           L
 466 \\Format linuxdoc sgml  LinuxDoc        x
 467 \\Format lyx      lyx   LyX             ""
 468 \\Format literate nw    NoWeb           N
 469 \\Format pdf      pdf   PDF             P
 470 \\Format pdf2     pdf  "PDF (pdflatex)" F
 471 \\Format pdf3     pdf  "PDF (dvipdfm)"  m
 472 \\Format pbm      pbm   PBM             ""
 473 \\Format pgm      pgm   PGM             ""
 474 \\Format png      png   PNG             ""
 475 \\Format ppm      ppm   PPM             ""
 476 \\Format ps       ps    Postscript      t
 477 \\Format program  ""    Program         ""
 478 \\Format sgi      sgi   SGI             ""
 479 \\Format tgif     tgif  TGIF            ""
 480 \\Format tiff     tif   TIFF            ""
 481 \\Format xpm      xpm   XPM             ""
 482 \\Format xwd      xwd   XWD             ""
 483 \\Format word     doc   Word            W
 484
 485 \\converter latex dvi "$latex_to_dvi" "latex"
 486 \\converter latex pdf2 "$latex_to_pdf" "latex"
 487 \\converter latex html "$latex_to_html_command" "originaldir,needaux"
 488 \\converter literate latex "$literate_to_tex_command" ""
 489 \\converter dvi pdf3 "$dvi_to_pdf_command" ""
 490 \\converter dvi ps "$dvi_to_ps_command" ""
 491 \\converter ps pdf "$ps_to_pdf_command" ""
 492 \\converter ps fax "$fax_command" ""
 493 \\converter linuxdoc lyx "$linuxdoc_to_lyx_command" ""
 494 \\converter linuxdoc latex "$linuxdoc_to_latex_command" ""
 495 \\converter linuxdoc dvi "$linuxdoc_to_dvi_command" ""
 496 \\converter linuxdoc html "$linuxdoc_to_html_command" ""
 497 \\converter docbook dvi "$docbook_to_dvi_command" ""
 498 \\converter docbook html "$docbook_to_html_command" ""
 499
 500 \\converter latex lyx "$tex_to_lyx_command" ""
 501 \\converter literate lyx "$literate_to_lyx_command" ""
 502 \\converter html latex "$html_to_latex_command" ""
 503 \\converter word latex "$word_to_latex_command" ""
 504
 505 \\converter agr  eps "xmgrace -hardcopy -hdevice EPS \$\$i" ""
 506 \\converter bmp  eps "$bmp_to_eps" ""
 507 \\converter fits  eps "$fits_to_eps" ""
 508 \\converter gif  eps "$gif_to_eps" ""
 509 \\converter jpg  eps "$jpg_to_eps" ""
 510 \\converter pbm  eps "$pbm_to_eps" ""
 511 \\converter pgm  eps "$pgm_to_eps" ""
 512 \\converter png  eps "$png_to_eps" ""
 513 \\converter ppm  eps "$ppm_to_eps" ""
 514 \\converter sgi  eps "$sgi_to_eps" ""
 515 \\converter tgif eps "tgif -print -eps \$\$i" ""
 516 \\converter tiff eps "tiff2ps \$\$i > \$\$o" ""
 517 \\converter xwd  eps "$xwd_to_eps" ""
 518
 519 \\converter tgif gif "tgif -print -gif \$\$i" ""
 520 \\converter tgif pdf "tgif -print -pdf \$\$i" ""
 521
 522 \\converter gif  png "$gif_to_png" ""
 523 \\converter eps  png "$eps_to_png" ""
 524 \\converter epsi png "$eps_to_png" ""
 525 \\converter jpg  png "$jpg_to_png" ""
 526
 527 \\converter gif  xpm "$gif_to_xpm" ""
 528 \\converter eps  xpm "$eps_to_xpm" ""
 529 \\converter epsi xpm "$eps_to_xpm" ""
 530 \\converter jpg  xpm "$jpg_to_xpm" ""
 531 \\converter png  xpm "$png_to_xpm" ""
 532
 533 \\converter eps  pdf "$eps_to_pdf" ""
 534 \\converter epsi pdf "$eps_to_pdf" ""
 535
 536 \\viewer dvi "$DVI_VIEWER"
 537 \\viewer html "$HTML_VIEWER"
 538 \\viewer pdf "$PDF_VIEWER"
 539 \\viewer ps "$GHOSTVIEW -swap"
 540 \\viewer eps "$GHOSTVIEW"
 541
 542 $rc_entries
 543 dnl \\fax_command "$fax_command"
 544 \\font_encoding "$chk_fontenc"
 545 EOF
 546
 547 # Remove superfluous files if we are not writing in the main lib
 548 # directory
 549 for file in $outfile textclass.lst packages.lst \
 550             doc/LaTeXConfig.lyx ; do
 551   # we rename the file first, so that we avoid comparing a file with itself
 552   mv $file $file.new
 553   if test -r $srcdir/$file && diff $file.new $srcdir/$file >/dev/null 2>/dev/null ;
 554   then
 555     echo "removing $file, which is identical to the system global version"
 556     rm -f $file.new
 557   else
 558     mv $file.new $file
 559   fi
 560 done
 561
 562
 563 # Final clean-up
 564 if test $lyx_keep_temps = no ; then
 565 rm -f chkconfig.sed chkconfig.vars wrap_chkconfig.* chklayouts.tex \
 566       missfont.log
 567 fi