development/cmake/doc/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2008-2011 Peter Kümmel, <syntheticpp@gmx.net>
   5 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   6 #
   7
   8 project(doc)
   9
  10 SET(_docs)
  11 file(GLOB_RECURSE _rel_lyx_docs RELATIVE "${TOP_SRC_DIR}/lib/doc"
  12                         "${TOP_SRC_DIR}/lib/doc/*.lyx"
  13                         "${TOP_SRC_DIR}/lib/doc/*.txt"
  14                         "${TOP_SRC_DIR}/lib/doc/*.tex")
  15 list(REMOVE_ITEM _rel_lyx_docs LFUNs.lyx)
  16
  17 foreach(_rel_doc ${_rel_lyx_docs})
  18   if (NOT "${_rel_doc}" MATCHES "#" )
  19     if ("${_rel_doc}" MATCHES "/" )
  20       string(REGEX REPLACE "/[^/]*$" "" _rel_dir_part ${_rel_doc})
  21     else("${_rel_doc}" MATCHES "/")
  22       set(_rel_dir_part ".")
  23     endif("${_rel_doc}" MATCHES "/")
  24     set(_created_doc "${CMAKE_CURRENT_BINARY_DIR}/${_rel_doc}")
  25     get_filename_component(_doc_dir ${_created_doc} PATH)
  26     file(MAKE_DIRECTORY ${_doc_dir})
  27     #message(STATUS "found relative file " ${_rel_doc})
  28     #message(STATUS "input ${TOP_SRC_DIR}/lib/doc/${_rel_doc}")
  29     #message(STATUS "output ${_created_doc}")
  30     #message(STATUS "rel_dir_part ${_rel_dir_part}")
  31     SET_SOURCE_FILES_PROPERTIES(${_created_doc} GENERATED)
  32     add_custom_command(
  33       OUTPUT "${_created_doc}"
  34       COMMAND ${LYX_PYTHON_EXECUTABLE} "${TOP_CMAKE_PATH}/doc/ReplaceValues.py"
  35         "LYX_USERDIR_VER=${LYX_USERDIR_VER}"
  36         "LYX_DIR_VER=${LYX_DIR_VER}"
  37         "\\origin\ unavailable=\\origin\ /systemlyxdir/doc/${_rel_dir_part}"
  38         "${TOP_SRC_DIR}/lib/doc/${_rel_doc}" > "${_created_doc}"
  39       DEPENDS "${TOP_SRC_DIR}/lib/doc/${_rel_doc}" "${TOP_CMAKE_PATH}/doc/ReplaceValues.py"
  40       )
  41     install(FILES "${CMAKE_CURRENT_BINARY_DIR}/${_rel_doc}" DESTINATION "${LYX_DATA_SUBDIR}doc/${_rel_dir_part}")
  42     LIST(APPEND _docs "${_created_doc}")
  43   endif()
  44 endforeach(_rel_doc)
  45
  46 # Special commands to create and install LFUNs.lyx
  47 add_custom_command(
  48   OUTPUT LFUNs.lyx
  49   COMMAND ${LYX_PYTHON_EXECUTABLE} "${TOP_SRC_DIR}/development/tools/gen_lfuns.py" "${TOP_SRC_DIR}/src/LyXAction.cpp" > LFUNs.lyx
  50   DEPENDS "${TOP_SRC_DIR}/development/tools/gen_lfuns.py" "${TOP_SRC_DIR}/src/LyXAction.cpp")
  51 LIST(APPEND _docs "${CMAKE_CURRENT_BINARY_DIR}/LFUNs.lyx")
  52 install(FILES "${CMAKE_CURRENT_BINARY_DIR}/LFUNs.lyx" DESTINATION "${LYX_DATA_SUBDIR}doc")
  53
  54 ADD_CUSTOM_TARGET(doc ALL DEPENDS ${_docs})
  55
  56 ADD_CUSTOM_TARGET(lfundoc DEPENDS LFUNs.lyx)
  57
  58 set_target_properties(doc lfundoc PROPERTIES FOLDER "doc")
  59