development/cmake/modules/FindQt4.cmake

   1 #
   2 #  kdelibs file
   3 #
   4 # - Find QT 4
   5 # This module can be used to find Qt4.
   6 # The most important issue is that the Qt4 qmake is available via the system path.
   7 # This qmake is then used to detect basically everything else.
   8 # This module defines a number of key variables and macros. First is
   9 # QT_USE_FILE which is the path to a CMake file that can be included to compile
  10 # Qt 4 applications and libraries.  By default, the QtCore and QtGui
  11 # libraries are loaded. This behavior can be changed by setting one or more
  12 # of the following variables to true:
  13 #                    QT_DONT_USE_QTCORE
  14 #                    QT_DONT_USE_QTGUI
  15 #                    QT_USE_QT3SUPPORT
  16 #                    QT_USE_QTASSISTANT
  17 #                    QT_USE_QTDESIGNER
  18 #                    QT_USE_QTMOTIF
  19 #                    QT_USE_QTMAIN
  20 #                    QT_USE_QTNETWORK
  21 #                    QT_USE_QTNSPLUGIN
  22 #                    QT_USE_QTOPENGL
  23 #                    QT_USE_QTSQL
  24 #                    QT_USE_QTXML
  25 #
  26 # All the libraries required are stored in a variable called QT_LIBRARIES.
  27 # Add this variable to your TARGET_LINK_LIBRARIES.
  28 #
  29 #  macro QT4_WRAP_CPP(outfiles inputfile ... )
  30 #  macro QT4_WRAP_UI(outfiles inputfile ... )
  31 #  macro QT4_ADD_RESOURCE(outfiles inputfile ... )
  32 #  macro QT4_AUTOMOC(inputfile ... )
  33 #  macro QT4_GENERATE_MOC(inputfile outputfile )
  34 #
  35 #  QT_FOUND         If false, don't try to use Qt.
  36 #  QT4_FOUND        If false, don't try to use Qt 4.
  37 #
  38 #  QT_QTCORE_FOUND        True if QtCore was found.
  39 #  QT_QTGUI_FOUND         True if QtGui was found.
  40 #  QT_QT3SUPPORT_FOUND    True if Qt3Support was found.
  41 #  QT_QTASSISTANT_FOUND   True if QtAssistant was found.
  42 #  QT_QTDESIGNER_FOUND    True if QtDesigner was found.
  43 #  QT_QTMOTIF_FOUND       True if QtMotif was found.
  44 #  QT_QTNETWORK_FOUND     True if QtNetwork was found.
  45 #  QT_QTNSPLUGIN_FOUND    True if QtNsPlugin was found.
  46 #  QT_QTOPENGL_FOUND      True if QtOpenGL was found.
  47 #  QT_QTSQL_FOUND         True if QtSql was found.
  48 #  QT_QTXML_FOUND         True if QtXml was found.
  49 #  QT_QTSVG_FOUND         True if QtSvg was found.
  50 #  QT_QTTEST_FOUND        True if QtTest was found.
  51 #
  52 #  QT_DEFINITIONS   Definitions to use when compiling code that uses Qt.
  53 #
  54 #  QT_INCLUDES      List of paths to all include directories of
  55 #                   Qt4 QT_INCLUDE_DIR and QT_QTCORE_INCLUDE_DIR are
  56 #                   always in this variable even if NOTFOUND,
  57 #                   all other INCLUDE_DIRS are
  58 #                   only added if they are found.
  59 #
  60 #  QT_INCLUDE_DIR              Path to "include" of Qt4
  61 #  QT_QT_INCLUDE_DIR           Path to "include/Qt"
  62 #  QT_QT3SUPPORT_INCLUDE_DIR   Path to "include/Qt3Support"
  63 #  QT_QTASSISTANT_INCLUDE_DIR  Path to "include/QtAssistant"
  64 #  QT_QTCORE_INCLUDE_DIR       Path to "include/QtCore"
  65 #  QT_QTDESIGNER_INCLUDE_DIR   Path to "include/QtDesigner"
  66 #  QT_QTGUI_INCLUDE_DIR        Path to "include/QtGui"
  67 #  QT_QTMOTIF_INCLUDE_DIR      Path to "include/QtMotif"
  68 #  QT_QTNETWORK_INCLUDE_DIR    Path to "include/QtNetwork"
  69 #  QT_QTNSPLUGIN_INCLUDE_DIR   Path to "include/QtNsPlugin"
  70 #  QT_QTOPENGL_INCLUDE_DIR     Path to "include/QtOpenGL"
  71 #  QT_QTSQL_INCLUDE_DIR        Path to "include/QtSql"
  72 #  QT_QTXML_INCLUDE_DIR        Path to "include/QtXml"
  73 #  QT_QTSVG_INCLUDE_DIR        Path to "include/QtSvg"
  74 #  QT_QTTEST_INCLUDE_DIR       Path to "include/QtTest"
  75 #
  76 #  QT_LIBRARY_DIR              Path to "lib" of Qt4
  77 #
  78 # For every library of Qt there are three variables:
  79 #  QT_QTFOO_LIBRARY_RELEASE, which contains the full path to the release version
  80 #  QT_QTFOO_LIBRARY_DEBUG, which contains the full path to the debug version
  81 #  QT_QTFOO_LIBRARY, the full path to the release version if available, otherwise to the debug version
  82 #
  83 # So there are the following variables:
  84 # The Qt3Support library:     QT_QT3SUPPORT_LIBRARY
  85 #                             QT_QT3SUPPORT_LIBRARY_RELEASE
  86 #                             QT_QT3SUPPORT_DEBUG
  87 #
  88 # The QtAssistant library:    QT_QTASSISTANT_LIBRARY
  89 #                             QT_QTASSISTANT_LIBRARY_RELEASE
  90 #                             QT_QTASSISTANT_LIBRARY_DEBUG
  91 #
  92 # The QtCore library:         QT_QTCORE_LIBRARY
  93 #                             QT_QTCORE_LIBRARY_RELEASE
  94 #                             QT_QTCORE_LIBRARY_DEBUG
  95 #
  96 # The QtDesigner library:     QT_QTDESIGNER_LIBRARY
  97 #                             QT_QTDESIGNER_LIBRARY_RELEASE
  98 #                             QT_QTDESIGNER_LIBRARY_DEBUG
  99 #
 100 # The QtGui library:          QT_QTGUI_LIBRARY
 101 #                             QT_QTGUI_LIBRARY_RELEASE
 102 #                             QT_QTGUI_LIBRARY_DEBUG
 103 #
 104 # The QtMotif library:        QT_QTMOTIF_LIBRARY
 105 #                             QT_QTMOTIF_LIBRARY_RELEASE
 106 #                             QT_QTMOTIF_LIBRARY_DEBUG
 107 #
 108 # The QtNetwork library:      QT_QTNETWORK_LIBRARY
 109 #                             QT_QTNETWORK_LIBRARY_RELEASE
 110 #                             QT_QTNETWORK_LIBRARY_DEBUG
 111 #
 112 # The QtNsPLugin library:     QT_QTNSPLUGIN_LIBRARY
 113 #                             QT_QTNSPLUGIN_LIBRARY_RELEASE
 114 #                             QT_QTNSPLUGIN_LIBRARY_DEBUG
 115 #
 116 # The QtOpenGL library:       QT_QTOPENGL_LIBRARY
 117 #                             QT_QTOPENGL_LIBRARY_RELEASE
 118 #                             QT_QTOPENGL_LIBRARY_DEBUG
 119 #
 120 # The QtSql library:          QT_QTSQL_LIBRARY
 121 #                             QT_QTSQL_LIBRARY_RELEASE
 122 #                             QT_QTSQL_LIBRARY_DEBUG
 123 #
 124 # The QtXml library:          QT_QTXML_LIBRARY
 125 #                             QT_QTXML_LIBRARY_RELEASE
 126 #                             QT_QTXML_LIBRARY_DEBUG
 127 #
 128 # The QtSvg library:          QT_QTSVG_LIBRARY
 129 #                             QT_QTSVG_LIBRARY_RELEASE
 130 #                             QT_QTSVG_LIBRARY_DEBUG
 131 #
 132 # The QtTest library:         QT_QTTEST_LIBRARY
 133 #                             QT_QTTEST_LIBRARY_RELEASE
 134 #                             QT_QTTEST_LIBRARY_DEBUG
 135 #
 136 # The qtmain library for Windows QT_QTMAIN_LIBRARY
 137 #                             QT_QTMAIN_LIBRARY_RELEASE
 138 #                             QT_QTMAIN_LIBRARY_DEBUG
 139 #
 140 #The QtUiTools library:       QT_QTUITOOLS_LIBRARY
 141 #                             QT_QTUITOOLS_LIBRARY_RELEASE
 142 #                             QT_QTUITOOLS_LIBRARY_DEBUG
 143 #
 144 # also defined, but NOT for general use are
 145 #  QT_MOC_EXECUTABLE          Where to find the moc tool.
 146 #  QT_UIC_EXECUTABLE          Where to find the uic tool.
 147 #  QT_UIC3_EXECUTABLE         Where to find the uic3 tool.
 148 #  QT_RCC_EXECUTABLE          Where to find the rcc tool
 149 #
 150 #  QT_DOC_DIR                 Path to "doc" of Qt4
 151 #  QT_MKSPECS_DIR             Path to "mkspecs" of Qt4
 152 #
 153 #
 154 # These are around for backwards compatibility
 155 # they will be set
 156 #  QT_WRAP_CPP  Set true if QT_MOC_EXECUTABLE is found
 157 #  QT_WRAP_UI   Set true if QT_UIC_EXECUTABLE is found
 158 #
 159 # These variables do _NOT_ have any effect anymore (compared to FindQt.cmake)
 160 #  QT_MT_REQUIRED         Qt4 is now always multithreaded
 161 #
 162 # These variables are set to "" Because Qt structure changed
 163 # (They make no sense in Qt4)
 164 #  QT_QT_LIBRARY        Qt-Library is now split
 165
 166 INCLUDE(CheckSymbolExists)
 167 INCLUDE(MacroAddFileDependencies)
 168
 169 SET(QT_USE_FILE ${CMAKE_ROOT}/Modules/UseQt4.cmake)
 170
 171 SET( QT_DEFINITIONS "")
 172
 173 IF (WIN32)
 174   SET(QT_DEFINITIONS -DQT_DLL)
 175 ENDIF(WIN32)
 176
 177 # check for qmake
 178 FIND_PROGRAM(QT_QMAKE_EXECUTABLE NAMES qmake qmake-qt4 PATHS
 179   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\4.0.0;InstallDir]/bin"
 180   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Versions\\4.0.0;InstallDir]/bin"
 181   $ENV{QTDIR}/bin
 182 )
 183
 184 SET(QT4_INSTALLED_VERSION_TOO_OLD FALSE)
 185
 186
 187 IF (QT_QMAKE_EXECUTABLE)
 188
 189    SET(QT4_QMAKE_FOUND FALSE)
 190
 191    EXEC_PROGRAM(${QT_QMAKE_EXECUTABLE} ARGS "-query QT_VERSION" OUTPUT_VARIABLE QTVERSION)
 192
 193    # check that we found the Qt4 qmake, Qt3 qmake output won't match here
 194    STRING(REGEX MATCH "^[0-9]+\\.[0-9]+\\.[0-9]+" qt_version_tmp "${QTVERSION}")
 195    IF (qt_version_tmp)
 196
 197       # we need at least version 4.0.0
 198       IF (NOT QT_MIN_VERSION)
 199          SET(QT_MIN_VERSION "4.0.0")
 200       ENDIF (NOT QT_MIN_VERSION)
 201
 202       #now parse the parts of the user given version string into variables
 203       STRING(REGEX MATCH "^[0-9]+\\.[0-9]+\\.[0-9]+" req_qt_major_vers "${QT_MIN_VERSION}")
 204       IF (NOT req_qt_major_vers)
 205          MESSAGE( FATAL_ERROR "Invalid Qt version string given: \"${QT_MIN_VERSION}\", expected e.g. \"4.0.1\"")
 206       ENDIF (NOT req_qt_major_vers)
 207
 208       # now parse the parts of the user given version string into variables
 209       STRING(REGEX REPLACE "^([0-9]+)\\.[0-9]+\\.[0-9]+" "\\1" req_qt_major_vers "${QT_MIN_VERSION}")
 210       STRING(REGEX REPLACE "^[0-9]+\\.([0-9])+\\.[0-9]+" "\\1" req_qt_minor_vers "${QT_MIN_VERSION}")
 211       STRING(REGEX REPLACE "^[0-9]+\\.[0-9]+\\.([0-9]+)" "\\1" req_qt_patch_vers "${QT_MIN_VERSION}")
 212
 213       IF (NOT req_qt_major_vers EQUAL 4)
 214          MESSAGE( FATAL_ERROR "Invalid Qt version string given: \"${QT_MIN_VERSION}\", major version 4 is required, e.g. \"4.0.1\"")
 215       ENDIF (NOT req_qt_major_vers EQUAL 4)
 216
 217       # and now the version string given by qmake
 218       STRING(REGEX REPLACE "^([0-9]+)\\.[0-9]+\\.[0-9]+.*" "\\1" found_qt_major_vers "${QTVERSION}")
 219       STRING(REGEX REPLACE "^[0-9]+\\.([0-9])+\\.[0-9]+.*" "\\1" found_qt_minor_vers "${QTVERSION}")
 220       STRING(REGEX REPLACE "^[0-9]+\\.[0-9]+\\.([0-9]+).*" "\\1" found_qt_patch_vers "${QTVERSION}")
 221
 222       # compute an overall version number which can be compared at once
 223       MATH(EXPR req_vers "${req_qt_major_vers}*10000 + ${req_qt_minor_vers}*100 + ${req_qt_patch_vers}")
 224       MATH(EXPR found_vers "${found_qt_major_vers}*10000 + ${found_qt_minor_vers}*100 + ${found_qt_patch_vers}")
 225
 226       IF (found_vers LESS req_vers)
 227          SET(QT4_QMAKE_FOUND FALSE)
 228          SET(QT4_INSTALLED_VERSION_TOO_OLD TRUE)
 229       ELSE (found_vers LESS req_vers)
 230          SET(QT4_QMAKE_FOUND TRUE)
 231       ENDIF (found_vers LESS req_vers)
 232
 233    ENDIF (qt_version_tmp)
 234
 235 ENDIF (QT_QMAKE_EXECUTABLE)
 236
 237 IF (QT4_QMAKE_FOUND)
 238
 239   # ask qmake for the library dir
 240   # Set QT_LIBRARY_DIR
 241   IF (NOT QT_LIBRARY_DIR)
 242     EXEC_PROGRAM( ${QT_QMAKE_EXECUTABLE}
 243        ARGS "-query QT_INSTALL_LIBS"
 244        OUTPUT_VARIABLE QT_LIBRARY_DIR_TMP )
 245     IF(EXISTS "${QT_LIBRARY_DIR_TMP}")
 246        SET(QT_LIBRARY_DIR ${QT_LIBRARY_DIR_TMP} CACHE PATH "Qt library dir")
 247     ELSE(EXISTS "${QT_LIBRARY_DIR_TMP}")
 248        MESSAGE("Warning: QT_QMAKE_EXECUTABLE reported QT_INSTALL_LIBS as ${QT_LIBRARY_DIR_TMP}")
 249        MESSAGE("Warning: ${QT_LIBRARY_DIR_TMP} does NOT exist, Qt must NOT be installed correctly.")
 250     ENDIF(EXISTS "${QT_LIBRARY_DIR_TMP}")
 251   ENDIF(NOT QT_LIBRARY_DIR)
 252
 253   IF (APPLE)
 254     IF (EXISTS ${QT_LIBRARY_DIR}/QtCore.framework)
 255       SET(QT_USE_FRAMEWORKS ON
 256          CACHE BOOL "Set to ON if Qt build uses frameworks.")
 257     ELSE (EXISTS ${QT_LIBRARY_DIR}/QtCore.framework)
 258        SET(QT_USE_FRAMEWORKS OFF
 259          CACHE BOOL "Set to ON if Qt build uses frameworks.")
 260     ENDIF (EXISTS ${QT_LIBRARY_DIR}/QtCore.framework)
 261
 262     MARK_AS_ADVANCED(QT_USE_FRAMEWORKS)
 263   ENDIF (APPLE)
 264
 265   # ask qmake for the binary dir
 266   IF (NOT QT_BINARY_DIR)
 267      EXEC_PROGRAM(${QT_QMAKE_EXECUTABLE}
 268         ARGS "-query QT_INSTALL_BINS"
 269         OUTPUT_VARIABLE qt_bins )
 270      SET(QT_BINARY_DIR ${qt_bins} CACHE INTERNAL "")
 271   ENDIF (NOT QT_BINARY_DIR)
 272
 273   # ask qmake for the include dir
 274   IF (NOT QT_HEADERS_DIR)
 275     EXEC_PROGRAM( ${QT_QMAKE_EXECUTABLE}
 276       ARGS "-query QT_INSTALL_HEADERS"
 277       OUTPUT_VARIABLE qt_headers )
 278     SET(QT_HEADERS_DIR ${qt_headers} CACHE INTERNAL "")
 279   ENDIF(NOT QT_HEADERS_DIR)
 280
 281
 282   # ask qmake for the documentation directory
 283   IF (NOT QT_DOC_DIR)
 284     EXEC_PROGRAM( ${QT_QMAKE_EXECUTABLE}
 285       ARGS "-query QT_INSTALL_DOCS"
 286       OUTPUT_VARIABLE qt_doc_dir )
 287     SET(QT_DOC_DIR ${qt_doc_dir} CACHE PATH "The location of the Qt docs")
 288   ENDIF (NOT QT_DOC_DIR)
 289
 290   # ask qmake for the mkspecs directory
 291   IF (NOT QT_MKSPECS_DIR)
 292     EXEC_PROGRAM( ${QT_QMAKE_EXECUTABLE}
 293       ARGS "-query QMAKE_MKSPECS"
 294       OUTPUT_VARIABLE qt_mkspecs_dir )
 295     SET(QT_MKSPECS_DIR ${qt_mkspecs_dir} CACHE PATH "The location of the Qt mkspecs")
 296   ENDIF (NOT QT_MKSPECS_DIR)
 297
 298   ########################################
 299   #
 300   #       Setting the INCLUDE-Variables
 301   #
 302   ########################################
 303
 304   FIND_PATH(QT_QTCORE_INCLUDE_DIR QtGlobal
 305     "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\4.0.0;InstallDir]/include/QtCore"
 306     ${QT_HEADERS_DIR}/QtCore
 307     ${QT_LIBRARY_DIR}/QtCore.framework/Headers
 308     $ENV{QTDIR}/include/QtCore
 309    "$ENV{ProgramFiles}/qt/include/Qt"
 310    )
 311
 312   # Set QT_INCLUDE_DIR by removine "/QtCore" in the string ${QT_QTCORE_INCLUDE_DIR}
 313   IF( QT_QTCORE_INCLUDE_DIR AND NOT QT_INCLUDE_DIR)
 314     IF (QT_USE_FRAMEWORKS)
 315       SET(QT_INCLUDE_DIR ${QT_HEADERS_DIR})
 316     ELSE (QT_USE_FRAMEWORKS)
 317       STRING( REGEX REPLACE "/QtCore$" "" qt4_include_dir ${QT_QTCORE_INCLUDE_DIR})
 318       SET( QT_INCLUDE_DIR ${qt4_include_dir} CACHE PATH "")
 319     ENDIF (QT_USE_FRAMEWORKS)
 320   ENDIF( QT_QTCORE_INCLUDE_DIR AND NOT QT_INCLUDE_DIR)
 321
 322   IF( NOT QT_INCLUDE_DIR)
 323     IF( NOT Qt4_FIND_QUIETLY AND Qt4_FIND_REQUIRED)
 324       MESSAGE( FATAL_ERROR "Could NOT find QtGlobal header")
 325     ENDIF( NOT Qt4_FIND_QUIETLY AND Qt4_FIND_REQUIRED)
 326   ENDIF( NOT QT_INCLUDE_DIR)
 327
 328   #############################################
 329   #
 330   # Find out what window system we're using
 331   #
 332   #############################################
 333   # Save required includes variable
 334   SET(CMAKE_REQUIRED_INCLUDES_SAVE ${CMAKE_REQUIRED_INCLUDES})
 335   # Add QT_INCLUDE_DIR to CMAKE_REQUIRED_INCLUDES
 336   SET(CMAKE_REQUIRED_INCLUDES "${CMAKE_REQUIRED_INCLUDES};${QT_INCLUDE_DIR}")
 337   # Check for Window system symbols (note: only one should end up being set)
 338   CHECK_SYMBOL_EXISTS(Q_WS_X11 "QtCore/qglobal.h" Q_WS_X11)
 339   CHECK_SYMBOL_EXISTS(Q_WS_MAC "QtCore/qglobal.h" Q_WS_MAC)
 340   CHECK_SYMBOL_EXISTS(Q_WS_WIN "QtCore/qglobal.h" Q_WS_WIN)
 341
 342   IF (QT_QTCOPY_REQUIRED)
 343      CHECK_SYMBOL_EXISTS(QT_IS_QTCOPY "QtCore/qglobal.h" QT_KDE_QT_COPY)
 344      IF (NOT QT_IS_QTCOPY)
 345         MESSAGE(FATAL_ERROR "qt-copy is required, but hasn't been found")
 346      ENDIF (NOT QT_IS_QTCOPY)
 347   ENDIF (QT_QTCOPY_REQUIRED)
 348
 349   # Restore CMAKE_REQUIRED_INCLUDES variable
 350   SET(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES_SAVE})
 351   #
 352   #############################################
 353
 354   IF (QT_USE_FRAMEWORKS)
 355     SET(QT_DEFINITIONS ${QT_DEFINITIONS} -F${QT_LIBRARY_DIR} -L${QT_LIBRARY_DIR} )
 356   ENDIF (QT_USE_FRAMEWORKS)
 357
 358   # Set QT_QT3SUPPORT_INCLUDE_DIR
 359   FIND_PATH(QT_QT3SUPPORT_INCLUDE_DIR Qt3Support
 360     PATHS
 361     ${QT_INCLUDE_DIR}/Qt3Support
 362     ${QT_LIBRARY_DIR}/Qt3Support.framework/Headers
 363     NO_DEFAULT_PATH
 364     )
 365
 366   # Set QT_QT_INCLUDE_DIR
 367   FIND_PATH(QT_QT_INCLUDE_DIR qglobal.h
 368     PATHS
 369     ${QT_INCLUDE_DIR}/Qt
 370     ${QT_LIBRARY_DIR}/QtCore.framework/Headers
 371     NO_DEFAULT_PATH
 372     )
 373
 374   # Set QT_QTGUI_INCLUDE_DIR
 375   FIND_PATH(QT_QTGUI_INCLUDE_DIR QtGui
 376     PATHS
 377     ${QT_INCLUDE_DIR}/QtGui
 378     ${QT_LIBRARY_DIR}/QtGui.framework/Headers
 379     NO_DEFAULT_PATH
 380     )
 381
 382   # Set QT_QTSVG_INCLUDE_DIR
 383   FIND_PATH(QT_QTSVG_INCLUDE_DIR QtSvg
 384     PATHS
 385     ${QT_INCLUDE_DIR}/QtSvg
 386     ${QT_LIBRARY_DIR}/QtSvg.framework/Headers
 387     NO_DEFAULT_PATH
 388     )
 389
 390   # Set QT_QTTEST_INCLUDE_DIR
 391   FIND_PATH(QT_QTTEST_INCLUDE_DIR QtTest
 392     PATHS
 393     ${QT_INCLUDE_DIR}/QtTest
 394     ${QT_LIBRARY_DIR}/QtTest.framework/Headers
 395     NO_DEFAULT_PATH
 396     )
 397
 398   # Set QT_QTUITOOLS_INCLUDE_DIR
 399   FIND_PATH(QT_QTUITOOLS_INCLUDE_DIR QtTest
 400     PATHS
 401     ${QT_INCLUDE_DIR}/QtUiTools
 402     ${QT_LIBRARY_DIR}/QtUiTools.framework/Headers
 403     NO_DEFAULT_PATH
 404     )
 405
 406
 407
 408   # Set QT_QTMOTIF_INCLUDE_DIR
 409   IF(Q_WS_X11)
 410     FIND_PATH(QT_QTMOTIF_INCLUDE_DIR QtMotif PATHS ${QT_INCLUDE_DIR}/QtMotif NO_DEFAULT_PATH )
 411   ENDIF(Q_WS_X11)
 412
 413   # Set QT_QTNETWORK_INCLUDE_DIR
 414   FIND_PATH(QT_QTNETWORK_INCLUDE_DIR QtNetwork
 415     PATHS
 416     ${QT_INCLUDE_DIR}/QtNetwork
 417     ${QT_LIBRARY_DIR}/QtNetwork.framework/Headers
 418     NO_DEFAULT_PATH
 419     )
 420
 421   # Set QT_QTNSPLUGIN_INCLUDE_DIR
 422   FIND_PATH(QT_QTNSPLUGIN_INCLUDE_DIR QtNsPlugin
 423     PATHS
 424     ${QT_INCLUDE_DIR}/QtNsPlugin
 425     ${QT_LIBRARY_DIR}/QtNsPlugin.framework/Headers
 426     NO_DEFAULT_PATH
 427     )
 428
 429   # Set QT_QTOPENGL_INCLUDE_DIR
 430   FIND_PATH(QT_QTOPENGL_INCLUDE_DIR QtOpenGL
 431     PATHS
 432     ${QT_INCLUDE_DIR}/QtOpenGL
 433     ${QT_LIBRARY_DIR}/QtOpenGL.framework/Headers
 434     NO_DEFAULT_PATH
 435     )
 436
 437   # Set QT_QTSQL_INCLUDE_DIR
 438   FIND_PATH(QT_QTSQL_INCLUDE_DIR QtSql
 439     PATHS
 440     ${QT_INCLUDE_DIR}/QtSql
 441     ${QT_LIBRARY_DIR}/QtSql.framework/Headers
 442     NO_DEFAULT_PATH
 443     )
 444
 445   # Set QT_QTXML_INCLUDE_DIR
 446   FIND_PATH(QT_QTXML_INCLUDE_DIR QtXml
 447     PATHS
 448     ${QT_INCLUDE_DIR}/QtXml
 449     ${QT_LIBRARY_DIR}/QtXml.framework/Headers
 450     NO_DEFAULT_PATH
 451     )
 452
 453   # Set QT_QTASSISTANT_INCLUDE_DIR
 454   FIND_PATH(QT_QTASSISTANT_INCLUDE_DIR QtAssistant
 455     PATHS
 456     ${QT_INCLUDE_DIR}/QtAssistant
 457     ${QT_HEADERS_DIR}/QtAssistant
 458     NO_DEFAULT_PATH
 459     )
 460
 461   # Set QT_QTDESIGNER_INCLUDE_DIR
 462   FIND_PATH(QT_QTDESIGNER_INCLUDE_DIR QDesignerComponents
 463     PATHS
 464     ${QT_INCLUDE_DIR}/QtDesigner
 465     ${QT_HEADERS_DIR}/QtDesigner
 466     NO_DEFAULT_PATH
 467     )
 468
 469   # Make variables changeble to the advanced user
 470   MARK_AS_ADVANCED( QT_LIBRARY_DIR QT_INCLUDE_DIR QT_QT_INCLUDE_DIR QT_DOC_DIR)
 471
 472   # Set QT_INCLUDES
 473   SET( QT_INCLUDES ${QT_INCLUDE_DIR} ${QT_QT_INCLUDE_DIR} ${QT_MKSPECS_DIR}/default )
 474
 475
 476   ########################################
 477   #
 478   #       Setting the LIBRARY-Variables
 479   #
 480   ########################################
 481
 482   IF (QT_USE_FRAMEWORKS)
 483     # If FIND_LIBRARY found libraries in Apple frameworks, we would NOT have
 484     # to jump through these hoops.
 485     SET(QT_QTCORE_LIBRARY_RELEASE "-F${QT_LIBRARY_DIR} -framework QtCore" CACHE STRING "The QtCore library.")
 486     SET(QT_QTCORE_LIBRARY_DEBUG   "-F${QT_LIBRARY_DIR} -framework QtCore" CACHE STRING "The QtCore library.")
 487     SET(QT_QT3SUPPORT_LIBRARY_RELEASE "-framework Qt3Support" CACHE STRING "The Qt3Support library.")
 488     SET(QT_QT3SUPPORT_LIBRARY_DEBUG   "-framework Qt3Support" CACHE STRING "The Qt3Support library.")
 489     SET(QT_QTGUI_LIBRARY_RELEASE      "-framework QtGui"      CACHE STRING "The QtGui library.")
 490     SET(QT_QTGUI_LIBRARY_DEBUG        "-framework QtGui"      CACHE STRING "The QtGui library.")
 491     SET(QT_QTNETWORK_LIBRARY_RELEASE  "-framework QtNetwork"  CACHE STRING "The QtNetwork library.")
 492     SET(QT_QTNETWORK_LIBRARY_DEBUG    "-framework QtNetwork"  CACHE STRING "The QtNetwork library.")
 493     SET(QT_QTOPENGL_LIBRARY_RELEASE   "-framework QtOpenGL"   CACHE STRING "The QtOpenGL library.")
 494     SET(QT_QTOPENGL_LIBRARY_DEBUG     "-framework QtOpenGL"   CACHE STRING "The QtOpenGL library.")
 495     SET(QT_QTSQL_LIBRARY_RELEASE      "-framework QtSql"      CACHE STRING "The QtSql library.")
 496     SET(QT_QTSQL_LIBRARY_DEBUG        "-framework QtSql"      CACHE STRING "The QtSql library.")
 497     SET(QT_QTXML_LIBRARY_RELEASE      "-framework QtXml"      CACHE STRING "The QtXml library.")
 498     SET(QT_QTXML_LIBRARY_DEBUG        "-framework QtXml"      CACHE STRING "The QtXml library.")
 499     SET(QT_QTSVG_LIBRARY_RELEASE      "-framework QtSvg"      CACHE STRING "The QtSvg library.")
 500     SET(QT_QTSVG_LIBRARY_DEBUG        "-framework QtSvg"      CACHE STRING "The QtSvg library.")
 501     SET(QT_QTUITOOLS_LIBRARY_RELEASE      "-framework QtUiTools"      CACHE STRING "The QtUiTools library.")
 502     SET(QT_QTUITOOLS_LIBRARY_DEBUG        "-framework QtUiTools"      CACHE STRING "The QtUiTools library.")
 503
 504
 505     # WTF?  why don't we have frameworks?  :P
 506     SET(QT_QTTEST_LIBRARY_RELEASE "-L${QT_LIBRARY_DIR} -lQtTest" CACHE STRING "The QtTest library.")
 507     SET(QT_QTTEST_LIBRARY_DEBUG   "-L${QT_LIBRARY_DIR} -lQtTest_debug" CACHE STRING "The QtTest library.")
 508     MARK_AS_ADVANCED(QT_QT3SUPPORT_LIBRARY QT_QTGUI_LIBRARY )
 509
 510   ELSE (QT_USE_FRAMEWORKS)
 511
 512     # Set QT_QTCORE_LIBRARY by searching for a lib with "QtCore."  as part of the filename
 513     FIND_LIBRARY(QT_QTCORE_LIBRARY_RELEASE NAMES QtCore QtCore4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH )
 514     FIND_LIBRARY(QT_QTCORE_LIBRARY_DEBUG NAMES QtCore_debug QtCored4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 515
 516     # Set QT_QT3SUPPORT_LIBRARY
 517     FIND_LIBRARY(QT_QT3SUPPORT_LIBRARY_RELEASE NAMES Qt3Support Qt3Support4 PATHS ${QT_LIBRARY_DIR}        NO_DEFAULT_PATH)
 518     FIND_LIBRARY(QT_QT3SUPPORT_LIBRARY_DEBUG   NAMES Qt3Support_debug Qt3Supportd4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 519
 520     # Set QT_QTGUI_LIBRARY
 521     FIND_LIBRARY(QT_QTGUI_LIBRARY_RELEASE NAMES QtGui QtGui4 PATHS ${QT_LIBRARY_DIR}        NO_DEFAULT_PATH)
 522     FIND_LIBRARY(QT_QTGUI_LIBRARY_DEBUG   NAMES QtGui_debug QtGuid4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 523
 524     # Set QT_QTMOTIF_LIBRARY
 525     IF(Q_WS_X11)
 526       FIND_LIBRARY(QT_QTMOTIF_LIBRARY_RELEASE NAMES QtMotif PATHS ${QT_LIBRARY_DIR}       NO_DEFAULT_PATH)
 527       FIND_LIBRARY(QT_QTMOTIF_LIBRARY_DEBUG   NAMES QtMotif_debug PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 528     ENDIF(Q_WS_X11)
 529
 530     # Set QT_QTNETWORK_LIBRARY
 531     FIND_LIBRARY(QT_QTNETWORK_LIBRARY_RELEASE NAMES QtNetwork QtNetwork4 PATHS ${QT_LIBRARY_DIR}        NO_DEFAULT_PATH)
 532     FIND_LIBRARY(QT_QTNETWORK_LIBRARY_DEBUG   NAMES QtNetwork_debug QtNetworkd4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 533
 534     # Set QT_QTNSPLUGIN_LIBRARY
 535     FIND_LIBRARY(QT_QTNSPLUGIN_LIBRARY_RELEASE NAMES QtNsPlugin PATHS ${QT_LIBRARY_DIR}       NO_DEFAULT_PATH)
 536     FIND_LIBRARY(QT_QTNSPLUGIN_LIBRARY_DEBUG   NAMES QtNsPlugin_debug PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 537
 538     # Set QT_QTOPENGL_LIBRARY
 539     FIND_LIBRARY(QT_QTOPENGL_LIBRARY_RELEASE NAMES QtOpenGL QtOpenGL4 PATHS ${QT_LIBRARY_DIR}        NO_DEFAULT_PATH)
 540     FIND_LIBRARY(QT_QTOPENGL_LIBRARY_DEBUG   NAMES QtOpenGL_debug QtOpenGLd4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 541
 542     # Set QT_QTSQL_LIBRARY
 543     FIND_LIBRARY(QT_QTSQL_LIBRARY_RELEASE NAMES QtSql QtSql4 PATHS ${QT_LIBRARY_DIR}        NO_DEFAULT_PATH)
 544     FIND_LIBRARY(QT_QTSQL_LIBRARY_DEBUG   NAMES QtSql_debug QtSqld4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 545
 546     # Set QT_QTXML_LIBRARY
 547     FIND_LIBRARY(QT_QTXML_LIBRARY_RELEASE NAMES QtXml QtXml4 PATHS ${QT_LIBRARY_DIR}        NO_DEFAULT_PATH)
 548     FIND_LIBRARY(QT_QTXML_LIBRARY_DEBUG   NAMES QtXml_debug QtXmld4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 549
 550     # Set QT_QTSVG_LIBRARY
 551     FIND_LIBRARY(QT_QTSVG_LIBRARY_RELEASE NAMES QtSvg QtSvg4 PATHS ${QT_LIBRARY_DIR}        NO_DEFAULT_PATH)
 552     FIND_LIBRARY(QT_QTSVG_LIBRARY_DEBUG   NAMES QtSvg_debug QtSvgd4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 553
 554     # Set QT_QTUITOOLS_LIBRARY
 555     FIND_LIBRARY(QT_QTUITOOLS_LIBRARY_RELEASE NAMES QtUiTools QtUiTools4 PATHS ${QT_LIBRARY_DIR}        NO_DEFAULT_PATH)
 556     FIND_LIBRARY(QT_QTUITOOLS_LIBRARY_DEBUG   NAMES QtUiTools_debug QtUiToolsd4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 557
 558     # Set QT_QTTEST_LIBRARY
 559     FIND_LIBRARY(QT_QTTEST_LIBRARY_RELEASE NAMES QtTest QtTest4 PATHS ${QT_LIBRARY_DIR}                      NO_DEFAULT_PATH)
 560     FIND_LIBRARY(QT_QTTEST_LIBRARY_DEBUG   NAMES QtTest_debug QtTest_debug4 QtTestd4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 561
 562     MARK_AS_ADVANCED(QT_QT3SUPPORT_LIBRARY QT_QTGUI_LIBRARY )
 563
 564   ENDIF (QT_USE_FRAMEWORKS)
 565
 566   IF( NOT QT_QTCORE_LIBRARY_DEBUG AND NOT QT_QTCORE_LIBRARY_RELEASE )
 567     IF( NOT Qt4_FIND_QUIETLY AND Qt4_FIND_REQUIRED)
 568       MESSAGE( FATAL_ERROR "Could NOT find QtCore. Check CMakeFiles/CMakeError.log for more details.")
 569     ENDIF( NOT Qt4_FIND_QUIETLY AND Qt4_FIND_REQUIRED)
 570   ENDIF( NOT QT_QTCORE_LIBRARY_DEBUG AND NOT QT_QTCORE_LIBRARY_RELEASE )
 571
 572   # Set QT_QTASSISTANT_LIBRARY
 573   FIND_LIBRARY(QT_QTASSISTANT_LIBRARY_RELEASE NAMES QtAssistantClient QtAssistant QtAssistant4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 574   FIND_LIBRARY(QT_QTASSISTANT_LIBRARY_DEBUG   NAMES QtAssistantClientd QtAssistantClient_debug QtAssistant_debug QtAssistantd4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 575
 576   # Set QT_QTDESIGNER_LIBRARY
 577   FIND_LIBRARY(QT_QTDESIGNER_LIBRARY_RELEASE NAMES QtDesigner QtDesigner4 PATHS ${QT_LIBRARY_DIR}        NO_DEFAULT_PATH)
 578   FIND_LIBRARY(QT_QTDESIGNER_LIBRARY_DEBUG   NAMES QtDesigner_debug QtDesignerd4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 579
 580   ############################################
 581   #
 582   # Check the existence of the libraries.
 583   #
 584   ############################################
 585
 586   MACRO (_QT4_ADJUST_LIB_VARS basename)
 587     IF (QT_${basename}_INCLUDE_DIR)
 588
 589       # if only the release version was found, set the debug variable also to the release version
 590       IF (QT_${basename}_LIBRARY_RELEASE AND NOT QT_${basename}_LIBRARY_DEBUG)
 591         SET(QT_${basename}_LIBRARY_DEBUG ${QT_${basename}_LIBRARY_RELEASE})
 592         SET(QT_${basename}_LIBRARY       ${QT_${basename}_LIBRARY_RELEASE})
 593         SET(QT_${basename}_LIBRARIES     ${QT_${basename}_LIBRARY_RELEASE})
 594       ENDIF (QT_${basename}_LIBRARY_RELEASE AND NOT QT_${basename}_LIBRARY_DEBUG)
 595
 596       # if only the debug version was found, set the release variable also to the debug version
 597       IF (QT_${basename}_LIBRARY_DEBUG AND NOT QT_${basename}_LIBRARY_RELEASE)
 598         SET(QT_${basename}_LIBRARY_RELEASE ${QT_${basename}_LIBRARY_DEBUG})
 599         SET(QT_${basename}_LIBRARY         ${QT_${basename}_LIBRARY_DEBUG})
 600         SET(QT_${basename}_LIBRARIES       ${QT_${basename}_LIBRARY_DEBUG})
 601       ENDIF (QT_${basename}_LIBRARY_DEBUG AND NOT QT_${basename}_LIBRARY_RELEASE)
 602
 603       IF (QT_${basename}_LIBRARY_DEBUG AND QT_${basename}_LIBRARY_RELEASE)
 604         IF(NOT MSVC)
 605           SET(QT_${basename}_LIBRARY       ${QT_${basename}_LIBRARY_RELEASE})
 606         ELSE(NOT MSVC)
 607           SET(QT_${basename}_LIBRARY       optimized ${QT_${basename}_LIBRARY_RELEASE} debug ${QT_${basename}_LIBRARY_DEBUG})
 608         ENDIF(NOT MSVC)
 609         SET(QT_${basename}_LIBRARIES       optimized ${QT_${basename}_LIBRARY_RELEASE} debug ${QT_${basename}_LIBRARY_DEBUG})
 610       ENDIF (QT_${basename}_LIBRARY_DEBUG AND QT_${basename}_LIBRARY_RELEASE)
 611
 612       SET(QT_${basename}_LIBRARY ${QT_${basename}_LIBRARY} CACHE FILEPATH "The Qt ${basename} library")
 613
 614       IF (QT_${basename}_LIBRARY)
 615         SET(QT_${basename}_FOUND 1)
 616       ENDIF (QT_${basename}_LIBRARY)
 617
 618       #add the include directory to QT_INCLUDES
 619       SET(QT_INCLUDES ${QT_INCLUDES} "${QT_${basename}_INCLUDE_DIR}")
 620     ENDIF (QT_${basename}_INCLUDE_DIR )
 621
 622     # Make variables changeble to the advanced user
 623     MARK_AS_ADVANCED(QT_${basename}_LIBRARY QT_${basename}_LIBRARY_RELEASE QT_${basename}_LIBRARY_DEBUG QT_${basename}_INCLUDE_DIR)
 624   ENDMACRO (_QT4_ADJUST_LIB_VARS)
 625
 626   IF(WIN32)
 627      _QT4_ADJUST_LIB_VARS(QTMAIN)
 628   ENDIF(WIN32)
 629
 630
 631   _QT4_ADJUST_LIB_VARS(QTCORE)
 632   _QT4_ADJUST_LIB_VARS(QTGUI)
 633   _QT4_ADJUST_LIB_VARS(QT3SUPPORT)
 634   _QT4_ADJUST_LIB_VARS(QTASSISTANT)
 635   _QT4_ADJUST_LIB_VARS(QTDESIGNER)
 636   IF(Q_WS_X11)
 637     _QT4_ADJUST_LIB_VARS(QTMOTIF)
 638   ENDIF(Q_WS_X11)
 639   _QT4_ADJUST_LIB_VARS(QTNETWORK)
 640   _QT4_ADJUST_LIB_VARS(QTNSPLUGIN)
 641   _QT4_ADJUST_LIB_VARS(QTOPENGL)
 642   _QT4_ADJUST_LIB_VARS(QTSQL)
 643   _QT4_ADJUST_LIB_VARS(QTXML)
 644   _QT4_ADJUST_LIB_VARS(QTSVG)
 645   _QT4_ADJUST_LIB_VARS(QTUITOOLS)
 646   _QT4_ADJUST_LIB_VARS(QTTEST)
 647
 648   #######################################
 649   #
 650   #       Check the executables of Qt
 651   #          ( moc, uic, rcc )
 652   #
 653   #######################################
 654
 655
 656    # find moc and uic using qmake
 657    FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/CMakeTmpQmake/tmp.pro
 658       "message("MOC <$$QMAKE_MOC>")
 659       message("UIC <$$QMAKE_UIC>")
 660    ")
 661
 662    EXECUTE_PROCESS(COMMAND ${QT_QMAKE_EXECUTABLE}
 663       WORKING_DIRECTORY  ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/CMakeTmpQmake
 664       OUTPUT_VARIABLE _moc_OUTPUT
 665       ERROR_VARIABLE _moc_OUTPUT )
 666
 667    FILE(REMOVE_RECURSE "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/CMakeTmpQmake")
 668
 669    STRING(REGEX REPLACE ".*MOC<([^>]+).*" "\\1" QT_MOC_EXECUTABLE "${_moc_OUTPUT}" )
 670    STRING(REGEX REPLACE ".*UIC<([^>]+).*" "\\1" QT_UIC_EXECUTABLE "${_moc_OUTPUT}" )
 671
 672    FILE(TO_CMAKE_PATH "${QT_MOC_EXECUTABLE}" QT_MOC_EXECUTABLE)
 673    FILE(TO_CMAKE_PATH "${QT_UIC_EXECUTABLE}" QT_UIC_EXECUTABLE)
 674
 675    SET(QT_MOC_EXECUTABLE ${QT_MOC_EXECUTABLE} CACHE FILEPATH "The moc executable")
 676    SET(QT_UIC_EXECUTABLE ${QT_UIC_EXECUTABLE} CACHE FILEPATH "The uic executable")
 677
 678
 679   FIND_PROGRAM(QT_UIC3_EXECUTABLE
 680     NAMES uic3
 681     PATHS ${QT_BINARY_DIR}
 682     NO_DEFAULT_PATH
 683     )
 684
 685   FIND_PROGRAM(QT_RCC_EXECUTABLE
 686     NAMES rcc
 687     PATHS ${QT_BINARY_DIR}
 688     NO_DEFAULT_PATH
 689     )
 690
 691   IF (QT_MOC_EXECUTABLE)
 692      SET(QT_WRAP_CPP "YES")
 693   ENDIF (QT_MOC_EXECUTABLE)
 694
 695   IF (QT_UIC_EXECUTABLE)
 696      SET(QT_WRAP_UI "YES")
 697   ENDIF (QT_UIC_EXECUTABLE)
 698
 699
 700
 701   MARK_AS_ADVANCED( QT_UIC_EXECUTABLE QT_UIC3_EXECUTABLE QT_MOC_EXECUTABLE QT_RCC_EXECUTABLE )
 702
 703   ######################################
 704   #
 705   #       Macros for building Qt files
 706   #
 707   ######################################
 708
 709   MACRO (QT4_GET_MOC_INC_DIRS _moc_INC_DIRS)
 710      SET(${_moc_INC_DIRS})
 711      GET_DIRECTORY_PROPERTY(_inc_DIRS INCLUDE_DIRECTORIES)
 712
 713      FOREACH(_current ${_inc_DIRS})
 714         SET(${_moc_INC_DIRS} ${${_moc_INC_DIRS}} "-I" ${_current})
 715      ENDFOREACH(_current ${_inc_DIRS})
 716   ENDMACRO(QT4_GET_MOC_INC_DIRS)
 717
 718
 719   MACRO (QT4_GENERATE_MOC infile outfile )
 720   # get include dirs
 721      QT4_GET_MOC_INC_DIRS(moc_includes)
 722
 723      GET_FILENAME_COMPONENT(infile ${infile} ABSOLUTE)
 724
 725      ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 726         COMMAND ${QT_MOC_EXECUTABLE}
 727         ARGS ${moc_includes} -o ${outfile} ${infile}
 728         DEPENDS ${infile})
 729
 730      MACRO_ADD_FILE_DEPENDENCIES(${infile} ${outfile})
 731   ENDMACRO (QT4_GENERATE_MOC)
 732
 733
 734   # QT4_WRAP_CPP(outfiles inputfile ... )
 735   # TODO  perhaps add support for -D, -U and other minor options
 736
 737   MACRO (QT4_WRAP_CPP outfiles )
 738     # get include dirs
 739     QT4_GET_MOC_INC_DIRS(moc_includes)
 740
 741     FOREACH (it ${ARGN})
 742       GET_FILENAME_COMPONENT(it ${it} ABSOLUTE)
 743       GET_FILENAME_COMPONENT(outfile ${it} NAME_WE)
 744
 745       SET(outfile ${CMAKE_CURRENT_BINARY_DIR}/moc_${outfile}.cxx)
 746       ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 747         COMMAND ${QT_MOC_EXECUTABLE}
 748         ARGS ${moc_includes} -o ${outfile} ${it}
 749         DEPENDS ${it})
 750       SET(${outfiles} ${${outfiles}} ${outfile})
 751     ENDFOREACH(it)
 752
 753   ENDMACRO (QT4_WRAP_CPP)
 754
 755
 756   # QT4_WRAP_UI(outfiles inputfile ... )
 757
 758   MACRO (QT4_WRAP_UI outfiles )
 759
 760     FOREACH (it ${ARGN})
 761       GET_FILENAME_COMPONENT(outfile ${it} NAME_WE)
 762       SET(infile ${CMAKE_CURRENT_SOURCE_DIR}/${it})
 763       SET(outfile ${CMAKE_CURRENT_BINARY_DIR}/ui_${outfile}.h)
 764       ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 765         COMMAND ${QT_UIC_EXECUTABLE}
 766         ARGS -o ${outfile} ${infile}
 767         MAIN_DEPENDENCY ${infile})
 768       SET(${outfiles} ${${outfiles}} ${outfile})
 769     ENDFOREACH (it)
 770
 771   ENDMACRO (QT4_WRAP_UI)
 772
 773
 774   # QT4_ADD_RESOURCE(outfiles inputfile ... )
 775   # TODO  perhaps consider adding support for compression and root options to rcc
 776
 777   MACRO (QT4_ADD_RESOURCES outfiles )
 778
 779     FOREACH (it ${ARGN})
 780       GET_FILENAME_COMPONENT(outfilename ${it} NAME_WE)
 781       SET(infile ${CMAKE_CURRENT_SOURCE_DIR}/${it})
 782       SET(outfile ${CMAKE_CURRENT_BINARY_DIR}/qrc_${outfilename}.cxx)
 783       ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 784         COMMAND ${QT_RCC_EXECUTABLE}
 785         ARGS -name ${outfilename} -o ${outfile} ${infile}
 786         MAIN_DEPENDENCY ${infile} )
 787       SET(${outfiles} ${${outfiles}} ${outfile})
 788     ENDFOREACH (it)
 789
 790   ENDMACRO (QT4_ADD_RESOURCES)
 791
 792
 793    MACRO(QT4_AUTOMOC)
 794       QT4_GET_MOC_INC_DIRS(_moc_INCS)
 795
 796       SET(_matching_FILES )
 797       FOREACH (_current_FILE ${ARGN})
 798
 799          GET_FILENAME_COMPONENT(_abs_FILE ${_current_FILE} ABSOLUTE)
 800          # if "SKIP_AUTOMOC" is set to true, we will not handle this file here.
 801          # here. this is required to make bouic work correctly:
 802          # we need to add generated .cpp files to the sources (to compile them),
 803          # but we cannot let automoc handle them, as the .cpp files don't exist yet when
 804          # cmake is run for the very first time on them -> however the .cpp files might
 805          # exist at a later run. at that time we need to skip them, so that we don't add two
 806          # different rules for the same moc file
 807          GET_SOURCE_FILE_PROPERTY(_skip ${_abs_FILE} SKIP_AUTOMOC)
 808
 809          IF ( NOT _skip AND EXISTS ${_abs_FILE} )
 810
 811             FILE(READ ${_abs_FILE} _contents)
 812
 813             GET_FILENAME_COMPONENT(_abs_PATH ${_abs_FILE} PATH)
 814
 815             STRING(REGEX MATCHALL "#include +[^ ]+\\.moc[\">]" _match "${_contents}")
 816             IF(_match)
 817                FOREACH (_current_MOC_INC ${_match})
 818                   STRING(REGEX MATCH "[^ <\"]+\\.moc" _current_MOC "${_current_MOC_INC}")
 819
 820                   GET_filename_component(_basename ${_current_MOC} NAME_WE)
 821    #               SET(_header ${CMAKE_CURRENT_SOURCE_DIR}/${_basename}.h)
 822                   SET(_header ${_abs_PATH}/${_basename}.h)
 823                   SET(_moc    ${CMAKE_CURRENT_BINARY_DIR}/${_current_MOC})
 824                   ADD_CUSTOM_COMMAND(OUTPUT ${_moc}
 825                      COMMAND ${QT_MOC_EXECUTABLE}
 826                      ARGS ${_moc_INCS} ${_header} -o ${_moc}
 827                      DEPENDS ${_header}
 828                   )
 829
 830                   MACRO_ADD_FILE_DEPENDENCIES(${_abs_FILE} ${_moc})
 831                ENDFOREACH (_current_MOC_INC)
 832             ENDIF(_match)
 833          ENDIF ( NOT _skip AND EXISTS ${_abs_FILE} )
 834       ENDFOREACH (_current_FILE)
 835    ENDMACRO(QT4_AUTOMOC)
 836
 837
 838
 839   ######################################
 840   #
 841   #       decide if Qt got found
 842   #
 843   ######################################
 844
 845   # if the includes,libraries,moc,uic and rcc are found then we have it
 846   IF( QT_LIBRARY_DIR AND QT_INCLUDE_DIR AND QT_MOC_EXECUTABLE AND QT_UIC_EXECUTABLE AND QT_RCC_EXECUTABLE)
 847     SET( QT4_FOUND "YES" )
 848     IF( NOT Qt4_FIND_QUIETLY)
 849       MESSAGE(STATUS "Found Qt-Version ${QTVERSION}")
 850     ENDIF( NOT Qt4_FIND_QUIETLY)
 851   ELSE( QT_LIBRARY_DIR AND QT_INCLUDE_DIR AND QT_MOC_EXECUTABLE AND QT_UIC_EXECUTABLE AND QT_RCC_EXECUTABLE)
 852     SET( QT4_FOUND "NO")
 853     IF( Qt4_FIND_REQUIRED)
 854       MESSAGE( FATAL_ERROR "Qt libraries, includes, moc, uic or/and rcc NOT found!")
 855     ENDIF( Qt4_FIND_REQUIRED)
 856   ENDIF( QT_LIBRARY_DIR AND QT_INCLUDE_DIR AND QT_MOC_EXECUTABLE AND QT_UIC_EXECUTABLE AND  QT_RCC_EXECUTABLE)
 857   SET(QT_FOUND ${QT4_FOUND})
 858
 859
 860   #######################################
 861   #
 862   #       System dependent settings
 863   #
 864   #######################################
 865   # for unix add X11 stuff
 866   IF(UNIX)
 867     # on OS X X11 may not be required
 868     IF (Q_WS_X11)
 869       FIND_PACKAGE(X11)
 870     ENDIF (Q_WS_X11)
 871     FIND_PACKAGE(Threads)
 872     SET(QT_QTCORE_LIBRARY ${QT_QTCORE_LIBRARY} ${CMAKE_THREAD_LIBS_INIT})
 873   ENDIF(UNIX)
 874
 875
 876   #######################################
 877   #
 878   #       compatibility settings
 879   #
 880   #######################################
 881   # Backwards compatibility for CMake1.4 and 1.2
 882   SET (QT_MOC_EXE ${QT_MOC_EXECUTABLE} )
 883   SET (QT_UIC_EXE ${QT_UIC_EXECUTABLE} )
 884
 885   SET( QT_QT_LIBRARY "")
 886
 887 ELSE(QT4_QMAKE_FOUND)
 888
 889    IF(Qt4_FIND_REQUIRED)
 890       IF(QT4_INSTALLED_VERSION_TOO_OLD)
 891          MESSAGE(FATAL_ERROR "The installed Qt version ${QTVERSION} is too old, at least version ${QT_MIN_VERSION} is required")
 892       ELSE(QT4_INSTALLED_VERSION_TOO_OLD)
 893          MESSAGE( FATAL_ERROR "Qt qmake not found!")
 894       ENDIF(QT4_INSTALLED_VERSION_TOO_OLD)
 895    ELSE(Qt4_FIND_REQUIRED)
 896       IF(QT4_INSTALLED_VERSION_TOO_OLD AND NOT Qt4_FIND_QUIETLY)
 897          MESSAGE(STATUS "The installed Qt version ${QTVERSION} is too old, at least version ${QT_MIN_VERSION} is required")
 898       ENDIF(QT4_INSTALLED_VERSION_TOO_OLD AND NOT Qt4_FIND_QUIETLY)
 899    ENDIF(Qt4_FIND_REQUIRED)
 900
 901 ENDIF (QT4_QMAKE_FOUND)
 902