development/cmake/LyxPackaging.cmake

   1
   2 # CPack packaging
   3 #
   4 # http://cmake.org/cmake/help/cmake-2-8-docs.html#module:CPack
   5
   6 if(LYX_BUNDLE)
   7         if(APPLE)
   8                 set(CPACK_GENERATOR DragNDrop)
   9         elseif(UNIX)
  10                 set(CPACK_GENERATOR STGZ)
  11         elseif(WIN32)
  12                 set(CPACK_GENERATOR ZIP)
  13         endif()
  14 endif()
  15
  16 # Overwrite package name dependent on platform
  17 # (Ignores the top project)
  18 if(APPLE)
  19         # true on all systems whre __APPLE__ is defined in header files
  20         set(CPACK_PACKAGE_NAME LyX)
  21 elseif(UNIX)
  22         # True also for cygwin
  23         set(CPACK_PACKAGE_NAME lyx)
  24 else()
  25         set(CPACK_PACKAGE_NAME LyX)
  26 endif()
  27
  28 set(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
  29 set(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
  30 FILE(STRINGS "${TOP_CMAKE_PATH}/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
  31
  32
  33 set(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
  34
  35 #
  36 # needed by rpm
  37 set(CPACK_SET_DESTDIR "ON")
  38 FILE(READ "${TOP_CMAKE_PATH}/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
  39 set(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
  40 set(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
  41 #
  42 # the next ones are needed by deb
  43 set(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
  44 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
  45
  46 # We depend on python scripting
  47 set(CPACK_DEBIAN_PACKAGE_DEPENDS "python (>= 2.6)")
  48
  49 # use dpkg-shlibdeps to generate additional info for package dependency list.
  50 set(CPACK_DEBIAN_PACKAGE_SHLIBDEPS ON)
  51
  52 #
  53 # for the next ones, cpack insists on data with values in some file
  54 set(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_CMAKE_PATH}/LyX_description.txt")
  55 set(CPACK_RESOURCE_FILE_LICENSE "${TOP_CMAKE_PATH}/LyX_license.txt")
  56
  57 # Use the revision number saved in ${LYX_PACKAGE_RELEASE}
  58 # as the release in rpm-package-build.
  59 # This way we maycan omit the otherwise needed "--force" parameter when
  60 # installing from that rpm package.
  61 set(CPACK_RPM_PACKAGE_RELEASE ${LYX_PACKAGE_RELEASE})
  62 set(CPACK_PACKAGE_VERSION_PATCH ${LYX_REVISION_VERSION})
  63
  64 # we do not have a readme or welcome data,
  65 # so we do not provide infofiles for
  66 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
  67
  68 # sources
  69 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
  70
  71
  72 set(CPACK_STRIP_FILES 1)
  73
  74 # Finaly give some hints about files not to be included in source package
  75 SET(CPACK_SOURCE_IGNORE_FILES
  76 "/CVS/"
  77 "/\\\\.svn/"
  78 "/\\\\.bzr/"
  79 "/\\\\.hg/"
  80 "/\\\\.git/"
  81 "/\\\\.project$"
  82 "/\\\\.cproject$"
  83 "/\\\\.history$"
  84 "\\\\.#"
  85 "\\\\.swp$"
  86 "~$"
  87 "/#"
  88 "/_CPack_Packages/"
  89 "/CMakeCache.txt$"
  90 "/CPackSourceConfig\\\\.cmake$"
  91 "/configCompiler\\\\.h$"
  92 "/install_manifest\\\\.txt$"
  93 "/cmake_install\\\\.cmake$"
  94 "/POTFILES"
  95 "\\\\.tar\\\\.gz$"
  96 "\\\\.tar\\\\.bz2$"
  97 "\\\\.tar\\\\.Z$"
  98 "\\\\.deb$"
  99 "\\\\.rpm$"
 100 "\\\\.rej$"
 101 "\\\\.orig$"
 102 "/core$"
 103 "/CMakeFiles/"
 104 "/Makefile\\\\.in$"
 105 "/Makefile$"
 106 "/autom4te\\\\.cache/"
 107 "/\\\\.deps/"
 108 "/build/"
 109 "/lyx-2\\\\."
 110 )
 111
 112 if(LYX_CPACK)
 113         include(CPack)
 114 endif()
 115
 116
 117 #Now it is possible to create some packages
 118 # cd <BuildDir>
 119 # make package
 120 #############################################################################################
 121 # So, e.g. for variables
 122 #    CMAKE_PROJECT_NAME                     : lyx
 123 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 124 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 125 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 126 #    CMAKE_SYSTEM_NAME                      : Linux
 127 #    CPACK_BINARY_DEB:BOOL                  : ON
 128 #
 129 # the package name builds as "lyx-2.0.1-Linux.deb"
 130 #
 131 ############################## rpm ################################### deb ##################
 132 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 133 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 134 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 135 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 136 #
 137