development/cmake/modules/LyXMacros.cmake

   1 #
   2 #  Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   3 #
   4 #  Redistribution and use in source and binary forms, with or without
   5 #  modification, are permitted provided that the following conditions
   6 #  are met:
   7 #
   8 #  1. Redistributions of source code must retain the copyright
   9 #     notice, this list of conditions and the following disclaimer.
  10 #  2. Redistributions in binary form must reproduce the copyright
  11 #     notice, this list of conditions and the following disclaimer in the
  12 #     documentation and/or other materials provided with the distribution.
  13 #  3. The name of the author may not be used to endorse or promote products
  14 #     derived from this software without specific prior written permission.
  15 #
  16 #  THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  17 #  IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  18 #  OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  19 #  IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  20 #  INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  21 #  NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  22 #  DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  23 #  THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  24 #  (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  25 #  THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  26 #
  27
  28 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  29
  30 macro(lyx_add_path _list _prefix)
  31    set(_tmp)
  32    foreach(_current ${${_list}})
  33       set(_tmp ${_tmp} ${_prefix}/${_current})
  34       #message( ${_prefix}/${_current})
  35    endforeach(_current)
  36    set(${_list} ${_tmp})
  37 endmacro(lyx_add_path _out _prefix)
  38
  39
  40 #create the implementation files from the ui files and add them
  41 # to the list of sources
  42 #usage: LYX_ADD_QT4_UI_FILES(foo_SRCS ${ui_files})
  43 macro(LYX_ADD_UI_FILES _sources _ui)
  44    foreach (_current_FILE ${ARGN})
  45
  46       get_filename_component(_tmp_FILE ${_current_FILE} ABSOLUTE)
  47       get_filename_component(_basename ${_tmp_FILE} NAME_WE)
  48       set(_header ${CMAKE_CURRENT_BINARY_DIR}/ui_${_basename}.h)
  49
  50       # we need to run uic and replace some things in the generated file
  51       # this is done by executing the cmake script kde4uic.cmake
  52       add_custom_command(OUTPUT ${_header}
  53          COMMAND ${CMAKE_COMMAND}
  54          ARGS
  55          -DKDE4_HEADER:BOOL=ON
  56          -DKDE_UIC_EXECUTABLE:FILEPATH=${QT_UIC_EXECUTABLE}
  57          -DKDE_UIC_FILE:FILEPATH=${_tmp_FILE}
  58          -DKDE_UIC_H_FILE:FILEPATH=${_header}
  59          -DKDE_UIC_BASENAME:STRING=${_basename}
  60          -P ${CMAKE_MODULE_PATH}/LyXuic.cmake
  61          MAIN_DEPENDENCY ${_tmp_FILE}
  62       )
  63       set(${_ui} ${${_ui}} ${_header})
  64    endforeach (_current_FILE)
  65 endmacro(LYX_ADD_UI_FILES)
  66
  67
  68
  69 macro(LYX_AUTOMOC)
  70    if(QT4_GET_MOC_INC_DIRS)
  71       QT4_GET_MOC_INC_DIRS(_moc_INCS)
  72    endif()
  73
  74    set(_matching_FILES )
  75    foreach (_current_FILE ${ARGN})
  76
  77       get_filename_component(_abs_FILE ${_current_FILE} ABSOLUTE)
  78       # if "SKIP_AUTOMOC" is set to true, we will not handle this file here.
  79       # here. this is required to make bouic work correctly:
  80       # we need to add generated .cpp files to the sources (to compile them),
  81       # but we cannot let automoc handle them, as the .cpp files don't exist yet when
  82       # cmake is run for the very first time on them -> however the .cpp files might
  83       # exist at a later run. at that time we need to skip them, so that we don't add two
  84       # different rules for the same moc file
  85       get_source_file_property(_skip ${_abs_FILE} SKIP_AUTOMOC)
  86
  87       if (EXISTS ${_abs_FILE} AND NOT _skip)
  88
  89          file(READ ${_abs_FILE} _contents)
  90
  91          get_filename_component(_abs_PATH ${_abs_FILE} PATH)
  92
  93          string(REGEX MATCHALL "#include +[\"<]moc_[^ ]+\\.cpp[\">]" _match "${_contents}")
  94          if (_match)
  95             foreach (_current_MOC_INC ${_match})
  96                string(REGEX MATCH "moc_[^ <\"]+\\.cpp" _current_MOC "${_current_MOC_INC}")
  97
  98                get_filename_component(_basename ${_current_MOC} NAME_WE)
  99
 100                string(LENGTH ${_basename} _length)
 101                MATH(EXPR _mocless_length ${_length}-4)
 102                STRING(SUBSTRING  ${_basename} 4 ${_mocless_length} _mocless_name )
 103
 104                set(_header ${_abs_PATH}/${_mocless_name}.h)
 105
 106                #message(STATUS "moc : ${_header}")
 107                #set(_header ${CMAKE_CURRENT_SOURCE_DIR}/${_basename}.h)
 108                #set(_header ${_abs_PATH}/${_basename}.h)
 109
 110                set(_moc  ${CMAKE_CURRENT_BINARY_DIR}/${_current_MOC})
 111                #set(_moc ${_abs_PATH}/${_current_MOC})
 112                add_custom_command(OUTPUT ${_moc}
 113                        COMMAND ${QT_MOC_EXECUTABLE}
 114                        ARGS ${_moc_INCS} ${_header} -o ${_moc}
 115                        MAIN_DEPENDENCY ${_header})
 116                macro_add_file_dependencies(${_abs_FILE} ${_moc})
 117             endforeach (_current_MOC_INC)
 118          else()
 119             #message(STATUS "moc not found : ${_abs_FILE} ")
 120          endif()
 121
 122       endif()
 123    endforeach (_current_FILE)
 124 endmacro (LYX_AUTOMOC)
 125
 126
 127 macro(lyx_const_touched_files _allinone_name _list)
 128    set(_file_list ${_allinone_name}_files)
 129    set(_file_const ${CMAKE_CURRENT_BINARY_DIR}/${_allinone_name}_const.C)
 130    set(_file_touched ${CMAKE_CURRENT_BINARY_DIR}/${_allinone_name}_touched.C)
 131
 132
 133    # don't touch exisiting or non-empty file,
 134    # so a cmake re-run doesn't touch all created files
 135    set(_rebuild_file_const 0)
 136    if (NOT EXISTS ${_file_const})
 137       set(_rebuild_file_const 1)
 138    else()
 139       FILE(READ ${_file_const} _file_content)
 140       if (NOT _file_content)
 141          set(_rebuild_file_const 1)
 142       endif()
 143    endif()
 144
 145    set(_rebuild_file_touched 0)
 146    if (NOT EXISTS ${_file_touched})
 147       set(_rebuild_file_touched 1)
 148    else()
 149       FILE(READ ${_file_touched} _file_content)
 150       if (NOT _file_content)
 151          set(_rebuild_file_touched 1)
 152       endif()
 153    endif()
 154
 155    if (merge_rebuild)
 156       set(_rebuild_file_const 1)
 157       set(_rebuild_file_touched 1)
 158    endif()
 159
 160    if (_rebuild_file_const)
 161       file(WRITE  ${_file_const} "// autogenerated file \n//\n")
 162       file(APPEND ${_file_const} "//    * clear or delete this file to build it again by cmake \n//\n\n")
 163    endif()
 164
 165    if (_rebuild_file_touched)
 166       file(WRITE  ${_file_touched} "// autogenerated file \n//\n")
 167       file(APPEND ${_file_touched} "//    * clear or delete this file to build it again by cmake \n//\n")
 168       file(APPEND ${_file_touched} "//    * don't touch this file \n//\n\n")
 169       file(APPEND ${_file_touched} "#define DONT_INCLUDE_CONST_FILES\n")
 170       file(APPEND ${_file_touched} "#include \"${_file_const}\"\n\n\n")
 171    endif()
 172
 173    set(${_file_list} ${_file_const} ${_file_touched})
 174
 175    foreach (_current_FILE ${${_list}})
 176       get_filename_component(_abs_FILE ${_current_FILE} ABSOLUTE)
 177       # don't include any generated files in the final-file
 178       # because then cmake will not know the dependencies
 179       get_source_file_property(_isGenerated ${_abs_FILE} GENERATED)
 180       if (_isGenerated)
 181          list(APPEND ${_file_list} ${_abs_FILE})
 182       else()
 183         GET_FILENAME_COMPONENT(_file_name ${_abs_FILE} NAME_WE)
 184         STRING(REGEX REPLACE "-" "_" _file_name "${_file_name}" )
 185         set(__macro_name ${_file_name}___ASSUME_CONST)
 186
 187         if (_rebuild_file_const)
 188            file(APPEND ${_file_const}  "#define ${__macro_name}\n")
 189            file(APPEND ${_file_const}  "#if defined(${__macro_name}) && !defined(DONT_INCLUDE_CONST_FILES)\n")
 190            file(APPEND ${_file_const}  "#include \"${_abs_FILE}\"\n")
 191            file(APPEND ${_file_const}  "#endif\n\n")
 192         endif()
 193
 194         if (_rebuild_file_touched)
 195            file(APPEND ${_file_touched}  "#ifndef ${__macro_name}\n")
 196            file(APPEND ${_file_touched}  "#include \"${_abs_FILE}\"\n")
 197            file(APPEND ${_file_touched}  "#endif\n\n")
 198         endif()
 199       endif()
 200    endforeach (_current_FILE)
 201 endmacro(lyx_const_touched_files)
 202
 203
 204 macro(lyx_qt_resources_file _qrc_name _to_dir _list)
 205    if (NOT EXISTS ${_qrc_name})
 206       set(_rebuild_file 1)
 207    else()
 208       FILE(READ ${_qrc_name} _file_content)
 209       if (NOT _file_content)
 210          set(_rebuild_file 1)
 211       endif()
 212    endif()
 213
 214    if (_rebuild_file)
 215       message(STATUS "Generating ${_qrc_name}")
 216       file(WRITE  ${_qrc_name} "<!DOCTYPE RCC><RCC version=\"1.0\">\n")
 217       file(APPEND  ${_qrc_name} "<qresource>\n")
 218
 219       foreach (_current_FILE ${${_list}})
 220          get_filename_component(_abs_FILE ${_current_FILE} ABSOLUTE)
 221          string(REGEX REPLACE "${_to_dir}" "" _file_name ${_abs_FILE})
 222          file(APPEND  ${_qrc_name} "    <file alias=\"${_file_name}\">${_abs_FILE}</file>\n")
 223       endforeach (_current_FILE)
 224
 225       file(APPEND  ${_qrc_name} "</qresource>\n")
 226       file(APPEND  ${_qrc_name} "</RCC>\n")
 227    endif()
 228 endmacro(lyx_qt_resources_file)
 229