development/cmake/modules/FindLyXGettext.cmake

   1 # - Slightly modified Find GNU gettext tools
   2 # This module looks for the GNU gettext tools. This module defines the
   3 # following values:
   4 #  GETTEXT_MSGMERGE_EXECUTABLE: the full path to the msgmerge tool.
   5 #  GETTEXT_MSGFMT_EXECUTABLE: the full path to the msgfmt tool.
   6 #  GETTEXT_FOUND: True if gettext has been found.
   7 #
   8 # Additionally it provides the following macros:
   9 # GETTEXT_CREATE_TRANSLATIONS ( outputFile [ALL] file1 ... fileN )
  10 #    This will create a target "translations" which will convert the
  11 #    given input po files into the binary output mo file. If the
  12 #    ALL option is used, the translations will also be created when
  13 #    building the default target.
  14
  15 set(hints HINTS "${GNUWIN32_DIR}/gettext-tools")
  16 FIND_PROGRAM(GETTEXT_MSGMERGE_EXECUTABLE msgmerge ${hints})
  17 FIND_PROGRAM(GETTEXT_MSGFMT_EXECUTABLE   msgfmt   ${hints})
  18 FIND_PROGRAM(GETTEXT_XGETTEXT_EXECUTABLE xgettext ${hints})
  19 FIND_PROGRAM(GETTEXT_MSGUNIQ_EXECUTABLE  msguniq  ${hints})
  20
  21 MACRO(GETTEXT_CREATE_TRANSLATIONS _potFile _firstPoFile)
  22
  23    SET(_gmoFiles)
  24    # remove only the last extension e.g
  25    #    LyX2.0.pot ==> LyX2.0
  26    # and not LyX2.0.pot ==> LyX2
  27    # as it would be with NAME_WE
  28    # GET_FILENAME_COMPONENT(_potBasename ${_potFile} NAME_WE)
  29    GET_FILENAME_COMPONENT(_potname ${_potFile} NAME)
  30    if (_potname MATCHES "^\(.+\)\\.[^\\.]+$")
  31        set(_potBasename ${CMAKE_MATCH_1})
  32    else()
  33        set(_potBasename ${_potname})
  34    endif()
  35    GET_FILENAME_COMPONENT(_absPotFile ${_potFile} ABSOLUTE)
  36
  37    SET(_addToAll)
  38    set(_firstArg)
  39    IF(${_firstPoFile} STREQUAL "ALL")
  40       SET(_addToAll "ALL")
  41    else()
  42       set(_firstArg ${_firstPoFile})
  43    ENDIF(${_firstPoFile} STREQUAL "ALL")
  44
  45    FOREACH (_currentPoFile ${_firstArg} ${ARGN})
  46       GET_FILENAME_COMPONENT(_absFile ${_currentPoFile} ABSOLUTE)
  47       GET_FILENAME_COMPONENT(_abs_PATH ${_absFile} PATH)
  48       GET_FILENAME_COMPONENT(_lang ${_absFile} NAME_WE)
  49       SET(_gmoFile ${CMAKE_CURRENT_BINARY_DIR}/${_lang}.gmo)
  50
  51       ADD_CUSTOM_COMMAND(
  52          OUTPUT ${_gmoFile}
  53          COMMAND ${GETTEXT_MSGMERGE_EXECUTABLE} --quiet --update --backup=none ${_absFile} ${_absPotFile}
  54          COMMAND ${GETTEXT_MSGFMT_EXECUTABLE} -c --statistics -o ${_gmoFile}.1 ${_absFile}
  55          COMMAND ${CMAKE_COMMAND} -E rename ${_gmoFile}.1 ${_gmoFile}
  56          DEPENDS ${_absPotFile} ${_absFile}
  57       )
  58
  59       INSTALL(FILES ${_gmoFile} DESTINATION ${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${_potBasename}.mo)
  60       SET(_gmoFiles ${_gmoFiles} ${_gmoFile})
  61
  62    ENDFOREACH (_currentPoFile )
  63
  64    ADD_CUSTOM_TARGET(translations ${_addToAll} DEPENDS ${_gmoFiles})
  65    set_target_properties(translations PROPERTIES FOLDER "i18n")
  66
  67 ENDMACRO(GETTEXT_CREATE_TRANSLATIONS )
  68
  69 IF (GETTEXT_MSGMERGE_EXECUTABLE AND GETTEXT_MSGFMT_EXECUTABLE )
  70    SET(GETTEXT_FOUND TRUE)
  71 ELSE (GETTEXT_MSGMERGE_EXECUTABLE AND GETTEXT_MSGFMT_EXECUTABLE )
  72    SET(GETTEXT_FOUND FALSE)
  73    IF (GetText_REQUIRED)
  74       MESSAGE(FATAL_ERROR "GetText not found")
  75    ENDIF (GetText_REQUIRED)
  76 ENDIF (GETTEXT_MSGMERGE_EXECUTABLE AND GETTEXT_MSGFMT_EXECUTABLE )
  77
  78 mark_as_advanced(GETTEXT_MSGMERGE_EXECUTABLE GETTEXT_MSGFMT_EXECUTABLE GETTEXT_XGETTEXT_EXECUTABLE GETTEXT_MSGUNIQ_EXECUTABLE)
  79