development/cmake/po/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2008, 2009 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008, 2009 Kornel Benko, <Kornel.Benko@berlin.de>
   6 #
   7
   8 project(po)
   9
  10 include_directories(${TOP_SRC_DIR}/po)
  11
  12 SET(_lyxname ${PACKAGE})
  13 SET(_py_sources)
  14 macro(add_gettext_python  _par _dir)
  15   set(_sources)
  16   foreach(_arg ${ARGN})
  17     file(GLOB _s1 ${TOP_SRC_DIR}/${_dir}/${_arg})
  18     list(SORT _s1)
  19     list(APPEND _sources ${_s1})
  20   endforeach(_arg)
  21   SET(_dst "${CMAKE_CURRENT_BINARY_DIR}/${_par}_l10n.pot")
  22   SET(_tmp_src_files "${CMAKE_CURRENT_BINARY_DIR}/${_par}_tmp_files")
  23   SET(_src_files "${CMAKE_CURRENT_BINARY_DIR}/${_par}_files")
  24   file(WRITE ${_tmp_src_files} "")
  25   foreach(_s ${_sources})
  26     FILE(APPEND ${_tmp_src_files} "${_s}\n")
  27   endforeach()
  28   if(${_par} MATCHES "^\(.*\)_[0-9]+$")
  29     set(_par1 ${CMAKE_MATCH_1})
  30   else()
  31     set(_par1 ${_par})
  32   endif()
  33   ADD_CUSTOM_COMMAND(
  34     OUTPUT ${_src_files}
  35     COMMAND ${CMAKE_COMMAND} -E copy_if_different ${_tmp_src_files} ${_src_files}
  36     DEPENDS ${_tmp_src_files}
  37   )
  38   ADD_CUSTOM_COMMAND(
  39     OUTPUT "${_dst}"
  40     PRE_BUILD
  41     COMMAND ${_PYTHON_EXECUTABLE}
  42     ARGS "${TOP_SRC_DIR}/po/lyx_pot.py" -b "${TOP_SRC_DIR}" -o "${_dst}" -t ${_par1} "--src_file=${_src_files}"
  43     DEPENDS ${_sources} ${_src_files}
  44     )
  45   SET_SOURCE_FILES_PROPERTIES("${_dst}" GENERATED)
  46   SET_SOURCE_FILES_PROPERTIES("${_src_files}" GENERATED)
  47   LIST(APPEND _py_sources "${_dst}")
  48 endmacro(add_gettext_python)
  49
  50 SET_SOURCE_FILES_PROPERTIES("${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot" GENERATED)
  51 SET_SOURCE_FILES_PROPERTIES("${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot" GENERATED)
  52 SET_SOURCE_FILES_PROPERTIES("${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot" GENERATED)
  53
  54 add_gettext_python(qt4 src/frontends/qt4/ui *.ui)
  55 add_gettext_python(layouts lib/layouts *.layout *.inc *.module)
  56 add_gettext_python(languages lib languages)
  57 add_gettext_python(encodings lib encodings)
  58 add_gettext_python(ui lib/ui *.ui *.inc)
  59 add_gettext_python(external lib external_templates)
  60 add_gettext_python(formats lib configure.py)
  61
  62 FIND_PROGRAM(GETTEXT_XGETTEXT_EXECUTABLE xgettext)
  63 FIND_PROGRAM(GETTEXT_MSGUNIQ_EXECUTABLE msguniq)
  64
  65 # TODO:
  66 #         We need here perl, because I don't know how
  67 #         to write the alternative for "cat" in python
  68 #         e.g. perl -e "\"while(<>){print;}\""
  69 # But maybe Jose knows?
  70
  71 ADD_CUSTOM_COMMAND(
  72     OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot"
  73     COMMAND ${_PYTHON_EXECUTABLE}
  74     ARGS   "${CMAKE_SOURCE_DIR}/po/cat.py" ${_py_sources} > "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot"
  75     DEPENDS ${_py_sources}
  76     )
  77
  78 ADD_CUSTOM_COMMAND(
  79     OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot"
  80     COMMAND ${GETTEXT_MSGUNIQ_EXECUTABLE}
  81     ARGS -o "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot" "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot"
  82     DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot"
  83     )
  84
  85 SET(_potfiles_dep)
  86
  87 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/POTFILES.in "")
  88 file(GLOB_RECURSE _tmp_potfiles RELATIVE ${TOP_SRC_DIR}/ ${TOP_SRC_DIR}/src/*.h  ${TOP_SRC_DIR}/src/*.cpp  ${TOP_SRC_DIR}/src/*.cpp.in)
  89 list(SORT _tmp_potfiles)
  90 list(REMOVE_ITEM _tmp_potfiles src/support/Package.cpp)
  91
  92 foreach(_f ${_tmp_potfiles})
  93   # we don't need to select only relevant files because the outcome of xgettext
  94   # will stay the same.
  95   # Relevant files are files containing the string '_(".*")'
  96   LIST(APPEND _potfiles_dep "${TOP_SRC_DIR}/${_f}")
  97   file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/POTFILES.in "${_f}\n")
  98 endforeach(_f)
  99
 100 ADD_CUSTOM_COMMAND(
 101     OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot"
 102     COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot" "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot"
 103     COMMAND ${GETTEXT_XGETTEXT_EXECUTABLE}
 104     ARGS --default-domain=${_lyxname} --directory=${TOP_SRC_DIR} --add-comments=TRANSLATORS: --language=C++ --join-existing --keyword=_ --keyword=N_ --keyword=B_ --keyword=qt_ --files-from="${CMAKE_CURRENT_BINARY_DIR}/POTFILES.in" --copyright-holder="LyX Developers" --msgid-bugs-address=lyx-devel@lists.lyx.org -o "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot"
 105     DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot" ${_potfiles_dep}
 106     )
 107
 108 #
 109 # We have to copy the po-files first,
 110 # otherwise they would be modified (inside the macro GETTEXT_CREATE_TRANSLATIONS())
 111 # This makes the "svn up" on po-files work again
 112 file(GLOB LYX_BASE_PO_FILES RELATIVE ${TOP_SRC_DIR}/po ${TOP_SRC_DIR}/po/*.po)
 113 set(LYX_PO_FILES)
 114 foreach(_pofile ${LYX_BASE_PO_FILES})
 115   add_custom_command(
 116     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}
 117     COMMAND ${CMAKE_COMMAND} -E copy ${TOP_SRC_DIR}/po/${_pofile} ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}
 118     DEPENDS ${TOP_SRC_DIR}/po/${_pofile}
 119     )
 120   list(APPEND LYX_PO_FILES ${CMAKE_CURRENT_BINARY_DIR}/${_pofile})
 121 endforeach(_pofile)
 122
 123 GETTEXT_CREATE_TRANSLATIONS(${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot ALL ${LYX_PO_FILES})
 124
 125 # ADD_POFILES("lyx")
 126