development/cmake/doc/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2008-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6 #
   7
   8 project(doc)
   9
  10 SET(_docs)
  11 file(GLOB_RECURSE _rel_lyx_docs RELATIVE "${TOP_SRC_DIR}/lib/doc" "${TOP_SRC_DIR}/lib/doc/*.lyx" "${TOP_SRC_DIR}/lib/doc/*.txt")
  12 list(REMOVE_ITEM _rel_lyx_docs LFUNs.lyx)
  13
  14 foreach(_rel_doc ${_rel_lyx_docs})
  15   if ("${_rel_doc}" MATCHES "/" )
  16     string(REGEX REPLACE "/[^/]*$" "" _rel_dir_part ${_rel_doc})
  17   else("${_rel_doc}" MATCHES "/")
  18     set(_rel_dir_part ".")
  19   endif("${_rel_doc}" MATCHES "/")
  20   set(_created_doc "${CMAKE_CURRENT_BINARY_DIR}/${_rel_doc}")
  21   get_filename_component(_doc_dir ${_created_doc} PATH)
  22   file(MAKE_DIRECTORY ${_doc_dir})
  23   #message("found relative file " ${_rel_doc})
  24   #message("input ${TOP_SRC_DIR}/lib/doc/${_rel_doc}")
  25   #message("output ${_created_doc}")
  26   #message("rel_dir_part ${_rel_dir_part}")
  27   SET_SOURCE_FILES_PROPERTIES(${_created_doc} GENERATED)
  28   add_custom_command(
  29     OUTPUT "${_created_doc}"
  30     COMMAND ${LYX_PYTHON_EXECUTABLE} "${TOP_CMAKE_PATH}/doc/ReplaceValues.py" "LYX_USERDIR_VER=${LYX_USERDIR_VER}" "LYX_DIR_VER=${LYX_DIR_VER}" "${TOP_SRC_DIR}/lib/doc/${_rel_doc}" > "${_created_doc}"
  31     DEPENDS "${TOP_SRC_DIR}/lib/doc/${_rel_doc}" "${TOP_CMAKE_PATH}/doc/ReplaceValues.py"
  32     )
  33   install(FILES "${CMAKE_CURRENT_BINARY_DIR}/${_rel_doc}" DESTINATION "${LYX_DATA_SUBDIR}doc/${_rel_dir_part}")
  34   LIST(APPEND _docs "${_created_doc}")
  35 endforeach(_rel_doc)
  36
  37 # Special commands to create and install LFUNs.lyx
  38 add_custom_command(
  39   OUTPUT LFUNs.lyx
  40   COMMAND ${LYX_PYTHON_EXECUTABLE} "${TOP_SRC_DIR}/development/tools/gen_lfuns.py" "${TOP_SRC_DIR}/src/LyXAction.cpp" > LFUNs.lyx
  41   DEPENDS "${TOP_SRC_DIR}/development/tools/gen_lfuns.py" "${TOP_SRC_DIR}/src/LyXAction.cpp")
  42 LIST(APPEND _docs "${CMAKE_CURRENT_BINARY_DIR}/LFUNs.lyx")
  43 install(FILES "${CMAKE_CURRENT_BINARY_DIR}/LFUNs.lyx" DESTINATION "${LYX_DATA_SUBDIR}doc")
  44
  45 ADD_CUSTOM_TARGET(doc ALL DEPENDS ${_docs})
  46
  47 ADD_CUSTOM_TARGET(lfundoc DEPENDS LFUNs.lyx)