development/cmake/post_install/CMakeLists.txt

   1 # Finish the construction of the bundle
   2 # by including the necessary QT libraries
   3
   4 set(QTPLUGINS "")
   5
   6 # Find a qt plugin and install it in the plugins directory
   7 macro(install_qt_plugin _qt_plugin_name)
   8     get_target_property(qtlib "${_qt_plugin_name}" LOCATION)
   9     if(EXISTS ${qtlib})
  10         get_filename_component(qtdir ${qtlib} PATH)
  11         get_filename_component(qtdir ${qtdir} NAME)
  12         # Installing QT plugin ${qtlib} into ${qtplugin_dest_dir}/plugins/${qtdir}
  13         install(FILES "${qtlib}" DESTINATION ${qtplugin_dest_dir}/plugins/${qtdir} COMPONENT Runtime)
  14     else()
  15         message(FATAL_ERROR "Could not find QT plugin ${_qt_plugin_name}")
  16     endif()
  17 endmacro()
  18
  19 if(LYX_BUNDLE)
  20     if(NOT APPLE)
  21         set(installed_lyx_path bin/${_lyx}${CMAKE_EXECUTABLE_SUFFIX})
  22         set(qtplugin_dest_dir bin)
  23         set(qt_conf_path bin/qt.conf)
  24     else()
  25         set(installed_lyx_path ${LYX_BUNDLE_NAME}.app)
  26         set(qtplugin_dest_dir "${LYX_BUNDLE_NAME}.app/Contents")
  27         set(qt_conf_path "${LYX_BUNDLE_NAME}.app/Contents/Resources/qt.conf")
  28     endif()
  29
  30     if(Qt5Core_FOUND)
  31         install_qt_plugin("Qt5::QJpegPlugin")
  32         install_qt_plugin("Qt5::QGifPlugin")
  33         install_qt_plugin("Qt5::QICOPlugin")
  34         if(APPLE)
  35             install_qt_plugin("Qt5::QCocoaIntegrationPlugin")
  36         endif()
  37     else()
  38         # With QT4, just copy all the plugins
  39         file(GLOB QT_PLUGIN_DIRECTORIES "${QT_PLUGINS_DIR}/*")
  40         install(DIRECTORY ${QT_PLUGIN_DIRECTORIES} DESTINATION "${qtplugin_dest_dir}/plugins/" COMPONENT Runtime)
  41     endif()
  42
  43     # Install code does the following:
  44     # - Creates the qt.conf file
  45     # - install the platform specific plugins (with Qt5)
  46     # - Fixup the bundle
  47     install(CODE "include(BundleUtilities)
  48                     file(WRITE \"\${CMAKE_INSTALL_PREFIX}/${qt_conf_path}\" \"\")
  49                     file(GLOB_RECURSE QTPLUGINS
  50                     \"\${CMAKE_INSTALL_PREFIX}/${qtplugin_dest_dir}/plugins/*/*${CMAKE_SHARED_LIBRARY_SUFFIX}\")
  51                     message(STATUS \"QT plugins [\${CMAKE_INSTALL_PREFIX}/${qtplugin_dest_dir}/plugins/*/*${CMAKE_SHARED_LIBRARY_SUFFIX}]: \${QTPLUGINS}\")
  52                     fixup_bundle(\"\${CMAKE_INSTALL_PREFIX}/${installed_lyx_path}\" \"\${QTPLUGINS}\" \"${QT_LIBRARY_DIRS}\")"
  53                     COMPONENT Runtime
  54             )
  55
  56     if (APPLE AND LYX_DMG)
  57         # Setup the disk image layout
  58         install(CODE "
  59             message(STATUS \"Creating the folder view options (.DS_Store)\")
  60             execute_process(COMMAND /bin/ln -sf /Applications \"\${CMAKE_INSTALL_PREFIX}\")
  61             execute_process(COMMAND /bin/bash \"${CMAKE_CURRENT_SOURCE_DIR}/../../MacOSX/set_bundle_display_options.sh\"
  62             \"${CMAKE_BINARY_DIR}/ds_store\" \"${_lyx}\" \"${TOP_CMAKE_PATH}/../MacOSX/dmg-background.png\" 560 364)
  63         ")
  64     endif()
  65 endif()