development/cmake/modules/FindCXX11Compiler.cmake

   1 # This file is part of lyx.
   2 #
   3 # The module comes from the enblend project, slightly modified.
   4 #
   5 # Check if compiler supports C++11 features
   6 # and which compiler switches are necessary
   7 # CXX11_FLAG : contains the necessary compiler flag
   8
   9 #
  10 # Copyright (c) 2013 Thomas Modes <tmodes@@users.sourceforge.net>
  11 #
  12 #  Redistribution and use in source and binary forms, with or without
  13 #  modification, are permitted provided that the following conditions
  14 #  are met:
  15 #
  16 #  1. Redistributions of source code must retain the copyright
  17 #         notice, this list of conditions and the following disclaimer.
  18 #  2. Redistributions in binary form must reproduce the copyright
  19 #         notice, this list of conditions and the following disclaimer in the
  20 #         documentation and/or other materials provided with the distribution.
  21 #  3. The name of the author may not be used to endorse or promote products
  22 #         derived from this software without specific prior written permission.
  23 #
  24 # This file is distributed in the hope that it will be useful,
  25 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  26 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  27 # GNU General Public License for more details.
  28 #
  29 # You should have received a copy of the GNU General Public License
  30 # along with lyx; if not, write to the Free Software
  31 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  32 #
  33
  34 INCLUDE(CheckCXXSourceCompiles)
  35 INCLUDE(FindPackageHandleStandardArgs)
  36
  37 if (CMAKE_CXX_COMPILER_ID MATCHES "^[cC]lang$")
  38   set(CXX11_FLAG_CANDIDATES "--std=c++11 -Wno-deprecated-register")
  39 else()
  40   if (CYGWIN)
  41     set(CXX11_FLAG_CANDIDATES "--std=gnu++11")
  42   else()
  43     if (MSVC)
  44       # MSVC does not have a general C++11 flag, one can only switch off
  45       # MS extensions with /Za in general or by extension with /Zc.
  46       # Use an empty flag to ensure that CXX11_STD_REGEX is correctly set.
  47       set(CXX11_FLAG_CANDIDATES "noflagneeded")
  48     else()
  49       set(CXX11_FLAG_CANDIDATES
  50         "--std=c++14"
  51         "--std=c++11"
  52         "--std=gnu++11"
  53         "--std=gnu++0x"
  54       )
  55     endif()
  56   endif()
  57 endif()
  58
  59 # sample openmp source code to test
  60 SET(CXX11_TEST_SOURCE
  61 "
  62 template <typename T>
  63 struct check
  64 {
  65     static_assert(sizeof(int) <= sizeof(T), \"not big enough\");
  66 };
  67
  68 typedef check<check<bool>> right_angle_brackets;
  69
  70 class TestDeleted
  71 {
  72 public:
  73     TestDeleted() = delete;
  74 };
  75
  76
  77 int a;
  78 decltype(a) b;
  79
  80 typedef check<int> check_type;
  81 check_type c;
  82 check_type&& cr = static_cast<check_type&&>(c);
  83
  84 auto d = a;
  85
  86 int main() {
  87   return 0;
  88 };
  89 ")
  90
  91 # The following code snipped taken from example in http://stackoverflow.com/questions/8561850/compile-stdregex-iterator-with-gcc
  92 set(REGEX_TEST_SOURCE
  93 "
  94 #include <regex>
  95 #include <iostream>
  96
  97 #include <string.h>
  98
  99 typedef std::regex_iterator<const char *> Myiter;
 100 int main()
 101 {
 102     const char *pat = \"axayaz\";
 103     Myiter::regex_type rx(\"a\");
 104     Myiter next(pat, pat + strlen(pat), rx);
 105     Myiter end;
 106
 107     return (0);
 108 }
 109 ")
 110
 111 # check c compiler
 112 set(SAFE_CMAKE_REQUIRED_QUIET ${CMAKE_REQUIRED_QUIET})
 113 set(CMAKE_REQUIRED_QUIET ON)
 114 SET(SAFE_CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 115 FOREACH(FLAG ${CXX11_FLAG_CANDIDATES})
 116   IF(NOT "${FLAG}" STREQUAL "noflagneeded")
 117     SET(CMAKE_REQUIRED_FLAGS "${FLAG}")
 118   ENDIF()
 119   UNSET(CXX11_FLAG_DETECTED CACHE)
 120   CHECK_CXX_SOURCE_COMPILES("${CXX11_TEST_SOURCE}" CXX11_FLAG_DETECTED)
 121   IF(CXX11_FLAG_DETECTED)
 122     SET(CXX11_FLAG "${FLAG}")
 123     message(STATUS "CXX11_FLAG_DETECTED = \"${FLAG}\"")
 124     set(LYX_USE_CXX11 1)
 125       check_cxx_source_compiles("${REGEX_TEST_SOURCE}" CXX_STD_REGEX_DETECTED)
 126       if (CXX_STD_REGEX_DETECTED)
 127         message(STATUS "Compiler supports std_regex")
 128         set(CXX11_STD_REGEX ON)
 129       else()
 130         message(STATUS "Compiler does not support std_regex")
 131         set(CXX11_STD_REGEX OFF)
 132       endif()
 133     break()
 134   ENDIF()
 135 ENDFOREACH()
 136 SET(CMAKE_REQUIRED_FLAGS "${SAFE_CMAKE_REQUIRED_FLAGS}")
 137 set(CMAKE_REQUIRED_QUIET ${SAFE_CMAKE_REQUIRED_QUIET})
 138
 139 # handle the standard arguments for find_package
 140 FIND_PACKAGE_HANDLE_STANDARD_ARGS(CXX11Compiler DEFAULT_MSG CXX11_FLAG)
 141 IF("${CXX11_FLAG}" STREQUAL "noflagneeded")
 142   SET(CXX11_FLAG "")
 143 ENDIF()
 144
 145 MARK_AS_ADVANCED(CXX11_FLAG CXX11_STD_REGEX)