development/cmake/src/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 set(_lyx ${PACKAGE_BASE}${PROGRAM_SUFFIX})
   8 project(${_lyx})
   9
  10 include_directories(${TOP_SRC_DIR}/src)
  11
  12 add_subdirectory(frontends)
  13 add_subdirectory(graphics)
  14 add_subdirectory(insets)
  15 add_subdirectory(mathed)
  16 add_subdirectory(support)
  17 add_subdirectory(tex2lyx)
  18 if (UNIX)
  19   add_subdirectory(client)
  20 endif()
  21
  22 file(GLOB lyx_sources ${TOP_SRC_DIR}/src/${LYX_CPP_FILES})
  23 file(GLOB lyx_headers ${TOP_SRC_DIR}/src/${LYX_HPP_FILES})
  24
  25 list(REMOVE_ITEM lyx_sources
  26         ${TOP_SRC_DIR}/src/ASpell.cpp
  27         ${TOP_SRC_DIR}/src/PSpell.cpp
  28         ${TOP_SRC_DIR}/src/ISpell.cpp
  29         ${TOP_SRC_DIR}/src/Variables.cpp
  30         ${TOP_SRC_DIR}/src/Section.cpp)
  31
  32 if (ASPELL_FOUND)
  33   include_directories(${ASPELL_INCLUDE_DIR})
  34   list(APPEND lyx_sources ${TOP_SRC_DIR}/src/ASpell.cpp)
  35 endif()
  36
  37 include_directories(${CMAKE_CURRENT_BINARY_DIR}
  38         ${ZLIB_INCLUDE_DIR} ${QT_INCLUDES})
  39
  40 lyx_add_msvc_pch(lyx)
  41
  42
  43 if (MERGE_FILES)
  44   lyx_const_touched_files(_allinone  lyx_sources)
  45   set(lyx_sources ${_allinone_files})
  46 endif()
  47
  48 if (LYX_LEAK_DETECTION)
  49         configure_file(${vld_path}/vld.ini ${CMAKE_CURRENT_BINARY_DIR}/vld.ini COPYONLY)
  50         configure_file(${vld_path}/vld.ini ${CMAKE_CURRENT_BINARY_DIR}/memory_leak_report.txt COPYONLY)
  51         set(vld_files ${CMAKE_CURRENT_BINARY_DIR}/vld.ini ${CMAKE_CURRENT_BINARY_DIR}/memory_leak_report.txt)
  52 endif()
  53
  54 add_executable(${_lyx}
  55         ${WIN32_CONSOLE}
  56         ${lyx_sources}
  57         ${lyx_headers}
  58         ${vld_files}
  59 )
  60
  61 target_link_libraries(${_lyx}
  62         mathed
  63         insets
  64         frontends
  65         frontend_qt4
  66         graphics
  67         support
  68         ${LIBINTL_LIBRARIES}
  69         ${ICONV_LIBRARY}
  70         ${QT_QTMAIN_LIBRARY}
  71         ${vld_dll})
  72
  73 if (ASPELL_FOUND)
  74         target_link_libraries(${_lyx} ${ASPELL_LIBRARY})
  75 endif()
  76
  77 if (APPLE)
  78   target_link_libraries(${_lyx} "-bind_at_load")
  79   target_link_libraries(${_lyx} "-framework Carbon")
  80 endif()
  81
  82 if (MINGW)
  83   target_link_libraries(${_lyx} ole32)
  84 endif()
  85
  86 project_source_group("${GROUP_CODE}" lyx_sources lyx_headers)
  87
  88 install(TARGETS ${_lyx} DESTINATION bin)
  89