development/cmake/modules/FindQt4.cmake

   1 # - Find QT 4
   2 # This module can be used to find Qt4.
   3 # The most important issue is that the Qt4 qmake is available via the system path.
   4 # This qmake is then used to detect basically everything else.
   5 # This module defines a number of key variables and macros. First is
   6 # QT_USE_FILE which is the path to a CMake file that can be included to compile
   7 # Qt 4 applications and libraries.  By default, the QtCore and QtGui
   8 # libraries are loaded. This behavior can be changed by setting one or more
   9 # of the following variables to true:
  10 #                    QT_DONT_USE_QTCORE
  11 #                    QT_DONT_USE_QTGUI
  12 #                    QT_USE_QT3SUPPORT
  13 #                    QT_USE_QTASSISTANT
  14 #                    QT_USE_QTDESIGNER
  15 #                    QT_USE_QTMOTIF
  16 #                    QT_USE_QTMAIN
  17 #                    QT_USE_QTNETWORK
  18 #                    QT_USE_QTNSPLUGIN
  19 #                    QT_USE_QTOPENGL
  20 #                    QT_USE_QTSQL
  21 #                    QT_USE_QTXML
  22 #                    QT_USE_QTSVG
  23 #                    QT_USE_QTTEST
  24 #                    QT_USE_QTUITOOLS
  25 #
  26 # All the libraries required are stored in a variable called QT_LIBRARIES.
  27 # Add this variable to your TARGET_LINK_LIBRARIES.
  28 #
  29 #  macro QT4_WRAP_CPP(outfiles inputfile ... )
  30 #  macro QT4_WRAP_UI(outfiles inputfile ... )
  31 #  macro QT4_ADD_RESOURCE(outfiles inputfile ... )
  32 #  macro QT4_AUTOMOC(inputfile ... )
  33 #  macro QT4_GENERATE_MOC(inputfile outputfile )
  34 #
  35 #  QT_FOUND         If false, don't try to use Qt.
  36 #  QT4_FOUND        If false, don't try to use Qt 4.
  37 #
  38 #  QT_QTCORE_FOUND        True if QtCore was found.
  39 #  QT_QTGUI_FOUND         True if QtGui was found.
  40 #  QT_QT3SUPPORT_FOUND    True if Qt3Support was found.
  41 #  QT_QTASSISTANT_FOUND   True if QtAssistant was found.
  42 #  QT_QTDESIGNER_FOUND    True if QtDesigner was found.
  43 #  QT_QTMOTIF_FOUND       True if QtMotif was found.
  44 #  QT_QTNETWORK_FOUND     True if QtNetwork was found.
  45 #  QT_QTNSPLUGIN_FOUND    True if QtNsPlugin was found.
  46 #  QT_QTOPENGL_FOUND      True if QtOpenGL was found.
  47 #  QT_QTSQL_FOUND         True if QtSql was found.
  48 #  QT_QTXML_FOUND         True if QtXml was found.
  49 #  QT_QTSVG_FOUND         True if QtSvg was found.
  50 #  QT_QTTEST_FOUND        True if QtTest was found.
  51 #  QT_QTUITOOLS_FOUND     True if QtUiTools was found.
  52 #
  53 #  QT_DEFINITIONS   Definitions to use when compiling code that uses Qt.
  54 #
  55 #  QT_INCLUDES      List of paths to all include directories of
  56 #                   Qt4 QT_INCLUDE_DIR and QT_QTCORE_INCLUDE_DIR are
  57 #                   always in this variable even if NOTFOUND,
  58 #                   all other INCLUDE_DIRS are
  59 #                   only added if they are found.
  60 #
  61 #  QT_INCLUDE_DIR              Path to "include" of Qt4
  62 #  QT_QT_INCLUDE_DIR           Path to "include/Qt"
  63 #  QT_QT3SUPPORT_INCLUDE_DIR   Path to "include/Qt3Support"
  64 #  QT_QTASSISTANT_INCLUDE_DIR  Path to "include/QtAssistant"
  65 #  QT_QTCORE_INCLUDE_DIR       Path to "include/QtCore"
  66 #  QT_QTDESIGNER_INCLUDE_DIR   Path to "include/QtDesigner"
  67 #  QT_QTGUI_INCLUDE_DIR        Path to "include/QtGui"
  68 #  QT_QTMOTIF_INCLUDE_DIR      Path to "include/QtMotif"
  69 #  QT_QTNETWORK_INCLUDE_DIR    Path to "include/QtNetwork"
  70 #  QT_QTNSPLUGIN_INCLUDE_DIR   Path to "include/QtNsPlugin"
  71 #  QT_QTOPENGL_INCLUDE_DIR     Path to "include/QtOpenGL"
  72 #  QT_QTSQL_INCLUDE_DIR        Path to "include/QtSql"
  73 #  QT_QTXML_INCLUDE_DIR        Path to "include/QtXml"
  74 #  QT_QTSVG_INCLUDE_DIR        Path to "include/QtSvg"
  75 #  QT_QTTEST_INCLUDE_DIR       Path to "include/QtTest"
  76 #
  77 #  QT_LIBRARY_DIR              Path to "lib" of Qt4
  78 #
  79 #  QT_PLUGINS_DIR              Path to "plugins" for Qt4
  80 #
  81 # For every library of Qt there are three variables:
  82 #  QT_QTFOO_LIBRARY_RELEASE, which contains the full path to the release version
  83 #  QT_QTFOO_LIBRARY_DEBUG, which contains the full path to the debug version
  84 #  QT_QTFOO_LIBRARY, the full path to the release version if available, otherwise to the debug version
  85 #
  86 # So there are the following variables:
  87 # The Qt3Support library:     QT_QT3SUPPORT_LIBRARY
  88 #                             QT_QT3SUPPORT_LIBRARY_RELEASE
  89 #                             QT_QT3SUPPORT_DEBUG
  90 #
  91 # The QtAssistant library:    QT_QTASSISTANT_LIBRARY
  92 #                             QT_QTASSISTANT_LIBRARY_RELEASE
  93 #                             QT_QTASSISTANT_LIBRARY_DEBUG
  94 #
  95 # The QtCore library:         QT_QTCORE_LIBRARY
  96 #                             QT_QTCORE_LIBRARY_RELEASE
  97 #                             QT_QTCORE_LIBRARY_DEBUG
  98 #
  99 # The QtDesigner library:     QT_QTDESIGNER_LIBRARY
 100 #                             QT_QTDESIGNER_LIBRARY_RELEASE
 101 #                             QT_QTDESIGNER_LIBRARY_DEBUG
 102 #
 103 # The QtGui library:          QT_QTGUI_LIBRARY
 104 #                             QT_QTGUI_LIBRARY_RELEASE
 105 #                             QT_QTGUI_LIBRARY_DEBUG
 106 #
 107 # The QtMotif library:        QT_QTMOTIF_LIBRARY
 108 #                             QT_QTMOTIF_LIBRARY_RELEASE
 109 #                             QT_QTMOTIF_LIBRARY_DEBUG
 110 #
 111 # The QtNetwork library:      QT_QTNETWORK_LIBRARY
 112 #                             QT_QTNETWORK_LIBRARY_RELEASE
 113 #                             QT_QTNETWORK_LIBRARY_DEBUG
 114 #
 115 # The QtNsPLugin library:     QT_QTNSPLUGIN_LIBRARY
 116 #                             QT_QTNSPLUGIN_LIBRARY_RELEASE
 117 #                             QT_QTNSPLUGIN_LIBRARY_DEBUG
 118 #
 119 # The QtOpenGL library:       QT_QTOPENGL_LIBRARY
 120 #                             QT_QTOPENGL_LIBRARY_RELEASE
 121 #                             QT_QTOPENGL_LIBRARY_DEBUG
 122 #
 123 # The QtSql library:          QT_QTSQL_LIBRARY
 124 #                             QT_QTSQL_LIBRARY_RELEASE
 125 #                             QT_QTSQL_LIBRARY_DEBUG
 126 #
 127 # The QtXml library:          QT_QTXML_LIBRARY
 128 #                             QT_QTXML_LIBRARY_RELEASE
 129 #                             QT_QTXML_LIBRARY_DEBUG
 130 #
 131 # The QtSvg library:          QT_QTSVG_LIBRARY
 132 #                             QT_QTSVG_LIBRARY_RELEASE
 133 #                             QT_QTSVG_LIBRARY_DEBUG
 134 #
 135 # The QtTest library:         QT_QTTEST_LIBRARY
 136 #                             QT_QTTEST_LIBRARY_RELEASE
 137 #                             QT_QTTEST_LIBRARY_DEBUG
 138 #
 139 # The qtmain library for Windows QT_QTMAIN_LIBRARY
 140 #                             QT_QTMAIN_LIBRARY_RELEASE
 141 #                             QT_QTMAIN_LIBRARY_DEBUG
 142 #
 143 #The QtUiTools library:       QT_QTUITOOLS_LIBRARY
 144 #                             QT_QTUITOOLS_LIBRARY_RELEASE
 145 #                             QT_QTUITOOLS_LIBRARY_DEBUG
 146 #
 147 # also defined, but NOT for general use are
 148 #  QT_MOC_EXECUTABLE          Where to find the moc tool.
 149 #  QT_UIC_EXECUTABLE          Where to find the uic tool.
 150 #  QT_UIC3_EXECUTABLE         Where to find the uic3 tool.
 151 #  QT_RCC_EXECUTABLE          Where to find the rcc tool
 152 #
 153 #  QT_DOC_DIR                 Path to "doc" of Qt4
 154 #  QT_MKSPECS_DIR             Path to "mkspecs" of Qt4
 155 #
 156 #
 157 # These are around for backwards compatibility
 158 # they will be set
 159 #  QT_WRAP_CPP  Set true if QT_MOC_EXECUTABLE is found
 160 #  QT_WRAP_UI   Set true if QT_UIC_EXECUTABLE is found
 161 #
 162 # These variables do _NOT_ have any effect anymore (compared to FindQt.cmake)
 163 #  QT_MT_REQUIRED         Qt4 is now always multithreaded
 164 #
 165 # These variables are set to "" Because Qt structure changed
 166 # (They make no sense in Qt4)
 167 #  QT_QT_LIBRARY        Qt-Library is now split
 168
 169 INCLUDE(CheckSymbolExists)
 170 INCLUDE(MacroAddFileDependencies)
 171
 172 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
 173
 174 set(QT_USE_FILE ${CMAKE_ROOT}/Modules/UseQt4.cmake)
 175
 176 set(QT_DEFINITIONS "")
 177
 178 # check for qmake
 179 find_program(QT_QMAKE_EXECUTABLE NAMES qmake qmake-qt4 PATHS
 180   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\4.0.0;InstallDir]/bin"
 181   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Versions\\4.0.0;InstallDir]/bin"
 182   $ENV{QTDIR}/bin)
 183
 184 set(QT4_INSTALLED_VERSION_TOO_OLD FALSE)
 185
 186 ##  macro for asking qmake to process pro files
 187 macro(QT_QUERY_QMAKE outvar invar)
 188   file(WRITE ${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmpQmake/tmp.pro
 189     "message(CMAKE_MESSAGE<$$${invar}>)")
 190   execute_process(COMMAND ${QT_QMAKE_EXECUTABLE}
 191     WORKING_DIRECTORY
 192     ${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmpQmake
 193     OUTPUT_VARIABLE _qmake_query_output
 194     ERROR_VARIABLE _qmake_query_output )
 195   file(REMOVE_RECURSE
 196     "${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmpQmake")
 197   string(REGEX REPLACE ".*CMAKE_MESSAGE<([^>]*).*" "\\1"
 198                 ${outvar} "${_qmake_query_output}")
 199 endmacro(QT_QUERY_QMAKE)
 200
 201
 202 if(QT_QMAKE_EXECUTABLE)
 203
 204   set(QT4_QMAKE_FOUND FALSE)
 205
 206   exec_program(${QT_QMAKE_EXECUTABLE} ARGS "-query QT_VERSION"
 207                 OUTPUT_VARIABLE QTVERSION)
 208   # check for qt3 qmake and then try and find qmake-qt4 in the path
 209   if("${QTVERSION}" MATCHES "Unknown")
 210     set(QT_QMAKE_EXECUTABLE NOTFOUND CACHE FILEPATH "" FORCE)
 211     find_program(QT_QMAKE_EXECUTABLE NAMES qmake-qt4 PATHS
 212       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\4.0.0;InstallDir]/bin"
 213       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Versions\\4.0.0;InstallDir]/bin"
 214       $ENV{QTDIR}/bin
 215       )
 216     if(QT_QMAKE_EXECUTABLE)
 217       EXEC_PROGRAM(${QT_QMAKE_EXECUTABLE}
 218         ARGS "-query QT_VERSION" OUTPUT_VARIABLE QTVERSION)
 219     endif()
 220   endif()
 221   # check that we found the Qt4 qmake, Qt3 qmake output won't match here
 222   string(REGEX MATCH "^[0-9]+\\.[0-9]+\\.[0-9]+" qt_version_tmp "${QTVERSION}")
 223   if(qt_version_tmp)
 224
 225     # we need at least version 4.0.0
 226     if(NOT QT_MIN_VERSION)
 227       set(QT_MIN_VERSION "4.0.0")
 228     endif()
 229
 230     # now parse the parts of the user given version string into variables
 231     string(REGEX MATCH "^[0-9]+\\.[0-9]+\\.[0-9]+" req_qt_major_vers "${QT_MIN_VERSION}")
 232     if(NOT req_qt_major_vers)
 233       message( FATAL_ERROR "Invalid Qt version string given: \"${QT_MIN_VERSION}\", expected e.g. \"4.0.1\"")
 234     endif()
 235
 236     # now parse the parts of the user given version string into variables
 237     string(REGEX REPLACE "^([0-9]+)\\.[0-9]+\\.[0-9]+" "\\1"
 238                         req_qt_major_vers "${QT_MIN_VERSION}")
 239     string(REGEX REPLACE "^[0-9]+\\.([0-9])+\\.[0-9]+" "\\1"
 240                         req_qt_minor_vers "${QT_MIN_VERSION}")
 241     string(REGEX REPLACE "^[0-9]+\\.[0-9]+\\.([0-9]+)" "\\1"
 242                         req_qt_patch_vers "${QT_MIN_VERSION}")
 243
 244     if(NOT req_qt_major_vers EQUAL 4)
 245       message( FATAL_ERROR "Invalid Qt version string given: \"${QT_MIN_VERSION}\", major version 4 is required, e.g. \"4.0.1\"")
 246     endif()
 247
 248     # and now the version string given by qmake
 249     string(REGEX REPLACE "^([0-9]+)\\.[0-9]+\\.[0-9]+.*" "\\1"
 250                         found_qt_major_vers "${QTVERSION}")
 251     string(REGEX REPLACE "^[0-9]+\\.([0-9])+\\.[0-9]+.*" "\\1"
 252                         found_qt_minor_vers "${QTVERSION}")
 253     string(REGEX REPLACE "^[0-9]+\\.[0-9]+\\.([0-9]+).*" "\\1"
 254                         found_qt_patch_vers "${QTVERSION}")
 255
 256     # compute an overall version number which can be compared at once
 257     math(EXPR req_vers "${req_qt_major_vers}*10000 + ${req_qt_minor_vers}*100 + ${req_qt_patch_vers}")
 258     math(EXPR found_vers "${found_qt_major_vers}*10000 + ${found_qt_minor_vers}*100 + ${found_qt_patch_vers}")
 259
 260     if(found_vers LESS req_vers)
 261       set(QT4_QMAKE_FOUND FALSE)
 262       set(QT4_INSTALLED_VERSION_TOO_OLD TRUE)
 263     else()
 264       set(QT4_QMAKE_FOUND TRUE)
 265     endif()
 266   endif()
 267
 268 endif()
 269
 270 if(QT4_QMAKE_FOUND)
 271
 272   # ask qmake for the library dir
 273   # Set QT_LIBRARY_DIR
 274   if(NOT QT_LIBRARY_DIR)
 275     exec_program( ${QT_QMAKE_EXECUTABLE}
 276       ARGS "-query QT_INSTALL_LIBS"
 277       OUTPUT_VARIABLE QT_LIBRARY_DIR_TMP)
 278     if(EXISTS "${QT_LIBRARY_DIR_TMP}")
 279       set(QT_LIBRARY_DIR ${QT_LIBRARY_DIR_TMP} CACHE PATH "Qt library dir")
 280     else()
 281       message("Warning: QT_QMAKE_EXECUTABLE reported QT_INSTALL_LIBS as ${QT_LIBRARY_DIR_TMP}")
 282       message("Warning: ${QT_LIBRARY_DIR_TMP} does NOT exist, Qt must NOT be installed correctly.")
 283     endif()
 284   endif()
 285
 286   if(APPLE)
 287     if(EXISTS ${QT_LIBRARY_DIR}/QtCore.framework)
 288       set(QT_USE_FRAMEWORKS ON
 289         CACHE BOOL "Set to ON if Qt build uses frameworks.")
 290     else()
 291       set(QT_USE_FRAMEWORKS OFF
 292         CACHE BOOL "Set to ON if Qt build uses frameworks.")
 293     endif()
 294
 295     mark_as_advanced(QT_USE_FRAMEWORKS)
 296   endif()
 297
 298   # ask qmake for the binary dir
 299   if(NOT QT_BINARY_DIR)
 300     exec_program(${QT_QMAKE_EXECUTABLE}
 301       ARGS "-query QT_INSTALL_BINS"
 302       OUTPUT_VARIABLE qt_bins )
 303     set(QT_BINARY_DIR ${qt_bins} CACHE INTERNAL "")
 304   endif()
 305
 306   # ask qmake for the include dir
 307   if(NOT QT_HEADERS_DIR)
 308     EXEC_PROGRAM( ${QT_QMAKE_EXECUTABLE}
 309       ARGS "-query QT_INSTALL_HEADERS"
 310       OUTPUT_VARIABLE qt_headers )
 311     set(QT_HEADERS_DIR ${qt_headers} CACHE INTERNAL "")
 312   endif()
 313
 314
 315   # ask qmake for the documentation directory
 316   if(NOT QT_DOC_DIR)
 317     exec_program( ${QT_QMAKE_EXECUTABLE}
 318       ARGS "-query QT_INSTALL_DOCS"
 319       OUTPUT_VARIABLE qt_doc_dir )
 320     set(QT_DOC_DIR ${qt_doc_dir} CACHE PATH "The location of the Qt docs")
 321   endif()
 322
 323   # ask qmake for the mkspecs directory
 324   if(NOT QT_MKSPECS_DIR)
 325     exec_program( ${QT_QMAKE_EXECUTABLE}
 326       ARGS "-query QMAKE_MKSPECS"
 327       OUTPUT_VARIABLE qt_mkspecs_dir )
 328     set(QT_MKSPECS_DIR ${qt_mkspecs_dir} CACHE PATH
 329                         "The location of the Qt mkspecs")
 330   endif()
 331
 332   # ask qmake for the plugins directory
 333   if(NOT QT_PLUGINS_DIR)
 334     exec_program( ${QT_QMAKE_EXECUTABLE}
 335       ARGS "-query QT_INSTALL_PLUGINS"
 336       OUTPUT_VARIABLE qt_plugins_dir )
 337     set(QT_PLUGINS_DIR ${qt_plugins_dir} CACHE PATH
 338                         "The location of the Qt plugins")
 339   endif()
 340   ########################################
 341   #
 342   #       Setting the INCLUDE-Variables
 343   #
 344   ########################################
 345
 346   find_path(QT_QTCORE_INCLUDE_DIR QtGlobal
 347     ${QT_HEADERS_DIR}/QtCore
 348     ${QT_LIBRARY_DIR}/QtCore.framework/Headers
 349     NO_DEFAULT_PATH)
 350
 351   # Set QT_INCLUDE_DIR by removing "/QtCore" in the string ${QT_QTCORE_INCLUDE_DIR}
 352   if(QT_QTCORE_INCLUDE_DIR AND NOT QT_INCLUDE_DIR)
 353     if(QT_USE_FRAMEWORKS)
 354       set(QT_INCLUDE_DIR ${QT_HEADERS_DIR})
 355     else()
 356       string(REGEX REPLACE "/QtCore$" "" qt4_include_dir ${QT_QTCORE_INCLUDE_DIR})
 357       set(QT_INCLUDE_DIR ${qt4_include_dir} CACHE PATH "")
 358     endif()
 359   endif()
 360
 361   if(NOT QT_INCLUDE_DIR)
 362     if(NOT Qt4_FIND_QUIETLY AND Qt4_FIND_REQUIRED)
 363       message( FATAL_ERROR "Could NOT find QtGlobal header")
 364     endif()
 365   endif()
 366
 367   #############################################
 368   #
 369   # Find out what window system we're using
 370   #
 371   #############################################
 372   # Save required includes variable
 373   set(CMAKE_REQUIRED_INCLUDES_SAVE ${CMAKE_REQUIRED_INCLUDES})
 374   # Add QT_INCLUDE_DIR to CMAKE_REQUIRED_INCLUDES
 375   set(CMAKE_REQUIRED_INCLUDES "${CMAKE_REQUIRED_INCLUDES};${QT_INCLUDE_DIR}")
 376   # Check for Window system symbols (note: only one should end up being set)
 377   check_symbol_exists(Q_WS_X11 "QtCore/qglobal.h" Q_WS_X11)
 378   check_symbol_exists(Q_WS_MAC "QtCore/qglobal.h" Q_WS_MAC)
 379   check_symbol_exists(Q_WS_WIN "QtCore/qglobal.h" Q_WS_WIN)
 380
 381   if(QT_QTCOPY_REQUIRED)
 382     check_symbol_exists(QT_IS_QTCOPY "QtCore/qglobal.h" QT_KDE_QT_COPY)
 383     if(NOT QT_IS_QTCOPY)
 384       message(FATAL_ERROR "qt-copy is required, but hasn't been found")
 385     endif()
 386   endif()
 387
 388   # Restore CMAKE_REQUIRED_INCLUDES variable
 389   set(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES_SAVE})
 390   #
 391   #############################################
 392
 393   IF (QT_USE_FRAMEWORKS)
 394     set(QT_DEFINITIONS ${QT_DEFINITIONS} -F${QT_LIBRARY_DIR} -L${QT_LIBRARY_DIR} )
 395   endif()
 396
 397   # Set QT_QT3SUPPORT_INCLUDE_DIR
 398   FIND_PATH(QT_QT3SUPPORT_INCLUDE_DIR Qt3Support
 399     PATHS
 400     ${QT_INCLUDE_DIR}/Qt3Support
 401     ${QT_LIBRARY_DIR}/Qt3Support.framework/Headers
 402     NO_DEFAULT_PATH
 403     )
 404
 405   # Set QT_QT_INCLUDE_DIR
 406   FIND_PATH(QT_QT_INCLUDE_DIR qglobal.h
 407     PATHS
 408     ${QT_INCLUDE_DIR}/Qt
 409     ${QT_LIBRARY_DIR}/QtCore.framework/Headers
 410     NO_DEFAULT_PATH
 411     )
 412
 413   # Set QT_QTGUI_INCLUDE_DIR
 414   FIND_PATH(QT_QTGUI_INCLUDE_DIR QtGui
 415     PATHS
 416     ${QT_INCLUDE_DIR}/QtGui
 417     ${QT_LIBRARY_DIR}/QtGui.framework/Headers
 418     NO_DEFAULT_PATH
 419     )
 420
 421   # Set QT_QTSVG_INCLUDE_DIR
 422   FIND_PATH(QT_QTSVG_INCLUDE_DIR QtSvg
 423     PATHS
 424     ${QT_INCLUDE_DIR}/QtSvg
 425     ${QT_LIBRARY_DIR}/QtSvg.framework/Headers
 426     NO_DEFAULT_PATH
 427     )
 428
 429   # Set QT_QTTEST_INCLUDE_DIR
 430   FIND_PATH(QT_QTTEST_INCLUDE_DIR QtTest
 431     PATHS
 432     ${QT_INCLUDE_DIR}/QtTest
 433     ${QT_LIBRARY_DIR}/QtTest.framework/Headers
 434     NO_DEFAULT_PATH
 435     )
 436
 437   # Set QT_QTUITOOLS_INCLUDE_DIR
 438   FIND_PATH(QT_QTUITOOLS_INCLUDE_DIR QtUiTools
 439     PATHS
 440     ${QT_INCLUDE_DIR}/QtUiTools
 441     ${QT_LIBRARY_DIR}/QtUiTools.framework/Headers
 442     NO_DEFAULT_PATH
 443     )
 444
 445
 446
 447   # Set QT_QTMOTIF_INCLUDE_DIR
 448   IF(Q_WS_X11)
 449     FIND_PATH(QT_QTMOTIF_INCLUDE_DIR QtMotif PATHS ${QT_INCLUDE_DIR}/QtMotif NO_DEFAULT_PATH )
 450   endif()
 451
 452   # Set QT_QTNETWORK_INCLUDE_DIR
 453   FIND_PATH(QT_QTNETWORK_INCLUDE_DIR QtNetwork
 454     PATHS
 455     ${QT_INCLUDE_DIR}/QtNetwork
 456     ${QT_LIBRARY_DIR}/QtNetwork.framework/Headers
 457     NO_DEFAULT_PATH
 458     )
 459
 460   # Set QT_QTNSPLUGIN_INCLUDE_DIR
 461   FIND_PATH(QT_QTNSPLUGIN_INCLUDE_DIR QtNsPlugin
 462     PATHS
 463     ${QT_INCLUDE_DIR}/QtNsPlugin
 464     ${QT_LIBRARY_DIR}/QtNsPlugin.framework/Headers
 465     NO_DEFAULT_PATH
 466     )
 467
 468   # Set QT_QTOPENGL_INCLUDE_DIR
 469   FIND_PATH(QT_QTOPENGL_INCLUDE_DIR QtOpenGL
 470     PATHS
 471     ${QT_INCLUDE_DIR}/QtOpenGL
 472     ${QT_LIBRARY_DIR}/QtOpenGL.framework/Headers
 473     NO_DEFAULT_PATH
 474     )
 475
 476   # Set QT_QTSQL_INCLUDE_DIR
 477   FIND_PATH(QT_QTSQL_INCLUDE_DIR QtSql
 478     PATHS
 479     ${QT_INCLUDE_DIR}/QtSql
 480     ${QT_LIBRARY_DIR}/QtSql.framework/Headers
 481     NO_DEFAULT_PATH
 482     )
 483
 484   # Set QT_QTXML_INCLUDE_DIR
 485   FIND_PATH(QT_QTXML_INCLUDE_DIR QtXml
 486     PATHS
 487     ${QT_INCLUDE_DIR}/QtXml
 488     ${QT_LIBRARY_DIR}/QtXml.framework/Headers
 489     NO_DEFAULT_PATH
 490     )
 491
 492   # Set QT_QTASSISTANT_INCLUDE_DIR
 493   FIND_PATH(QT_QTASSISTANT_INCLUDE_DIR QtAssistant
 494     PATHS
 495     ${QT_INCLUDE_DIR}/QtAssistant
 496     ${QT_HEADERS_DIR}/QtAssistant
 497     NO_DEFAULT_PATH
 498     )
 499
 500   # Set QT_QTDESIGNER_INCLUDE_DIR
 501   FIND_PATH(QT_QTDESIGNER_INCLUDE_DIR QDesignerComponents
 502     PATHS
 503     ${QT_INCLUDE_DIR}/QtDesigner
 504     ${QT_HEADERS_DIR}/QtDesigner
 505     NO_DEFAULT_PATH
 506     )
 507
 508   # Make variables changeble to the advanced user
 509   MARK_AS_ADVANCED( QT_LIBRARY_DIR QT_INCLUDE_DIR QT_QT_INCLUDE_DIR QT_DOC_DIR)
 510
 511   # Set QT_INCLUDES
 512   set( QT_INCLUDES ${QT_INCLUDE_DIR} ${QT_QT_INCLUDE_DIR} ${QT_MKSPECS_DIR}/default )
 513
 514   # Set QT_QTCORE_LIBRARY by searching for a lib with "QtCore."  as part of the filename
 515   FIND_LIBRARY(QT_QTCORE_LIBRARY_RELEASE NAMES QtCore QtCore4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH )
 516   FIND_LIBRARY(QT_QTCORE_LIBRARY_DEBUG NAMES QtCore_debug QtCored QtCored4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 517
 518   # Set QT_QT3SUPPORT_LIBRARY
 519   FIND_LIBRARY(QT_QT3SUPPORT_LIBRARY_RELEASE NAMES Qt3Support Qt3Support4 PATHS ${QT_LIBRARY_DIR}        NO_DEFAULT_PATH)
 520   FIND_LIBRARY(QT_QT3SUPPORT_LIBRARY_DEBUG   NAMES Qt3Support_debug Qt3Supportd4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 521
 522   # Set QT_QTGUI_LIBRARY
 523   FIND_LIBRARY(QT_QTGUI_LIBRARY_RELEASE NAMES QtGui QtGui4 PATHS ${QT_LIBRARY_DIR}        NO_DEFAULT_PATH)
 524   FIND_LIBRARY(QT_QTGUI_LIBRARY_DEBUG   NAMES QtGui_debug QtGuid4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 525
 526   # Set QT_QTMOTIF_LIBRARY
 527   IF(Q_WS_X11)
 528     FIND_LIBRARY(QT_QTMOTIF_LIBRARY_RELEASE NAMES QtMotif PATHS ${QT_LIBRARY_DIR}       NO_DEFAULT_PATH)
 529     FIND_LIBRARY(QT_QTMOTIF_LIBRARY_DEBUG   NAMES QtMotif_debug PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 530   endif()
 531
 532   # Set QT_QTNETWORK_LIBRARY
 533   FIND_LIBRARY(QT_QTNETWORK_LIBRARY_RELEASE NAMES QtNetwork QtNetwork4 PATHS ${QT_LIBRARY_DIR}        NO_DEFAULT_PATH)
 534   FIND_LIBRARY(QT_QTNETWORK_LIBRARY_DEBUG   NAMES QtNetwork_debug QtNetworkd4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 535
 536   # Set QT_QTNSPLUGIN_LIBRARY
 537   FIND_LIBRARY(QT_QTNSPLUGIN_LIBRARY_RELEASE NAMES QtNsPlugin PATHS ${QT_LIBRARY_DIR}       NO_DEFAULT_PATH)
 538   FIND_LIBRARY(QT_QTNSPLUGIN_LIBRARY_DEBUG   NAMES QtNsPlugin_debug PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 539
 540   # Set QT_QTOPENGL_LIBRARY
 541   FIND_LIBRARY(QT_QTOPENGL_LIBRARY_RELEASE NAMES QtOpenGL QtOpenGL4 PATHS ${QT_LIBRARY_DIR}        NO_DEFAULT_PATH)
 542   FIND_LIBRARY(QT_QTOPENGL_LIBRARY_DEBUG   NAMES QtOpenGL_debug QtOpenGLd4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 543
 544   # Set QT_QTSQL_LIBRARY
 545   FIND_LIBRARY(QT_QTSQL_LIBRARY_RELEASE NAMES QtSql QtSql4 PATHS ${QT_LIBRARY_DIR}        NO_DEFAULT_PATH)
 546   FIND_LIBRARY(QT_QTSQL_LIBRARY_DEBUG   NAMES QtSql_debug QtSqld4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 547
 548   # Set QT_QTXML_LIBRARY
 549   FIND_LIBRARY(QT_QTXML_LIBRARY_RELEASE NAMES QtXml QtXml4 PATHS ${QT_LIBRARY_DIR}        NO_DEFAULT_PATH)
 550   FIND_LIBRARY(QT_QTXML_LIBRARY_DEBUG   NAMES QtXml_debug QtXmld4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 551
 552   # Set QT_QTSVG_LIBRARY
 553   FIND_LIBRARY(QT_QTSVG_LIBRARY_RELEASE NAMES QtSvg QtSvg4 PATHS ${QT_LIBRARY_DIR}        NO_DEFAULT_PATH)
 554   FIND_LIBRARY(QT_QTSVG_LIBRARY_DEBUG   NAMES QtSvg_debug QtSvgd4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 555
 556   # Set QT_QTUITOOLS_LIBRARY
 557   FIND_LIBRARY(QT_QTUITOOLS_LIBRARY_RELEASE NAMES QtUiTools QtUiTools4 PATHS ${QT_LIBRARY_DIR}        NO_DEFAULT_PATH)
 558   FIND_LIBRARY(QT_QTUITOOLS_LIBRARY_DEBUG   NAMES QtUiTools_debug QtUiToolsd4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 559
 560   # Set QT_QTTEST_LIBRARY
 561   FIND_LIBRARY(QT_QTTEST_LIBRARY_RELEASE NAMES QtTest QtTest4 PATHS ${QT_LIBRARY_DIR}                      NO_DEFAULT_PATH)
 562   FIND_LIBRARY(QT_QTTEST_LIBRARY_DEBUG   NAMES QtTest_debug QtTest_debug4 QtTestd4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 563
 564   MARK_AS_ADVANCED(QT_QT3SUPPORT_LIBRARY QT_QTGUI_LIBRARY )
 565
 566   IF( NOT QT_QTCORE_LIBRARY_DEBUG AND NOT QT_QTCORE_LIBRARY_RELEASE )
 567     IF( NOT Qt4_FIND_QUIETLY AND Qt4_FIND_REQUIRED)
 568       message( FATAL_ERROR "Could NOT find QtCore. Check ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log for more details.")
 569     endif()
 570   endif()
 571
 572   # Set QT_QTASSISTANT_LIBRARY
 573   FIND_LIBRARY(QT_QTASSISTANT_LIBRARY_RELEASE NAMES QtAssistantClient QtAssistantClient4 QtAssistant QtAssistant4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 574   FIND_LIBRARY(QT_QTASSISTANT_LIBRARY_DEBUG   NAMES QtAssistantClientd QtAssistantClientd4 QtAssistantClient_debug QtAssistant_debug QtAssistantd4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 575
 576   # Set QT_QTDESIGNER_LIBRARY
 577   FIND_LIBRARY(QT_QTDESIGNER_LIBRARY_RELEASE NAMES QtDesigner QtDesigner4 PATHS ${QT_LIBRARY_DIR}        NO_DEFAULT_PATH)
 578   FIND_LIBRARY(QT_QTDESIGNER_LIBRARY_DEBUG   NAMES QtDesigner_debug QtDesignerd4 PATHS ${QT_LIBRARY_DIR} NO_DEFAULT_PATH)
 579
 580   # Set QT_QTMAIN_LIBRARY
 581   IF(WIN32)
 582     FIND_LIBRARY(QT_QTMAIN_LIBRARY_RELEASE NAMES qtmain  PATHS ${QT_LIBRARY_DIR}  NO_DEFAULT_PATH)
 583     FIND_LIBRARY(QT_QTMAIN_LIBRARY_DEBUG   NAMES qtmaind PATHS ${QT_LIBRARY_DIR}  NO_DEFAULT_PATH)
 584   endif()
 585
 586   ############################################
 587   #
 588   # Check the existence of the libraries.
 589   #
 590   ############################################
 591
 592   MACRO (_QT4_ADJUST_LIB_VARS basename)
 593     IF (QT_${basename}_LIBRARY_RELEASE OR QT_${basename}_LIBRARY_DEBUG)
 594
 595       # if only the release version was found, set the debug variable also to the release version
 596       IF (QT_${basename}_LIBRARY_RELEASE AND NOT QT_${basename}_LIBRARY_DEBUG)
 597         set(QT_${basename}_LIBRARY_DEBUG ${QT_${basename}_LIBRARY_RELEASE})
 598         set(QT_${basename}_LIBRARY       ${QT_${basename}_LIBRARY_RELEASE})
 599         set(QT_${basename}_LIBRARIES     ${QT_${basename}_LIBRARY_RELEASE})
 600       endif()
 601
 602       # if only the debug version was found, set the release variable also to the debug version
 603       IF (QT_${basename}_LIBRARY_DEBUG AND NOT QT_${basename}_LIBRARY_RELEASE)
 604         set(QT_${basename}_LIBRARY_RELEASE ${QT_${basename}_LIBRARY_DEBUG})
 605         set(QT_${basename}_LIBRARY         ${QT_${basename}_LIBRARY_DEBUG})
 606         set(QT_${basename}_LIBRARIES       ${QT_${basename}_LIBRARY_DEBUG})
 607       endif()
 608       IF (QT_${basename}_LIBRARY_DEBUG AND QT_${basename}_LIBRARY_RELEASE)
 609         # if the generator supports configuration types then set
 610         # optimized and debug libraries, or if the CMAKE_BUILD_TYPE has a value
 611         IF (CMAKE_CONFIGURATION_TYPES OR CMAKE_BUILD_TYPE)
 612           set(QT_${basename}_LIBRARY       optimized ${QT_${basename}_LIBRARY_RELEASE} debug ${QT_${basename}_LIBRARY_DEBUG})
 613         else()
 614           # if there are no configuration types and CMAKE_BUILD_TYPE has no value
 615           # then just use the release libraries
 616           set(QT_${basename}_LIBRARY       ${QT_${basename}_LIBRARY_RELEASE} )
 617         endif()
 618         set(QT_${basename}_LIBRARIES       optimized ${QT_${basename}_LIBRARY_RELEASE} debug ${QT_${basename}_LIBRARY_DEBUG})
 619       endif()
 620
 621       set(QT_${basename}_LIBRARY ${QT_${basename}_LIBRARY} CACHE FILEPATH "The Qt ${basename} library")
 622
 623       IF (QT_${basename}_LIBRARY)
 624         set(QT_${basename}_FOUND 1)
 625       endif()
 626     endif()
 627
 628       #add the include directory to QT_INCLUDES
 629     IF (QT_${basename}_INCLUDE_DIR)
 630       set(QT_INCLUDES ${QT_INCLUDES} "${QT_${basename}_INCLUDE_DIR}")
 631     endif()
 632
 633     # Make variables changeble to the advanced user
 634     MARK_AS_ADVANCED(QT_${basename}_LIBRARY QT_${basename}_LIBRARY_RELEASE QT_${basename}_LIBRARY_DEBUG QT_${basename}_INCLUDE_DIR)
 635   ENDMACRO (_QT4_ADJUST_LIB_VARS)
 636
 637
 638   # Set QT_xyz_LIBRARY variable and add
 639   # library include path to QT_INCLUDES
 640   _QT4_ADJUST_LIB_VARS(QTCORE)
 641   _QT4_ADJUST_LIB_VARS(QTGUI)
 642   _QT4_ADJUST_LIB_VARS(QT3SUPPORT)
 643   _QT4_ADJUST_LIB_VARS(QTASSISTANT)
 644   _QT4_ADJUST_LIB_VARS(QTDESIGNER)
 645   _QT4_ADJUST_LIB_VARS(QTNETWORK)
 646   _QT4_ADJUST_LIB_VARS(QTNSPLUGIN)
 647   _QT4_ADJUST_LIB_VARS(QTOPENGL)
 648   _QT4_ADJUST_LIB_VARS(QTSQL)
 649   _QT4_ADJUST_LIB_VARS(QTXML)
 650   _QT4_ADJUST_LIB_VARS(QTSVG)
 651   _QT4_ADJUST_LIB_VARS(QTUITOOLS)
 652   _QT4_ADJUST_LIB_VARS(QTTEST)
 653
 654   # platform dependent libraries
 655   IF(Q_WS_X11)
 656     _QT4_ADJUST_LIB_VARS(QTMOTIF)
 657   endif()
 658   IF(WIN32)
 659     _QT4_ADJUST_LIB_VARS(QTMAIN)
 660   endif()
 661
 662   #######################################
 663   #
 664   #       Check the executables of Qt
 665   #          ( moc, uic, rcc )
 666   #
 667   #######################################
 668
 669
 670   # find moc and uic using qmake
 671   QT_QUERY_QMAKE(QT_MOC_EXECUTABLE_INTERNAL "QMAKE_MOC")
 672   QT_QUERY_QMAKE(QT_UIC_EXECUTABLE_INTERNAL "QMAKE_UIC")
 673
 674   FILE(TO_CMAKE_PATH
 675     "${QT_MOC_EXECUTABLE_INTERNAL}" QT_MOC_EXECUTABLE_INTERNAL)
 676   FILE(TO_CMAKE_PATH
 677     "${QT_UIC_EXECUTABLE_INTERNAL}" QT_UIC_EXECUTABLE_INTERNAL)
 678
 679   set(QT_MOC_EXECUTABLE
 680     ${QT_MOC_EXECUTABLE_INTERNAL} CACHE FILEPATH "The moc executable")
 681   set(QT_UIC_EXECUTABLE
 682     ${QT_UIC_EXECUTABLE_INTERNAL} CACHE FILEPATH "The uic executable")
 683
 684   FIND_PROGRAM(QT_UIC3_EXECUTABLE
 685     NAMES uic3
 686     PATHS ${QT_BINARY_DIR}
 687     NO_DEFAULT_PATH
 688     )
 689
 690   FIND_PROGRAM(QT_RCC_EXECUTABLE
 691     NAMES rcc
 692     PATHS ${QT_BINARY_DIR}
 693     NO_DEFAULT_PATH
 694     )
 695
 696   IF (QT_MOC_EXECUTABLE)
 697     set(QT_WRAP_CPP "YES")
 698   endif()
 699
 700   IF (QT_UIC_EXECUTABLE)
 701     set(QT_WRAP_UI "YES")
 702   endif()
 703
 704
 705
 706   MARK_AS_ADVANCED( QT_UIC_EXECUTABLE QT_UIC3_EXECUTABLE QT_MOC_EXECUTABLE QT_RCC_EXECUTABLE )
 707
 708   ######################################
 709   #
 710   #       Macros for building Qt files
 711   #
 712   ######################################
 713
 714   MACRO (QT4_GET_MOC_INC_DIRS _moc_INC_DIRS)
 715     set(${_moc_INC_DIRS})
 716     GET_DIRECTORY_PROPERTY(_inc_DIRS INCLUDE_DIRECTORIES)
 717
 718     FOREACH(_current ${_inc_DIRS})
 719       set(${_moc_INC_DIRS} ${${_moc_INC_DIRS}} "-I" ${_current})
 720     ENDFOREACH(_current ${_inc_DIRS})
 721   ENDMACRO(QT4_GET_MOC_INC_DIRS)
 722
 723
 724   MACRO (QT4_GENERATE_MOC infile outfile )
 725     # get include dirs
 726     QT4_GET_MOC_INC_DIRS(moc_includes)
 727
 728     GET_FILENAME_COMPONENT(infile ${infile} ABSOLUTE)
 729
 730     ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 731       COMMAND ${QT_MOC_EXECUTABLE}
 732       ARGS ${moc_includes} -o ${outfile} ${infile}
 733       DEPENDS ${infile})
 734
 735     MACRO_ADD_FILE_DEPENDENCIES(${infile} ${outfile})
 736   ENDMACRO (QT4_GENERATE_MOC)
 737
 738
 739   # QT4_WRAP_CPP(outfiles inputfile ... )
 740   # TODO  perhaps add support for -D, -U and other minor options
 741
 742   MACRO (QT4_WRAP_CPP outfiles )
 743     # get include dirs
 744     QT4_GET_MOC_INC_DIRS(moc_includes)
 745
 746     FOREACH (it ${ARGN})
 747       GET_FILENAME_COMPONENT(it ${it} ABSOLUTE)
 748       GET_FILENAME_COMPONENT(outfile ${it} NAME_WE)
 749
 750       set(outfile ${CMAKE_CURRENT_BINARY_DIR}/moc_${outfile}.cxx)
 751       ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 752         COMMAND ${QT_MOC_EXECUTABLE}
 753         ARGS ${moc_includes} -o ${outfile} ${it}
 754         DEPENDS ${it})
 755       set(${outfiles} ${${outfiles}} ${outfile})
 756     ENDFOREACH(it)
 757
 758   ENDMACRO (QT4_WRAP_CPP)
 759
 760
 761
 762
 763 macro (QT4_EXTRACT_OPTIONS _qt4_files _qt4_options)
 764         set(${_qt4_files})
 765         set(${_qt4_options})
 766         set(_QT4_DOING_OPTIONS FALSE)
 767         foreach (_currentArg ${ARGN})
 768                 if ("${_currentArg}" STREQUAL "OPTIONS")
 769                         set(_QT4_DOING_OPTIONS TRUE)
 770                 else ()
 771                         if (_QT4_DOING_OPTIONS)
 772                                 list(APPEND ${_qt4_options} "${_currentArg}")
 773                         else()
 774                                 list(APPEND ${_qt4_files} "${_currentArg}")
 775                         endif()
 776                 endif()
 777         endforeach()
 778 endmacro()
 779
 780   # QT4_WRAP_UI(outfiles inputfile ... )
 781
 782   MACRO (QT4_WRAP_UI outfiles )
 783     QT4_EXTRACT_OPTIONS(ui_files_list ui_options ${ARGN})
 784     FOREACH (it ${ui_files_list})
 785
 786       GET_FILENAME_COMPONENT(outfile ${it} NAME_WE)
 787       GET_FILENAME_COMPONENT(infile ${it} ABSOLUTE)
 788
 789       set(outfile ${CMAKE_CURRENT_BINARY_DIR}/ui_${outfile}.h)
 790       ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 791         COMMAND ${QT_UIC_EXECUTABLE}
 792         ARGS ${ui_options} -o ${outfile} ${infile}
 793         MAIN_DEPENDENCY ${infile})
 794     ENDFOREACH (it)
 795
 796   ENDMACRO (QT4_WRAP_UI)
 797
 798
 799   # QT4_ADD_RESOURCE(outfiles inputfile ... )
 800   # TODO  perhaps consider adding support for compression and root options to rcc
 801
 802   MACRO (QT4_ADD_RESOURCES outfiles )
 803
 804     FOREACH (it ${ARGN})
 805       GET_FILENAME_COMPONENT(outfilename ${it} NAME_WE)
 806       GET_FILENAME_COMPONENT(infile ${it} ABSOLUTE)
 807       set(outfile ${CMAKE_CURRENT_BINARY_DIR}/qrc_${outfilename}.cxx)
 808       ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 809         COMMAND ${QT_RCC_EXECUTABLE}
 810         ARGS -name ${outfilename} -o ${outfile} ${infile}
 811         MAIN_DEPENDENCY ${infile} )
 812       set(${outfiles} ${${outfiles}} ${outfile})
 813     ENDFOREACH (it)
 814
 815   ENDMACRO (QT4_ADD_RESOURCES)
 816
 817
 818   MACRO(QT4_AUTOMOC)
 819     QT4_GET_MOC_INC_DIRS(_moc_INCS)
 820
 821     set(_matching_FILES )
 822     FOREACH (_current_FILE ${ARGN})
 823
 824       GET_FILENAME_COMPONENT(_abs_FILE ${_current_FILE} ABSOLUTE)
 825       # if "SKIP_AUTOMOC" is set to true, we will not handle this file here.
 826       # here. this is required to make bouic work correctly:
 827       # we need to add generated .cpp files to the sources (to compile them),
 828       # but we cannot let automoc handle them, as the .cpp files don't exist yet when
 829       # cmake is run for the very first time on them -> however the .cpp files might
 830       # exist at a later run. at that time we need to skip them, so that we don't add two
 831       # different rules for the same moc file
 832       GET_SOURCE_FILE_PROPERTY(_skip ${_abs_FILE} SKIP_AUTOMOC)
 833
 834       IF ( NOT _skip AND EXISTS ${_abs_FILE} )
 835
 836         FILE(READ ${_abs_FILE} _contents)
 837
 838         GET_FILENAME_COMPONENT(_abs_PATH ${_abs_FILE} PATH)
 839
 840         STRING(REGEX MATCHALL "#include +[^ ]+\\.moc[\">]" _match "${_contents}")
 841         IF(_match)
 842           FOREACH (_current_MOC_INC ${_match})
 843             STRING(REGEX MATCH "[^ <\"]+\\.moc" _current_MOC "${_current_MOC_INC}")
 844
 845             GET_filename_component(_basename ${_current_MOC} NAME_WE)
 846             # set(_header ${CMAKE_CURRENT_SOURCE_DIR}/${_basename}.h)
 847             set(_header ${_abs_PATH}/${_basename}.h)
 848             set(_moc    ${CMAKE_CURRENT_BINARY_DIR}/${_current_MOC})
 849             ADD_CUSTOM_COMMAND(OUTPUT ${_moc}
 850               COMMAND ${QT_MOC_EXECUTABLE}
 851               ARGS ${_moc_INCS} ${_header} -o ${_moc}
 852               DEPENDS ${_header}
 853               )
 854
 855             MACRO_ADD_FILE_DEPENDENCIES(${_abs_FILE} ${_moc})
 856           ENDFOREACH (_current_MOC_INC)
 857         endif()
 858       endif()
 859     ENDFOREACH (_current_FILE)
 860   ENDMACRO(QT4_AUTOMOC)
 861
 862
 863
 864   ######################################
 865   #
 866   #       decide if Qt got found
 867   #
 868   ######################################
 869
 870   # if the includes,libraries,moc,uic and rcc are found then we have it
 871   IF( QT_LIBRARY_DIR AND QT_INCLUDE_DIR AND QT_MOC_EXECUTABLE AND QT_UIC_EXECUTABLE AND QT_RCC_EXECUTABLE)
 872     set( QT4_FOUND "YES" )
 873     IF( NOT Qt4_FIND_QUIETLY)
 874       message(STATUS "Found Qt-Version ${QTVERSION}")
 875     endif()
 876   else()
 877     set( QT4_FOUND "NO")
 878     IF( Qt4_FIND_REQUIRED)
 879       message( FATAL_ERROR "Qt libraries, includes, moc, uic or/and rcc NOT found!")
 880     endif()
 881   endif()
 882   set(QT_FOUND ${QT4_FOUND})
 883
 884   #######################################
 885   #
 886   #       Qt configuration
 887   #
 888   #######################################
 889   IF(EXISTS "${QT_MKSPECS_DIR}/qconfig.pri")
 890     FILE(READ ${QT_MKSPECS_DIR}/qconfig.pri _qconfig_FILE_contents)
 891     STRING(REGEX MATCH "QT_CONFIG[^\n]+" QT_QCONFIG ${_qconfig_FILE_contents})
 892     STRING(REGEX MATCH "CONFIG[^\n]+" QT_CONFIG ${_qconfig_FILE_contents})
 893   endif()
 894
 895
 896   ###############################################
 897   #
 898   #       configuration/system dependent settings
 899   #
 900   ###############################################
 901
 902   set(QT_GUI_LIB_DEPENDENCIES "")
 903   set(QT_CORE_LIB_DEPENDENCIES "")
 904
 905   # shared build needs -DQT_SHARED
 906   IF(NOT QT_CONFIG MATCHES "static")
 907     # warning currently only qconfig.pri on Windows potentially contains "static"
 908     # so QT_SHARED might not get defined properly on Mac/X11 (which seems harmless right now)
 909     # Trolltech said they'd consider exporting it for all platforms in future releases.
 910     set(QT_DEFINITIONS ${QT_DEFINITIONS} -DQT_SHARED)
 911   endif()
 912
 913   ## system png
 914   IF(QT_QCONFIG MATCHES "system-png")
 915     FIND_LIBRARY(QT_PNG_LIBRARY NAMES png)
 916     set(QT_GUI_LIB_DEPENDENCIES ${QT_GUI_LIB_DEPENDENCIES} ${QT_PNG_LIBRARY})
 917     MARK_AS_ADVANCED(QT_PNG_LIBRARY)
 918   endif()
 919
 920   # for X11, get X11 library directory
 921   IF(Q_WS_X11)
 922     QT_QUERY_QMAKE(QMAKE_LIBDIR_X11 "QMAKE_LIBDIR_X11")
 923   endif()
 924
 925   ## X11 SM
 926   IF(QT_QCONFIG MATCHES "x11sm")
 927     # ask qmake where the x11 libs are
 928     FIND_LIBRARY(QT_X11_SM_LIBRARY NAMES SM PATHS ${QMAKE_LIBDIR_X11})
 929     FIND_LIBRARY(QT_X11_ICE_LIBRARY NAMES ICE PATHS ${QMAKE_LIBDIR_X11})
 930     set(QT_GUI_LIB_DEPENDENCIES ${QT_GUI_LIB_DEPENDENCIES} ${QT_X11_SM_LIBRARY} ${QT_X11_ICE_LIBRARY})
 931     MARK_AS_ADVANCED(QT_X11_SM_LIBRARY)
 932     MARK_AS_ADVANCED(QT_X11_ICE_LIBRARY)
 933   endif()
 934
 935   ## Xi
 936   IF(QT_QCONFIG MATCHES "tablet")
 937     FIND_LIBRARY(QT_XI_LIBRARY NAMES Xi PATHS ${QMAKE_LIBDIR_X11})
 938     set(QT_GUI_LIB_DEPENDENCIES ${QT_GUI_LIB_DEPENDENCIES} ${QT_XI_LIBRARY})
 939     MARK_AS_ADVANCED(QT_XI_LIBRARY)
 940   endif()
 941
 942   ## Xrender
 943   IF(QT_QCONFIG MATCHES "xrender")
 944     FIND_LIBRARY(QT_XRENDER_LIBRARY NAMES Xrender PATHS ${QMAKE_LIBDIR_X11})
 945     set(QT_GUI_LIB_DEPENDENCIES ${QT_GUI_LIB_DEPENDENCIES} ${QT_XRENDER_LIBRARY})
 946     MARK_AS_ADVANCED(QT_XRENDER_LIBRARY)
 947   endif()
 948
 949   ## Xrandr
 950   IF(QT_QCONFIG MATCHES "xrandr")
 951     FIND_LIBRARY(QT_XRANDR_LIBRARY NAMES Xrandr PATHS ${QMAKE_LIBDIR_X11})
 952     set(QT_GUI_LIB_DEPENDENCIES ${QT_GUI_LIB_DEPENDENCIES} ${QT_XRANDR_LIBRARY})
 953     MARK_AS_ADVANCED(QT_XRANDR_LIBRARY)
 954   endif()
 955
 956   ## Xcursor
 957   IF(QT_QCONFIG MATCHES "xcursor")
 958     FIND_LIBRARY(QT_XCURSOR_LIBRARY NAMES Xcursor PATHS ${QMAKE_LIBDIR_X11})
 959     set(QT_GUI_LIB_DEPENDENCIES ${QT_GUI_LIB_DEPENDENCIES} ${QT_XCURSOR_LIBRARY})
 960     MARK_AS_ADVANCED(QT_XCURSOR_LIBRARY)
 961   endif()
 962
 963   ## Xinerama
 964   IF(QT_QCONFIG MATCHES "xinerama")
 965     FIND_LIBRARY(QT_XINERAMA_LIBRARY NAMES Xinerama PATHS ${QMAKE_LIBDIR_X11})
 966     set(QT_GUI_LIB_DEPENDENCIES ${QT_GUI_LIB_DEPENDENCIES} ${QT_XINERAMA_LIBRARY})
 967     MARK_AS_ADVANCED(QT_XINERAMA_LIBRARY)
 968   endif()
 969
 970   ## system-freetype
 971   IF(QT_QCONFIG MATCHES "system-freetype")
 972     FIND_LIBRARY(QT_FREETYPE_LIBRARY NAMES freetype)
 973     set(QT_GUI_LIB_DEPENDENCIES ${QT_GUI_LIB_DEPENDENCIES} ${QT_FREETYPE_LIBRARY})
 974     MARK_AS_ADVANCED(QT_FREETYPE_LIBRARY)
 975   endif()
 976
 977   ## fontconfig
 978   IF(QT_QCONFIG MATCHES "fontconfig")
 979     FIND_LIBRARY(QT_FONTCONFIG_LIBRARY NAMES fontconfig)
 980     set(QT_GUI_LIB_DEPENDENCIES ${QT_GUI_LIB_DEPENDENCIES} ${QT_FONTCONFIG_LIBRARY})
 981     MARK_AS_ADVANCED(QT_FONTCONFIG_LIBRARY)
 982   endif()
 983
 984   ## system-zlib
 985   IF(QT_QCONFIG MATCHES "system-zlib")
 986     FIND_LIBRARY(QT_ZLIB_LIBRARY NAMES z)
 987     set(QT_CORE_LIB_DEPENDENCIES ${QT_CORE_LIB_DEPENDENCIES} ${QT_ZLIB_LIBRARY})
 988     MARK_AS_ADVANCED(QT_ZLIB_LIBRARY)
 989   endif()
 990
 991   IF(Q_WS_X11)
 992     # X11 libraries Qt absolutely depends on
 993     QT_QUERY_QMAKE(QT_LIBS_X11 "QMAKE_LIBS_X11")
 994     SEPARATE_ARGUMENTS(QT_LIBS_X11)
 995     FOREACH(QT_X11_LIB ${QT_LIBS_X11})
 996       STRING(REGEX REPLACE "-l" "" QT_X11_LIB "${QT_X11_LIB}")
 997       set(QT_TMP_STR "QT_X11_${QT_X11_LIB}_LIBRARY")
 998       FIND_LIBRARY(${QT_TMP_STR} NAMES "${QT_X11_LIB}" PATHS ${QMAKE_LIBDIR_X11})
 999       set(QT_GUI_LIB_DEPENDENCIES ${QT_GUI_LIB_DEPENDENCIES} ${${QT_TMP_STR}})
1000     ENDFOREACH(QT_X11_LIB)
1001
1002     QT_QUERY_QMAKE(QT_LIBS_THREAD "QMAKE_LIBS_THREAD")
1003     set(QT_CORE_LIB_DEPENDENCIES ${QT_CORE_LIB_DEPENDENCIES} ${QT_LIBS_THREAD})
1004
1005     QT_QUERY_QMAKE(QMAKE_LIBS_DYNLOAD "QMAKE_LIBS_DYNLOAD")
1006     set(QT_CORE_LIB_DEPENDENCIES ${QT_CORE_LIB_DEPENDENCIES} ${QMAKE_LIBS_DYNLOAD})
1007
1008   endif()
1009
1010   IF(Q_WS_WIN)
1011     set(QT_GUI_LIB_DEPENDENCIES ${QT_GUI_LIB_DEPENDENCIES} Imm32 Winmm)
1012     set(QT_CORE_LIB_DEPENDENCIES ${QT_CORE_LIB_DEPENDENCIES} Ws2_32)
1013   endif()
1014
1015   IF(Q_WS_MAC)
1016     set(QT_GUI_LIB_DEPENDENCIES ${QT_GUI_LIB_DEPENDENCIES} "-framework Carbon" "-framework QuickTime")
1017     set(QT_CORE_LIB_DEPENDENCIES ${QT_CORE_LIB_DEPENDENCIES} "-framework ApplicationServices")
1018   endif()
1019
1020   #######################################
1021   #
1022   #       compatibility settings
1023   #
1024   #######################################
1025   # Backwards compatibility for CMake1.4 and 1.2
1026   set(QT_MOC_EXE ${QT_MOC_EXECUTABLE} )
1027   set(QT_UIC_EXE ${QT_UIC_EXECUTABLE} )
1028
1029   set( QT_QT_LIBRARY "")
1030
1031 else()
1032
1033   IF(Qt4_FIND_REQUIRED)
1034     IF(QT4_INSTALLED_VERSION_TOO_OLD)
1035       message(FATAL_ERROR "The installed Qt version ${QTVERSION} is too old, at least version ${QT_MIN_VERSION} is required")
1036     else()
1037       message( FATAL_ERROR "Qt qmake not found!")
1038     endif()
1039   else()
1040     IF(QT4_INSTALLED_VERSION_TOO_OLD AND NOT Qt4_FIND_QUIETLY)
1041       message(STATUS "The installed Qt version ${QTVERSION} is too old, at least version ${QT_MIN_VERSION} is required")
1042     endif()
1043   endif()
1044
1045 endif()
1046