development/cmake/src/frontends/qt4/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 project(frontend_qt4)
   8
   9
  10 file(GLOB frontends_qt4_sources ${TOP_SRC_DIR}/src/frontends/qt4/${LYX_CPP_FILES})
  11 file(GLOB frontends_qt4_headers ${TOP_SRC_DIR}/src/frontends/qt4/${LYX_HPP_FILES})
  12 file(GLOB frontend_qt4_UI       ${TOP_SRC_DIR}/src/frontends/qt4/ui/*.ui)
  13
  14 lyx_add_msvc_pch(frontends_qt4)
  15
  16 lyx_automoc(${frontends_qt4_sources})
  17
  18 lyx_add_ui_files(frontends_qt4_sources ui_files ${frontend_qt4_UI})
  19
  20 add_definitions(
  21                 -DQT_CLEAN_NAMESPACE
  22                 -DQT_GENUINE_STR
  23                 -DQT_NO_STL
  24                 -DQT_NO_KEYWORDS
  25                 -DLYX_BUILD_QT4_FRONTEND
  26                 )
  27
  28
  29 include_directories(
  30                         ${TOP_SRC_DIR}/src/frontends/qt4
  31                         ${TOP_SRC_DIR}/src/frontends/controllers
  32                         ${CMAKE_CURRENT_BINARY_DIR})
  33
  34 if(MERGE_FILES)
  35         list(REMOVE_ITEM frontends_qt4_sources ${TOP_SRC_DIR}/src/frontends/qt4/QCommandEdit.cpp)
  36         list(APPEND frontends_qt4_sources ${TOP_SRC_DIR}/src/frontends/qt4/QCommandEdit.cpp)
  37         list(REVERSE frontends_qt4_sources)
  38         list(REMOVE_ITEM frontends_qt4_sources ${TOP_SRC_DIR}/src/frontends/qt4/GuiApplication.cpp)
  39         list(APPEND frontends_qt4_sources ${TOP_SRC_DIR}/src/frontends/qt4/GuiApplication.cpp)
  40         lyx_const_touched_files(_allinone frontends_qt4_sources)
  41         set(depends_moc_uic ${frontends_qt4_headers} ${ui_files})
  42         SET_SOURCE_FILES_PROPERTIES(_allinone_const.C PROPERTIES OBJECT_DEPENDS "${depends_moc_uic}")
  43         SET_SOURCE_FILES_PROPERTIES(_allinone_touched.C PROPERTIES OBJECT_DEPENDS "${depends_moc_uic}")
  44         add_library(frontend_qt4 ${library_type}
  45                                         ${_allinone_files}
  46                                         ${frontends_qt4_headers}
  47                                         ${ui_files}
  48         )
  49 else(MERGE_FILES)
  50         add_library(frontend_qt4 ${library_type}  ${frontends_qt4_sources} ${frontends_qt4_headers} ${ui_files})
  51 endif(MERGE_FILES)
  52
  53 target_link_libraries(frontend_qt4 ${QT_QTCORE_LIBRARY} ${QT_QTGUI_LIBRARY} controllers)
  54
  55 if(WIN32)
  56         target_link_libraries(frontend_qt4 Gdi32)
  57 endif(WIN32)
  58
  59 project_source_group("${GROUP_CODE}" frontends_qt4_sources frontends_qt4_headers)
  60 source_group("Uic files" FILES ${frontend_qt4_UI})
  61