development/cmake/modules/FindLyXGettext.cmake

   1 # - Slightly modified Find GNU gettext tools
   2 # This module looks for the GNU gettext tools. This module defines the
   3 # following values:
   4 #  GETTEXT_MSGMERGE_EXECUTABLE: the full path to the msgmerge tool.
   5 #  GETTEXT_MSGFMT_EXECUTABLE: the full path to the msgfmt tool.
   6 #  GETTEXT_FOUND: True if gettext has been found.
   7 #
   8 # Additionally it provides the following macros:
   9 # GETTEXT_CREATE_TRANSLATIONS ( outputFile [ALL] file1 ... fileN )
  10 #    This will create a target "translations" which will convert the
  11 #    given input po files into the binary output mo file. If the
  12 #    ALL option is used, the translations will also be created when
  13 #    building the default target.
  14
  15 FIND_PROGRAM(GETTEXT_MSGMERGE_EXECUTABLE msgmerge)
  16
  17 FIND_PROGRAM(GETTEXT_MSGFMT_EXECUTABLE msgfmt)
  18
  19 MACRO(GETTEXT_CREATE_TRANSLATIONS _potFile _firstPoFile)
  20
  21    SET(_gmoFiles)
  22    # remove only the last extension e.g
  23    #    LyX2.0.pot ==> LyX2.0
  24    # and not LyX2.0.pot ==> LyX2
  25    # as it would be with NAME_WE
  26    # GET_FILENAME_COMPONENT(_potBasename ${_potFile} NAME_WE)
  27    GET_FILENAME_COMPONENT(_potname ${_potFile} NAME)
  28    if (_potname MATCHES "^\(.+\)\\.[^\\.]+$")
  29        set(_potBasename ${CMAKE_MATCH_1})
  30    else()
  31        set(_potBasename ${_potname})
  32    endif()
  33    GET_FILENAME_COMPONENT(_absPotFile ${_potFile} ABSOLUTE)
  34
  35    SET(_addToAll)
  36    IF(${_firstPoFile} STREQUAL "ALL")
  37       SET(_addToAll "ALL")
  38       SET(_firstPoFile)
  39    ENDIF(${_firstPoFile} STREQUAL "ALL")
  40
  41    FOREACH (_currentPoFile ${ARGN})
  42       GET_FILENAME_COMPONENT(_absFile ${_currentPoFile} ABSOLUTE)
  43       GET_FILENAME_COMPONENT(_abs_PATH ${_absFile} PATH)
  44       GET_FILENAME_COMPONENT(_lang ${_absFile} NAME_WE)
  45       SET(_gmoFile ${CMAKE_CURRENT_BINARY_DIR}/${_lang}.gmo)
  46
  47       ADD_CUSTOM_COMMAND(
  48          OUTPUT ${_gmoFile}
  49          COMMAND ${GETTEXT_MSGMERGE_EXECUTABLE} --quiet --update --backup=none -s ${_absFile} ${_absPotFile}
  50          COMMAND ${GETTEXT_MSGFMT_EXECUTABLE} -o ${_gmoFile} ${_absFile}
  51          DEPENDS ${_absPotFile} ${_absFile}
  52       )
  53
  54       INSTALL(FILES ${_gmoFile} DESTINATION ${LYX_LOCALEDIR}/${_lang}/LC_MESSAGES RENAME ${_potBasename}.mo)
  55       SET(_gmoFiles ${_gmoFiles} ${_gmoFile})
  56
  57    ENDFOREACH (_currentPoFile )
  58
  59    ADD_CUSTOM_TARGET(translations ${_addToAll} DEPENDS ${_gmoFiles})
  60
  61 ENDMACRO(GETTEXT_CREATE_TRANSLATIONS )
  62
  63 IF (GETTEXT_MSGMERGE_EXECUTABLE AND GETTEXT_MSGFMT_EXECUTABLE )
  64    SET(GETTEXT_FOUND TRUE)
  65 ELSE (GETTEXT_MSGMERGE_EXECUTABLE AND GETTEXT_MSGFMT_EXECUTABLE )
  66    SET(GETTEXT_FOUND FALSE)
  67    IF (GetText_REQUIRED)
  68       MESSAGE(FATAL_ERROR "GetText not found")
  69    ENDIF (GetText_REQUIRED)
  70 ENDIF (GETTEXT_MSGMERGE_EXECUTABLE AND GETTEXT_MSGFMT_EXECUTABLE )
  71
  72
  73