lib/configure.m4

   1 #! /bin/sh
   2 dnl Use 'make' to create configure from this m4 script.
   3 # This script is a hand-made configure script. It contains a lot of
   4 # code stolen from GNU autoconf. I removed all the code that was not
   5 # useful for configuring a LyX installation.
   6
   7
   8 dnl ######### Begin M4 macros #########################################
   9 dnl This is a template for my stripped-down configure script.
  10 dnl First, a few convenient macros.
  11 changequote([,])dnl
  12 dnl
  13 dnl
  14 dnl MSG_CHECKING(FEATURE-DESCRIPTION,PREFIX)
  15 dnl
  16 define(MSG_CHECKING,
  17 [echo $ac_n "$2checking $1""... $ac_c"])dnl
  18 dnl
  19 dnl
  20 dnl MSG_RESULT(RESULT-DESCRIPTION)
  21 dnl
  22 define(MSG_RESULT,
  23 [echo "$ac_t""$1"])dnl
  24 dnl
  25 dnl
  26 dnl SEARCH_PROG(FEATURE-DESCRIPTION,VARIABLE-NAME,PROGRAMS-LIST,
  27 dnl             ACTION-IF-FOUND,ACTION-IF-NOT-FOUND)
  28 dnl
  29 define(SEARCH_PROG,[dnl
  30 changequote([,])dnl
  31 MSG_CHECKING($1)
  32 MSG_RESULT(($3))
  33 $2=
  34 for ac_prog in $3
  35 do
  36 # Extract the first word of "$ac_prog", so it can be a program name with args.
  37 set dummy $ac_prog ; ac_word=$[2]
  38 if test -n "$ac_word"; then
  39   MSG_CHECKING([for \"$ac_word\"],[+])
  40   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS=":"
  41   for ac_dir in $PATH; do
  42     test -z "$ac_dir" && ac_dir=.
  43     if test -x [$ac_dir/$ac_word]; then
  44       $2="$ac_prog"
  45       break
  46     fi
  47   done
  48   IFS="$ac_save_ifs"
  49
  50   if test -n "[$]$2"; then
  51     ac_result=yes
  52   else
  53     ac_result=no
  54   fi
  55   ifelse($4,,,[$4])
  56   MSG_RESULT($ac_result)
  57   test -n "[$]$2" && break
  58 fi
  59 done
  60
  61 if test -z "[$]$2" ; then
  62   $2=none
  63 ifelse($5,,,[  $5
  64 ])dnl
  65 fi
  66 changequote(,)dnl
  67 ])dnl
  68 dnl
  69 dnl
  70 dnl PROVIDE_DEFAULT_FILE(FILE, DEFAULT-VALUE)
  71 dnl
  72 define(PROVIDE_DEFAULT_FILE,[dnl
  73 # if $1 does not exist (because LaTeX did not run),
  74 # then provide a standard version.
  75 if test ! -f $1 ; then
  76   cat >$1 <<EOF
  77 $2
  78 EOF
  79 fi])
  80 changequote(,)dnl
  81 dnl ######### End M4 macros #############################################
  82
  83
  84 ####some configuration variables
  85 lyx_check_config=yes
  86 lyx_keep_temps=no
  87 srcdir=
  88 lyx_suffix=
  89
  90 #### Parse the command line
  91 for ac_option do
  92   case "$ac_option" in
  93     -help | --help | -h)
  94       cat << EOF
  95 Usage: configure [options]
  96 Options:
  97   --help                   show this help lines
  98   --keep-temps             keep temporary files (for debug. purposes)
  99   --without-latex-config   do not run LaTeX to determine configuration
 100   --with-lyx-suffix=suffix suffix of binary installed files
 101 EOF
 102       exit 0;;
 103     --without-latex-config)
 104       lyx_check_config=no ;;
 105     --keep-temps)
 106       lyx_keep_temps=yes ;;
 107     --with-lyx-suffix*)
 108       lyx_suffix=`echo "$ac_option" | sed 's,--with-lyx-suffix=,,;s,^,-,'`
 109   esac
 110 done
 111
 112
 113 #### Checking for some echo oddities
 114 if (echo "testing\c"; echo 1,2,3) | grep c >/dev/null; then
 115   # Stardent Vistra SVR4 grep lacks -e, says ghazi@caip.rutgers.edu.
 116   if (echo -n testing; echo 1,2,3) | sed s/-n/xn/ | grep xn >/dev/null; then
 117     ac_n= ac_c='
 118 ' ac_t='        '
 119   else
 120     ac_n=-n ac_c= ac_t=
 121   fi
 122 else
 123   ac_n= ac_c='\c' ac_t=
 124 fi
 125
 126
 127 #### I do not really know why this is useful, but we might as well keep it.
 128 # NLS nuisances.
 129 # Only set these to C if already set.  These must not be set unconditionally
 130 # because not all systems understand e.g. LANG=C (notably SCO).
 131 # Fixing LC_MESSAGES prevents Solaris sh from translating var values in `set'!
 132 # Non-C LC_CTYPE values break the ctype check.
 133 if test "${LANG+set}"   = set; then LANG=C;   export LANG;   fi
 134 if test "${LC_ALL+set}" = set; then LC_ALL=C; export LC_ALL; fi
 135 if test "${LC_MESSAGES+set}" = set; then LC_MESSAGES=C; export LC_MESSAGES; fi
 136 if test "${LC_CTYPE+set}"    = set; then LC_CTYPE=C;    export LC_CTYPE;    fi
 137
 138
 139 #### Guess the directory in which configure is located.
 140 changequote([,])dnl
 141 ac_prog=[$]0
 142 changequote(,)dnl
 143 srcdir=`echo $ac_prog|sed 's%/[^/][^/]*$%%'`
 144 srcdir=`echo "${srcdir}" | sed 's%\([^/]\)/*$%\1%'`
 145 test "x$srcdir" = "x$ac_prog" && srcdir=.
 146 if test ! -r ${srcdir}/chkconfig.ltx ; then
 147   echo "configure: error: cannot find chkconfig.ltx script"
 148   exit 1
 149 fi
 150
 151
 152 #### Create the build directories if necessary
 153 for dir in bind clipart doc examples images kbd layouts reLyX \
 154     scripts templates ui ; do
 155   test ! -d $dir && mkdir $dir
 156 done
 157
 158
 159 #### Searching some useful programs
 160 define(CHECKLATEX2E,[
 161 ## Check whether this is really LaTeX2e
 162 rm -f chklatex.ltx
 163 cat >chklatex.ltx <<EOF
 164 \\nonstopmode\\makeatletter
 165 \\ifx\\undefined\\documentclass\\else
 166   \\message{ThisIsLaTeX2e}
 167 \\fi
 168 \\@@end
 169 EOF
 170 if eval ${LATEX} chklatex.ltx </dev/null 2>/dev/null \
 171                        | grep 'ThisIsLaTeX2e' >/dev/null; then
 172   :
 173 else
 174   LATEX=
 175   ac_result="not useable"
 176 fi
 177 rm -f chklatex.ltx chklatex.log])dnl
 178 dnl
 179 # Search LaTeX2e
 180 SEARCH_PROG([for a LaTeX2e program],LATEX,latex latex2e,CHECKLATEX2E,dnl
 181   [lyx_check_config=no])
 182 if test x$lyx_check_config != x ; then
 183 SEARCH_PROG([for the pdflatex program],PDFLATEX,pdflatex,CHECKLATEX2E)
 184 fi
 185
 186 # Search for an installed reLyX or a ready-to-install one
 187 save_PATH=${PATH}
 188 PATH=${PATH}:./reLyX/
 189 SEARCH_PROG([for a LaTeX -> LyX converter],tex_to_lyx_command,reLyX)
 190 PATH=${save_PATH}
 191 test $tex_to_lyx_command = "reLyX" && tex_to_lyx_command="reLyX -f \$\$i"
 192 tex_to_lyx_command=`echo $tex_to_lyx_command | sed "s,reLyX,reLyX$lyx_suffix,"`
 193
 194 SEARCH_PROG([for a Noweb -> LyX converter],literate_to_lyx_command,noweb2lyx)
 195 test $literate_to_lyx_command = "noweb2lyx" && literate_to_lyx_command="noweb2lyx \$\$i \$\$o"
 196 literate_to_lyx_command=`echo $literate_to_lyx_command | sed "s,noweb2lyx,noweb2lyx$lyx_suffix,"`
 197
 198 # Search something to process a literate document
 199 SEARCH_PROG([for a Noweb -> LaTeX converter],literate_to_tex_command,noweave)
 200 test $literate_to_tex_command = "noweave" && literate_to_tex_command="noweave -delay -index \$\$i > \$\$o"
 201
 202 SEARCH_PROG([for a HTML -> Latex converter],html_to_latex_command,html2latex)
 203 test $html_to_latex_command = "html2latex" && html_to_latex_command="html2latex \$\$i"
 204
 205 SEARCH_PROG([for a MSWord -> Latex converter],word_to_latex_command,wvCleanLatex word2x)
 206 test "$word_to_latex_command" = "wvCleanLatex" && word_to_latex_command="wvCleanLatex \$\$i \$\$o"
 207 test "$word_to_latex_command" = "word2x" && word_to_latex_command="word2x -f latex \$\$i"
 208
 209 SEARCH_PROG([for Image converter],image_command,convert)
 210 test $image_command = "convert" && image_command="convert \$\$i \$\$o"
 211
 212 # Search for a Postscript interpreter
 213 SEARCH_PROG([for a Postscript interpreter],GS, gs)
 214
 215 # Search something to preview postscript
 216 SEARCH_PROG([for a Postscript previewer],GHOSTVIEW,gv ghostview)
 217
 218 # Search for a program to preview pdf
 219 SEARCH_PROG([for a PDF preview],PDF_VIEWER,acroread gv ghostview xpdf)
 220
 221 # Search something to preview dvi
 222 SEARCH_PROG([for a DVI previewer],DVI_VIEWER, xdvi)
 223
 224 # Search something to preview html
 225 SEARCH_PROG([for a HTML previewer],HTML_VIEWER, netscape)
 226
 227 # Search for a program to convert ps to pdf
 228 SEARCH_PROG([for a PS to PDF converter],ps_to_pdf_command,ps2pdf)
 229 test $ps_to_pdf_command = "ps2pdf" && ps_to_pdf_command="ps2pdf \$\$i"
 230
 231 # Search for a program to convert dvi to ps
 232 SEARCH_PROG([for a DVI to PS converter],dvi_to_ps_command,dvips)
 233 test $dvi_to_ps_command = "dvips" && dvi_to_ps_command="dvips -o \$\$o \$\$i"
 234
 235 # Search for a program to convert dvi to pdf
 236 SEARCH_PROG([for a DVI to PDF converter],dvi_to_pdf_command,dvipdfm)
 237 test $dvi_to_pdf_command = "dvipdfm" && dvi_to_pdf_command="dvipdfm \$\$i"
 238
 239 # Search a *roff program (used to translate tables in ASCII export)
 240 SEARCH_PROG([for a *roff formatter],ROFF,groff nroff)
 241 ascii_roff_command=$ROFF
 242 test $ROFF = "groff" && ascii_roff_command="groff -t -Tlatin1 \$\$FName"
 243 test $ROFF = "nroff" && ascii_roff_command="tbl \$\$FName | nroff"
 244
 245 # Search the ChkTeX program
 246 SEARCH_PROG([for ChkTeX],CHKTEX,chktex)
 247 chktex_command=$CHKTEX
 248 test $CHKTEX = "chktex" && chktex_command="$CHKTEX -n1 -n3 -n6 -n9 -n22 -n25 -n30 -n38"
 249
 250 # Search for a spellchecker
 251 SEARCH_PROG([for a spell-checker], SPELL,ispell)
 252
 253 dnl # Search a Fax handling program
 254 dnl SEARCH_PROG([for a fax driver], FAX, sendfax faxsend fax)
 255 dnl if test $FAX = sendfax ; then
 256 dnl   fax_command="sendfax -n -h '\$\$Host' -c '\$\$Comment' -x '\$\$Enterprise' -d '\$\$Name'@'\$\$Phone' '\$\$FName'"
 257 dnl elif test $FAX = faxsend ; then
 258 dnl   fax_command="faxsend '\$\$Phone' '\$\$FName'"
 259 dnl elif test $FAX = fax ; then
 260 dnl   fax_command="fax send '\$\$Phone' '\$\$FName'"
 261 dnl else
 262 dnl   fax_command="none"
 263 dnl fi
 264
 265 # Search a GUI Fax program
 266 SEARCH_PROG([for a fax program], fax_command, ksendfax)
 267 test $fax_command = "ksendfax" && fax_command="ksendfax \$\$i"
 268
 269 # Search for LinuxDoc support
 270 SEARCH_PROG([for SGML-tools 1.x (LinuxDoc)], LINUXDOC, sgml2lyx)
 271 chk_linuxdoc=no
 272 if test $LINUXDOC != none; then
 273   chk_linuxdoc=yes
 274   linuxdoc_cmd="\\def\\haslinuxdoc{yes}"
 275 fi
 276
 277 case $LINUXDOC in
 278   sgml2lyx)
 279     linuxdoc_to_latex_command="sgml2latex \$\$i"
 280     linuxdoc_to_dvi_command="sgml2latex -o dvi \$\$i"
 281     linuxdoc_to_html_command="sgml2html \$\$i"
 282     linuxdoc_to_lyx_command="sgml2lyx \$\$i";;
 283   none)
 284     linuxdoc_to_latex_command="none"
 285     linuxdoc_to_dvi_command="none"
 286     linuxdoc_to_html_command="none"
 287     linuxdoc_to_lyx_command="none";;
 288 esac
 289
 290 # Search for DocBook support
 291 SEARCH_PROG([for SGML-tools 2.x (DocBook) or db2x scripts], DOCBOOK, sgmltools db2dvi)
 292 chk_docbook=no
 293 if test $DOCBOOK != none; then
 294   chk_docbook=yes
 295   docbook_cmd="\\def\\hasdocbook{yes}"
 296 fi
 297
 298 case $DOCBOOK in
 299   sgmltools)
 300     docbook_to_dvi_command="sgmltools -b dvi \$\$i"
 301     docbook_to_html_command="sgmltools -b html \$\$i";;
 302   db2dvi)
 303     docbook_to_dvi_command="db2dvi \$\$i"
 304     docbook_to_html_command="db2html \$\$i";;
 305   none)
 306     docbook_to_dvi_command="none"
 307     docbook_to_html_command="none";;
 308 esac
 309
 310 # Search for a spool command
 311 SEARCH_PROG([for a spool command], LPR, lp lpr)
 312 case $LPR in
 313   lp) print_spool_command=lp
 314       print_spool_printerprefix="-d ";;
 315  lpr) print_spool_command=lpr
 316       print_spool_printerprefix="-P";;
 317    *) :;; # leave to empty values
 318 esac
 319
 320 SEARCH_PROG([for a LaTeX -> HTML converter], TOHTML, tth latex2html hevea)
 321 latex_to_html_command=$TOHTML
 322 case $TOHTML in
 323         tth) latex_to_html_command="tth -t -e2 -L\$\$b < \$\$i > \$\$o";;
 324  latex2html) latex_to_html_command="latex2html -no_subdir -split 0 -show_section_numbers \$\$i";;
 325       hevea) latex_to_html_command="hevea -s \$\$i";;
 326 esac
 327
 328 #### Explore the LaTeX configuration
 329 MSG_CHECKING(LaTeX configuration)
 330 # First, remove the files that we want to re-create
 331 rm -f textclass.lst packages.lst chkconfig.sed
 332 if test ${lyx_check_config} = no ; then
 333   MSG_RESULT(default values)
 334 else
 335   MSG_RESULT(auto)
 336   rm -f wrap_chkconfig.ltx chkconfig.vars chkconfig.classes chklayouts.tex
 337   cat >wrap_chkconfig.ltx <<EOF
 338 \\newcommand\\srcdir{${srcdir}}
 339 ${linuxdoc_cmd}
 340 ${docbook_cmd}
 341 \\input{${srcdir}/chkconfig.ltx}
 342 EOF
 343   ## Construct the list of classes to test for.
 344   # build the list of available layout files and convert it to commands
 345   # for chkconfig.ltx
 346   for file in ./layouts/*.layout ${srcdir}/layouts/*.layout ; do
 347     case $file in
 348       */\*.layout) ;;
 349       *) test -r "$file" && echo $file ;;
 350     esac
 351   done | sed -e 's%^.*layouts/\(.*\)\.layout$%\\TestDocClass{\1}%'\
 352              > chklayouts.tex
 353 changequote([,])dnl
 354   [eval] ${LATEX} wrap_chkconfig.ltx 2>/dev/null | grep '^\+'
 355   [eval] `cat chkconfig.vars | sed 's/-/_/g'`
 356 changequote(,)dnl
 357 fi
 358
 359 # Do we have all the files we need? Useful if latex did not run
 360 changequote([,])dnl
 361 echo creating textclass.lst
 362 PROVIDE_DEFAULT_FILE(textclass.lst,dnl
 363 [# This file declares layouts and their associated definition files
 364 # (include dir. relative to the place where this file is).
 365 # It contains only default values, since chkconfig.ltx could not be run
 366 # for some reason. Run ./configure if you need to update it after a
 367 # configuration change.
 368 article article article
 369 report  report  report
 370 book    book    book
 371 linuxdoc        linuxdoc        linuxdoc
 372 letter  letter  letter])
 373
 374 PROVIDE_DEFAULT_FILE(chkconfig.sed,[s/@.*@/???/g])
 375
 376 echo creating packages.lst
 377 PROVIDE_DEFAULT_FILE(packages.lst,dnl
 378 [# This file should contain the list of LaTeX packages that have been
 379 # recognized by LyX. Unfortunately, since configure could not find
 380 # your LaTeX2e program, the tests have not been run. Run ./configure
 381 # if you need to update it after a configuration change.
 382 ])
 383 changequote(,)dnl
 384
 385 echo creating doc/LaTeXConfig.lyx
 386 echo "s/@chk_linuxdoc@/$chk_linuxdoc/g" >> chkconfig.sed
 387 echo "s/@chk_docbook@/$chk_docbook/g" >> chkconfig.sed
 388 sed -f chkconfig.sed ${srcdir}/doc/LaTeXConfig.lyx.in >doc/LaTeXConfig.lyx
 389
 390 echo creating lyxrc.defaults
 391 rm -f lyxrc.defaults
 392 cat >lyxrc.defaults <<EOF
 393 # This file has been automatically generated by LyX' lib/configure
 394 # script. It contains default settings that have been determined by
 395 # examining your system. PLEASE DO NOT MODIFY ANYTHING HERE! If you
 396 # want to customize LyX, make a copy of the file LYXDIR/lyxrc as
 397 # ~/.lyx/lyxrc and edit this file instead. Any setting in lyxrc will
 398 # override the values given here.
 399 \\Format text     txt   ASCII           A
 400 \\Format textparagraph txt ASCII(paragraphs)    ""
 401 \\Format docbook  sgml  DocBook         B
 402 \\Format dvi      dvi   DVI             D
 403 \\Format eps      eps   EPS             ""
 404 \\Format fax      ""    Fax             ""
 405 \\Format gif      gif   GIF             ""
 406 \\Format html     html  HTML            H
 407 \\Format jpg      jpg   JPEG            ""
 408 \\Format latex    tex   LaTeX           L
 409 \\Format linuxdoc sgml  LinuxDoc        x
 410 \\Format lyx      lyx   LyX             ""
 411 \\Format literate nw    NoWeb           N
 412 \\Format pdf      pdf   PDF             P
 413 \\Format pdf2     pdf  "PDF (pdflatex)" F
 414 \\Format pdf3     pdf  "PDF (dvipdfm)"  m
 415 \\Format png      png   PNG             ""
 416 \\Format ps       ps    Postscript      t
 417 \\Format program  ""    Program         ""
 418 \\Format word     doc   Word            W
 419
 420
 421 \\converter latex dvi "$LATEX \$\$i" "latex"
 422 \\converter latex pdf2 "$PDFLATEX \$\$i" "latex"
 423 \\converter latex html "$latex_to_html_command" "originaldir,needaux"
 424 \\converter literate latex "$literate_to_tex_command" ""
 425 \\converter dvi pdf3 "$dvi_to_pdf_command" ""
 426 \\converter dvi ps "$dvi_to_ps_command" ""
 427 \\converter ps pdf "$ps_to_pdf_command" ""
 428 \\converter ps fax "$fax_command" ""
 429 \\converter linuxdoc lyx "$linuxdoc_to_lyx_command" ""
 430 \\converter linuxdoc latex "$linuxdoc_to_latex_command" ""
 431 \\converter linuxdoc dvi "$linuxdoc_to_dvi_command" ""
 432 \\converter linuxdoc html "$linuxdoc_to_html_command" ""
 433 \\converter docbook dvi "$docbook_to_dvi_command" ""
 434 \\converter docbook html "$docbook_to_html_command" ""
 435
 436 \\converter latex lyx "$tex_to_lyx_command" ""
 437 \\converter literate lyx "$literate_to_lyx_command" ""
 438 \\converter html latex "$html_to_latex_command" ""
 439 \\converter word latex "$word_to_latex_command" ""
 440
 441 \converter gif eps "$image_command" ""
 442 \converter png eps "$image_command" ""
 443 \converter jpg eps "$image_command" ""
 444 \converter gif png "$image_command" ""
 445
 446 \\viewer dvi "$DVI_VIEWER"
 447 \\viewer html "$HTML_VIEWER"
 448 \\viewer pdf "$PDF_VIEWER"
 449 \\viewer ps "$GHOSTVIEW -swap"
 450 \\viewer eps "$GHOSTVIEW"
 451
 452 \\ps_command "$GS"
 453 \\ascii_roff_command "$ascii_roff_command"
 454 \\chktex_command "$chktex_command"
 455 \\spell_command "$SPELL"
 456 dnl \\fax_command "$fax_command"
 457 \\print_spool_command "$print_spool_command"
 458 \\print_spool_printerprefix "$print_spool_printerprefix"
 459 \\font_encoding "$chk_fontenc"
 460 EOF
 461
 462 # Remove superfluous files if we are not writing in the main lib
 463 # directory
 464 for file in lyxrc.defaults textclass.lst packages.lst \
 465             doc/LaTeXConfig.lyx ; do
 466   # we rename the file first, so that we avoid comparing a file with itself
 467   mv $file $file.new
 468   if test -r $srcdir/$file && diff $file.new $srcdir/$file >/dev/null 2>/dev/null ;
 469   then
 470     echo "removing $file, which is identical to the system global version"
 471     rm -f $file.new
 472   else
 473     mv $file.new $file
 474   fi
 475 done
 476
 477
 478 # Final clean-up
 479 if test $lyx_keep_temps = no ; then
 480 rm -f chkconfig.sed chkconfig.vars wrap_chkconfig.* chklayouts.tex \
 481       missfont.log
 482 fi