development/cmake/Install.cmake

   1
   2 # TODO: set correct path in call to cmake
   3 # e.g. cmake /usr/src/lyx/lyx-devel/development/cmake -DCMAKE_INSTALL_PREFIX=/usr/local/share/lyx2.0 -Dnls=1
   4
   5 if(NOT(LYX_BUNDLE) AND APPLE)
   6         message(STATUS "Installing to ${CMAKE_INSTALL_PREFIX}, defined by CMAKE_INSTALL_PREFIX")
   7 endif()
   8
   9 # the macro scans the directories "_parent_src_dir/_dir/_current_dir" for *._file_type files
  10 # and installs the files in CMAKE_INSTALL_PREFIX/_current_dir
  11 # dir_item is on item of the remaining arguments
  12 macro(lyx_install _parent_src_dir _gl_dir _file_type)
  13   #message("checking parents ${_parent_src_dir}")
  14   file(GLOB _dirs RELATIVE "${_parent_src_dir}" ${_parent_src_dir}/${_gl_dir})
  15   #cmake bug on Windows: if _gl_dir==. _dirs is empty but on linux _dirs==.
  16   if(NOT _dirs)
  17     set(_dirs .)
  18   endif()
  19   foreach(_dir ${_dirs})
  20     foreach(_glob_dir ${ARGN})
  21       file(GLOB _dir_list ${_parent_src_dir}/${_dir}/${_glob_dir})
  22       if(NOT _dir_list)
  23         if(_glob_dir STREQUAL ".")
  24           set(_dir_list ${_parent_src_dir}/${_dir}/.)
  25         endif()
  26       endif()
  27       #message(STATUS "${_dir}/${_glob_dir} -> ${_dir_list} ")
  28       foreach(_current_dir ${_dir_list})
  29         file(GLOB _item_list ${_current_dir}/${_file_type})
  30         #cmake bug: globbing with * also returns directories on Windows
  31         set(files_list ${_item_list})
  32         set(program_list)
  33         foreach(_current_item ${_item_list})
  34           if(files_list)
  35             if(IS_DIRECTORY ${_current_item})
  36               #message(STATUS "removing dir ${_current_item}")
  37               list(REMOVE_ITEM files_list "${_current_item}")
  38             else()
  39               if(_current_item MATCHES "/\\.[^/]+$")
  40                 #message(STATUS "removing hidden ${_current_item}")
  41                 list(REMOVE_ITEM files_list "${_current_item}")
  42               endif()
  43               if(_current_item MATCHES "\\.in$")
  44                 #message(STATUS "removing .in file ${_current_item}")
  45                 list(REMOVE_ITEM files_list "${_current_item}")
  46               endif()
  47               if(_current_item MATCHES "\\.py$")
  48                 list(REMOVE_ITEM files_list "${_current_item}")
  49                 list(APPEND program_list "${_current_item}")
  50               endif()
  51             endif()
  52           endif()
  53         endforeach(_current_item)
  54         if(files_list)
  55           list(REMOVE_ITEM files_list "${_current_dir}/lyx.svg")
  56           list(REMOVE_ITEM files_list "${_current_dir}/Makefile.am")
  57           list(REMOVE_ITEM files_list "${_current_dir}/layouttranslations")
  58           GET_FILENAME_COMPONENT(_base_dir ${_current_dir} NAME)
  59           if(_glob_dir STREQUAL ".")
  60             set(_base_dir .)
  61           endif()
  62
  63           install(FILES ${files_list} DESTINATION "${LYX_DATA_SUBDIR}${_dir}/${_base_dir}")
  64         endif()
  65         if(program_list)
  66           if(_glob_dir STREQUAL ".")
  67             set(_base_dir .)
  68           endif()
  69     install(FILES ${program_list} DESTINATION "${LYX_DATA_SUBDIR}${_dir}/${_base_dir}")
  70         endif()
  71       endforeach(_current_dir)
  72     endforeach(_glob_dir)
  73   endforeach(_dir)
  74 endmacro(lyx_install)
  75
  76
  77 # language-specific-directories (like ca, de, es ...) are now globbed as "[a-z][a-z]"
  78 set(_all_languages "[a-z][a-z]")
  79
  80 lyx_install(${TOP_SRC_DIR}/lib bind         *.bind   . ${_all_languages})
  81 lyx_install(${TOP_SRC_DIR}/lib commands     *.def    .)
  82
  83 # this is handled in doc/CMakeLists.txt
  84 #lyx_install(${TOP_SRC_DIR}/lib doc          *.lyx    . ${_all_languages})
  85 #lyx_install(${TOP_SRC_DIR}/lib doc          *.txt    . ${_all_languages})
  86 lyx_install(${TOP_SRC_DIR}/lib doc          *      biblio clipart)
  87
  88 lyx_install(${TOP_SRC_DIR}/lib doc/${_all_languages} *    clipart)
  89
  90 lyx_install(${TOP_SRC_DIR}/lib examples     *      . ${_all_languages} springer thesis)
  91 lyx_install(${TOP_SRC_DIR}/lib fonts        *      .)
  92 lyx_install(${TOP_SRC_DIR}/lib images       *      . math ipa commands attic classic oxygen)
  93 lyx_install(${TOP_SRC_DIR}/lib images/svg   *      . math ipa oxygen)
  94 lyx_install(${TOP_SRC_DIR}/lib kbd          *      .)
  95 lyx_install(${TOP_SRC_DIR}/lib layouts      *      .)
  96 lyx_install(${TOP_SRC_DIR}/lib lyx2lyx      *.py   .)
  97 lyx_install(${TOP_SRC_DIR}/lib scripts      *.py   .)
  98 lyx_install(${TOP_SRC_DIR}/lib scripts      *.R    .)
  99 lyx_install(${TOP_SRC_DIR}/lib templates    *      . springer)
 100 lyx_install(${TOP_SRC_DIR}/lib tex          *      .)
 101 lyx_install(${TOP_SRC_DIR}/lib ui           *      .)
 102 lyx_install(${TOP_SRC_DIR}/lib .            *      .)
 103
 104 # Install
 105 if(APPLE)
 106   if(LYX_BUNDLE)
 107     install(FILES ${TOP_SRC_DIR}/development/MacOSX/spotlight/Info.plist DESTINATION "${MACOSX_BUNDLE_STARTUP_COMMAND}/Contents/Library/Spotlight/LyX-Metadata.mdimporter/Contents")
 108     install(FILES "${TOP_SRC_DIR}/development/MacOSX/PkgInfo" DESTINATION "${MACOSX_BUNDLE_STARTUP_COMMAND}/Contents")
 109   endif()
 110
 111   install(FILES "${TOP_SRC_DIR}/development/MacOSX/lyxeditor" DESTINATION "${LYX_UTILITIES_INSTALL_PATH}")
 112   install(FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.icns" DESTINATION "${LYX_DATA_SUBDIR}")
 113   set(program_suffix ${PROGRAM_SUFFIX})
 114 elseif(UNIX)
 115   set(program_suffix ${PROGRAM_SUFFIX})
 116   configure_file(${TOP_SRC_DIR}/lib/lyx.desktop.in lyx${PROGRAM_SUFFIX}.desktop)
 117   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/lyx${PROGRAM_SUFFIX}.desktop DESTINATION ${SYSTEM_DATADIR}/applications)
 118   install(FILES ${TOP_SRC_DIR}/lib/images/lyx.svg RENAME lyx${PROGRAM_SUFFIX}.svg DESTINATION ${SYSTEM_DATADIR}/icons/hicolor/scalable/apps/)
 119 endif()