development/cmake/src/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 set(_lyx ${PACKAGE_BASE}${PROGRAM_SUFFIX})
   8 project(${_lyx})
   9
  10 include_directories(${TOP_SRC_DIR}/src)
  11
  12 add_subdirectory(frontends)
  13 add_subdirectory(graphics)
  14 add_subdirectory(insets)
  15 add_subdirectory(mathed)
  16 add_subdirectory(support)
  17 add_subdirectory(tex2lyx)
  18 if (UNIX)
  19   add_subdirectory(client)
  20 endif()
  21
  22 file(GLOB lyx_sources ${TOP_SRC_DIR}/src/${LYX_CPP_FILES})
  23 file(GLOB moc_files ${TOP_SRC_DIR}/src/${LYX_MOC_FILES})
  24 list(REMOVE_ITEM  lyx_sources ${moc_files} .)
  25 file(GLOB lyx_headers ${TOP_SRC_DIR}/src/${LYX_HPP_FILES})
  26
  27 list(REMOVE_ITEM lyx_sources
  28         ${TOP_SRC_DIR}/src/Variables.cpp
  29         ${TOP_SRC_DIR}/src/Section.cpp
  30         ${TOP_SRC_DIR}/src/lyxcore.cpp
  31         ${TOP_SRC_DIR}/src/lyxinsets.cpp
  32         ${TOP_SRC_DIR}/src/lyxmathed.cpp)
  33
  34 list(REMOVE_ITEM lyx_headers
  35         ${TOP_SRC_DIR}/src/Variables.h
  36         ${TOP_SRC_DIR}/src/Section.h)
  37
  38 if(NOT APPLE)
  39         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/AppleSpellChecker.cpp)
  40         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/AppleSpellChecker.h)
  41 endif()
  42
  43 if(NOT ASPELL_FOUND)
  44         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/AspellChecker.cpp)
  45         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/AspellChecker.h)
  46 else()
  47         set(dont_merge ${dont_merge} ${TOP_SRC_DIR}/src/AspellChecker.cpp)
  48 endif()
  49
  50 if(NOT ENCHANT_FOUND)
  51         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/EnchantChecker.cpp)
  52         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/EnchantChecker.h)
  53 else()
  54         set(dont_merge ${dont_merge} ${TOP_SRC_DIR}/src/EnchantChecker.cpp)
  55 endif()
  56
  57 if(NOT HUNSPELL_FOUND)
  58         list(REMOVE_ITEM lyx_sources ${TOP_SRC_DIR}/src/HunspellChecker.cpp)
  59         list(REMOVE_ITEM lyx_headers ${TOP_SRC_DIR}/src/HunspellChecker.h)
  60 else()
  61         set(dont_merge ${dont_merge} ${TOP_SRC_DIR}/src/HunspellChecker.cpp)
  62 endif()
  63
  64
  65 lyx_automoc(${TOP_SRC_DIR}/src/Compare.cpp)
  66 if (WIN32)
  67   lyx_automoc(${TOP_SRC_DIR}/src/Server.cpp)
  68 endif()
  69
  70 include_directories(${CMAKE_CURRENT_BINARY_DIR}
  71         ${ZLIB_INCLUDE_DIR} ${QT_INCLUDES})
  72
  73 lyx_add_msvc_pch(lyx)
  74
  75
  76 if (LYX_MERGE_FILES)
  77         if(dont_merge)
  78                 list(REMOVE_ITEM lyx_sources ${dont_merge})
  79         endif()
  80         lyx_const_touched_files(_allinone lyx_sources)
  81         set(lyx_sources ${_allinone_files} ${dont_merge})
  82 endif()
  83
  84 if (LYX_VLD)
  85         configure_file(${vld_path}/vld.ini ${CMAKE_CURRENT_BINARY_DIR}/vld.ini COPYONLY)
  86         configure_file(${vld_path}/vld.ini ${CMAKE_CURRENT_BINARY_DIR}/memory_leak_report.txt COPYONLY)
  87         set(vld_files ${CMAKE_CURRENT_BINARY_DIR}/vld.ini ${CMAKE_CURRENT_BINARY_DIR}/memory_leak_report.txt)
  88 endif()
  89
  90 if(WIN32)
  91         set(FILE_RC ${CMAKE_SOURCE_DIR}/lyx.rc)
  92         message(STATUS "Using icon defined in resource file: ${FILE_RC}")
  93 endif()
  94
  95 add_executable(${_lyx}
  96         ${WIN32_CONSOLE}
  97         ${lyx_sources}
  98         ${lyx_headers}
  99         ${vld_files}
 100         ${FILE_RC}
 101 )
 102
 103 lyx_add_gcc_pch(${_lyx})
 104
 105 target_link_libraries(${_lyx}
 106         mathed
 107         insets
 108         frontends
 109         frontend_qt4
 110         graphics
 111         support
 112         ${LIBINTL_LIBRARIES}
 113         ${ICONV_LIBRARY}
 114         ${QT_QTMAIN_LIBRARY}
 115         ${vld_dll})
 116
 117 if (HUNSPELL_FOUND)
 118         target_link_libraries(${_lyx} ${HUNSPELL_LIBRARY})
 119 endif()
 120 if (ASPELL_FOUND)
 121         target_link_libraries(${_lyx} ${ASPELL_LIBRARY})
 122 endif()
 123 if (ENCHANT_FOUND)
 124     target_link_libraries(${_lyx} ${ENCHANT_LIBRARY})
 125 endif()
 126
 127 if (APPLE)
 128   target_link_libraries(${_lyx} "-bind_at_load")
 129   target_link_libraries(${_lyx} "-framework Carbon")
 130 endif()
 131
 132 if (MINGW)
 133   target_link_libraries(${_lyx} ole32)
 134 endif()
 135
 136 project_source_group("${GROUP_CODE}" lyx_sources lyx_headers)
 137
 138 install(TARGETS ${_lyx} DESTINATION bin)
 139