development/cmake/po/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2008-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6 #
   7
   8 project(po)
   9
  10 include_directories(${TOP_SRC_DIR}/po)
  11
  12 SET(_lyxname ${PACKAGE})
  13 SET(_py_sources)
  14 macro(add_gettext_python  _par _dir)
  15   set(_sources)
  16   foreach(_arg ${ARGN})
  17     file(GLOB _s1 ${TOP_SRC_DIR}/${_dir}/${_arg})
  18     list(SORT _s1)
  19     list(APPEND _sources ${_s1})
  20   endforeach(_arg)
  21   if (${_par} MATCHES "layouttranslations")
  22     SET(_dst "${CMAKE_CURRENT_BINARY_DIR}/${_par}")
  23   else ()
  24     SET(_dst "${CMAKE_CURRENT_BINARY_DIR}/${_par}_l10n.pot")
  25   endif()
  26   SET(_tmp_src_files "${CMAKE_CURRENT_BINARY_DIR}/${_par}_tmp_files")
  27   SET(_src_files "${CMAKE_CURRENT_BINARY_DIR}/${_par}_files")
  28   file(WRITE ${_tmp_src_files} "")
  29   foreach(_s ${_sources})
  30     FILE(APPEND ${_tmp_src_files} "${_s}\n")
  31   endforeach()
  32   if(${_par} MATCHES "^\(.*\)_[0-9]+$")
  33     set(_par1 ${CMAKE_MATCH_1})
  34   else()
  35     set(_par1 ${_par})
  36   endif()
  37   ADD_CUSTOM_COMMAND(
  38     OUTPUT ${_src_files}
  39     COMMAND ${CMAKE_COMMAND} -E copy_if_different ${_tmp_src_files} ${_src_files}
  40     DEPENDS ${_tmp_src_files}
  41   )
  42   if (${_par} MATCHES "layouttranslations")
  43     ADD_CUSTOM_COMMAND(
  44       OUTPUT "${_dst}"
  45       PRE_BUILD
  46       COMMAND  ${CMAKE_COMMAND} -E copy_if_different "${TOP_SRC_DIR}/lib/layouttranslations" "${_dst}"
  47       COMMAND ${LYX_PYTHON_EXECUTABLE}
  48       ARGS "${TOP_SRC_DIR}/po/lyx_pot.py" -b "${TOP_SRC_DIR}" -o "${_dst}" -t ${_par1} "--src_file=${_src_files}"
  49       DEPENDS ${_sources} ${_src_files}
  50       COMMENT "${LYX_PYTHON_EXECUTABLE} ${TOP_SRC_DIR}/po/lyx_pot.py -b ${TOP_SRC_DIR} -o  ${_dst} -t ${_par1} --src_file=${_src_files}"
  51       )
  52     ADD_CUSTOM_TARGET(layouttranslations ALL DEPENDS "${_dst}")
  53     install(FILES "${_dst}" DESTINATION .)
  54   else()
  55     ADD_CUSTOM_COMMAND(
  56       OUTPUT "${_dst}"
  57       PRE_BUILD
  58       COMMAND ${LYX_PYTHON_EXECUTABLE}
  59       ARGS "${TOP_SRC_DIR}/po/lyx_pot.py" -b "${TOP_SRC_DIR}" -o "${_dst}" -t ${_par1} "--src_file=${_src_files}"
  60       DEPENDS ${_sources} ${_src_files}
  61       COMMENT "${LYX_PYTHON_EXECUTABLE} ${TOP_SRC_DIR}/po/lyx_pot.py -b ${TOP_SRC_DIR} -o  ${_dst} -t ${_par1} --src_file=${_src_files}"
  62       )
  63     LIST(APPEND _py_sources "${_dst}")
  64   endif()
  65   SET_SOURCE_FILES_PROPERTIES("${_dst}" GENERATED)
  66   SET_SOURCE_FILES_PROPERTIES("${_src_files}" GENERATED)
  67 endmacro(add_gettext_python)
  68
  69 SET_SOURCE_FILES_PROPERTIES("${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot" GENERATED)
  70 SET_SOURCE_FILES_PROPERTIES("${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot" GENERATED)
  71 SET_SOURCE_FILES_PROPERTIES("${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot" GENERATED)
  72
  73 add_gettext_python(qt4 src/frontends/qt4/ui *.ui)
  74 add_gettext_python(layouts lib/layouts *.layout *.inc *.module)
  75 add_gettext_python(languages lib languages)
  76 add_gettext_python(encodings lib encodings)
  77 add_gettext_python(ui lib/ui *.ui *.inc)
  78 add_gettext_python(external lib external_templates)
  79 add_gettext_python(formats lib configure.py)
  80 add_gettext_python(layouttranslations lib/layouts *.layout *.inc *.module)
  81
  82 ADD_CUSTOM_COMMAND(
  83     OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot"
  84     COMMAND ${LYX_PYTHON_EXECUTABLE}
  85     ARGS   "${CMAKE_SOURCE_DIR}/po/cat.py" ${_py_sources} > "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot"
  86     DEPENDS ${_py_sources}
  87     )
  88
  89 ADD_CUSTOM_COMMAND(
  90     OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot"
  91     COMMAND ${GETTEXT_MSGUNIQ_EXECUTABLE}
  92     ARGS -o "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot" "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot"
  93     DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.cat.pot"
  94     )
  95
  96 SET(_potfiles_dep)
  97
  98 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/POTFILES.in "")
  99 file(GLOB_RECURSE _tmp_potfiles RELATIVE ${TOP_SRC_DIR}/ ${TOP_SRC_DIR}/src/*.h  ${TOP_SRC_DIR}/src/*.cpp  ${TOP_SRC_DIR}/src/*.cpp.in)
 100 list(SORT _tmp_potfiles)
 101 list(REMOVE_ITEM _tmp_potfiles src/support/Package.cpp)
 102
 103 foreach(_f ${_tmp_potfiles})
 104   # we don't need to select only relevant files because the outcome of xgettext
 105   # will stay the same.
 106   # Relevant files are files containing the string '_(".*")'
 107   LIST(APPEND _potfiles_dep "${TOP_SRC_DIR}/${_f}")
 108   file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/POTFILES.in "${_f}\n")
 109 endforeach(_f)
 110
 111 ADD_CUSTOM_COMMAND(
 112     OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot"
 113     COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot" "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot"
 114     COMMAND ${GETTEXT_XGETTEXT_EXECUTABLE}
 115     ARGS --default-domain=${_lyxname} --directory=${TOP_SRC_DIR} --add-comments=TRANSLATORS: --language=C++ --join-existing --keyword=_ --keyword=N_ --keyword=B_ --keyword=qt_ --files-from="${CMAKE_CURRENT_BINARY_DIR}/POTFILES.in" --copyright-holder="LyX Developers" --msgid-bugs-address=lyx-devel@lists.lyx.org -o "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot"
 116     DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.fmt.pot" ${_potfiles_dep}
 117     )
 118
 119 #
 120 # We have to copy the po-files first,
 121 # otherwise they would be modified (inside the macro GETTEXT_CREATE_TRANSLATIONS())
 122 # This makes the "svn up" on po-files work again
 123 file(GLOB LYX_BASE_PO_FILES RELATIVE ${TOP_SRC_DIR}/po ${TOP_SRC_DIR}/po/*.po)
 124 set(LYX_PO_FILES)
 125 SET(LYX_UPDATED_PO_FILES)
 126 SET(LYX_DEST_PO ${TOP_SRC_DIR}/po)
 127
 128 foreach(_pofile ${LYX_BASE_PO_FILES})
 129   add_custom_command(
 130     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}
 131     COMMAND ${CMAKE_COMMAND} -E copy ${TOP_SRC_DIR}/po/${_pofile} ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}
 132     DEPENDS ${TOP_SRC_DIR}/po/${_pofile}
 133     )
 134   list(APPEND LYX_PO_FILES ${CMAKE_CURRENT_BINARY_DIR}/${_pofile})
 135 endforeach(_pofile)
 136
 137 foreach(_pofile ${LYX_BASE_PO_FILES})
 138   add_custom_command(
 139     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}.copied
 140     COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_BINARY_DIR}/${_pofile} ${LYX_DEST_PO}/${_pofile}
 141     COMMAND ${CMAKE_COMMAND} -E touch ${_pofile}.copied
 142     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}
 143     )
 144   list(APPEND LYX_UPDATED_PO_FILES ${CMAKE_CURRENT_BINARY_DIR}/${_pofile}.copied)
 145 endforeach(_pofile)
 146
 147 if(LYX_CPACK OR LYX_INSTALL)
 148   set(_addALLOption ALL)
 149 endif()
 150 GETTEXT_CREATE_TRANSLATIONS(${CMAKE_CURRENT_BINARY_DIR}/${_lyxname}.pot ${_addALLOption} ${LYX_PO_FILES})
 151
 152 # ALL omitted here, to prevent from automatic creation
 153 ADD_CUSTOM_TARGET(update_po_files DEPENDS ${LYX_UPDATED_PO_FILES})
 154 add_dependencies(update_po_files translations)
 155
 156 # ADD_POFILES("lyx")
 157