development/cmake/scripts/LyXGetVersion.cmake

   1 #  Copyright (c) 2012-2014, Kornel Benko, <kornel@lyx.org>
   2 #
   3 #  Redistribution and use in source and binary forms, with or without
   4 #  modification, are permitted provided that the following conditions
   5 #  are met:
   6 #
   7 #  1. Redistributions of source code must retain the copyright
   8 #         notice, this list of conditions and the following disclaimer.
   9 #  2. Redistributions in binary form must reproduce the copyright
  10 #         notice, this list of conditions and the following disclaimer in the
  11 #         documentation and/or other materials provided with the distribution.
  12 #  3. The name of the author may not be used to endorse or promote products
  13 #         derived from this software without specific prior written permission.
  14 #
  15 #  THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  16 #  IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  17 #  OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  18 #  IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  19 #  INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  20 #  NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  21 #  DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  22 #  THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  23 #  (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  24 #  THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  25 #
  26 # To call this script, one has to provide following parameters
  27 # TOP_SRC_DIR
  28 # TOP_CMAKE_PATH
  29 # TOP_BINARY_DIR
  30 # LYX_DATE:     to be used if not under git control
  31
  32
  33 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  34
  35 set(LYX_GIT_COMMIT_HASH "none")
  36
  37 FIND_PROGRAM(LYX_GITVERSION git)
  38 if(LYX_GITVERSION)
  39   # Override the value from configure.ac, if possible
  40   EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} "log" "-1" "--format=%h %ci"
  41     WORKING_DIRECTORY "${TOP_SRC_DIR}"
  42     OUTPUT_VARIABLE LYX_DATEtmp OUTPUT_STRIP_TRAILING_WHITESPACE)
  43
  44   if(LYX_DATEtmp MATCHES "^([0-9a-f]+) ([0-9]+-[0-9]+-[0-9]+)")
  45     set(LYX_GITHASH ${CMAKE_MATCH_1})
  46     set(LYX_DATE ${CMAKE_MATCH_2})
  47     message(STATUS "Git-hash = ${LYX_GITHASH}")
  48   endif()
  49   EXECUTE_PROCESS(COMMAND ${LYX_GITVERSION} log -1 "--pretty=format:%H"
  50     WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE lyxgitcommit OUTPUT_STRIP_TRAILING_WHITESPACE)
  51   if (lyxgitcommit MATCHES "^[0-9a-f]+$")
  52     set(LYX_GIT_COMMIT_HASH ${lyxgitcommit})
  53   endif()
  54 endif()
  55
  56 foreach(_hf lyx_date lyx_commit_hash)
  57   if(NOT EXISTS ${TOP_BINARY_DIR}/${_hf}.h)
  58     configure_file(${TOP_CMAKE_PATH}/${_hf}.h.cmake ${TOP_BINARY_DIR}/${_hf}.h)
  59   else()
  60     configure_file(${TOP_CMAKE_PATH}/${_hf}.h.cmake ${TOP_BINARY_DIR}/${_hf}.tmp)
  61     message(STATUS "Created ${TOP_BINARY_DIR}/${_hf}.tmp")
  62
  63     EXECUTE_PROCESS(
  64       COMMAND ${CMAKE_COMMAND} -E copy_if_different ${TOP_BINARY_DIR}/${_hf}.tmp ${TOP_BINARY_DIR}/${_hf}.h
  65       ERROR_VARIABLE copy_err
  66     )
  67
  68     if(copy_err)
  69       message(FATAL_ERROR "${CMAKE_COMMAND} -E copy_if_different not working")
  70     endif()
  71
  72     EXECUTE_PROCESS(
  73       COMMAND ${CMAKE_COMMAND} -E remove ${TOP_BINARY_DIR}/${_hf}.tmp
  74     )
  75   endif()
  76 endforeach()
  77