development/cmake/Install.cmake

   1
   2 # TODO: set correct path in call to cmake
   3 # e.g. cmake /usr/src/lyx/lyx-devel/development/cmake -DCMAKE_INSTALL_PREFIX=/usr/local -Dnls=1
   4
   5 if(NOT(LYX_BUNDLE) AND APPLE)
   6         message(STATUS "Installing to ${CMAKE_INSTALL_PREFIX}, defined by CMAKE_INSTALL_PREFIX")
   7 endif()
   8
   9 # the macro scans the directories "_parent_src_dir/_dir/_current_dir" for *._file_type files
  10 # and installs the files in CMAKE_INSTALL_PREFIX/_current_dir
  11 # dir_item is on item of the remaining arguments
  12 #
  13 # Special handling for ${_file_type} == "*"
  14 #     Here we try to exclude files which we do not want to install
  15 # Depending on _what, installation on UNIX goes to
  16 # data -> ${LYX_DATA_SUBDIR}
  17 # font -> share/${_lyx}/fonts/
  18 # bin -> bin
  19 # tex -> share/texmf/tex/latex/${_lyx}/
  20 macro(lyx_install _what _parent_src_dir _gl_dir _file_type)
  21   #message("checking parents ${_parent_src_dir}")
  22   file(GLOB _dirs RELATIVE "${_parent_src_dir}" ${_parent_src_dir}/${_gl_dir})
  23   #cmake bug on Windows: if _gl_dir==. _dirs is empty but on linux _dirs==.
  24   if(NOT _dirs)
  25     set(_dirs .)
  26   endif()
  27   # Select installation dir
  28   if ("${_what}" STREQUAL "data")
  29     get_data_destination(_dest_subdir)
  30   elseif ("${_what}" STREQUAL "font")
  31     get_font_destination(_dest_subdir)
  32   elseif ("${_what}" STREQUAL "tex")
  33     get_tex_destination(_dest_subdir)
  34   else()
  35     message(FATAL_ERROR "Undefined parameter _what = ${_what} in call to lyx_install")
  36   endif()
  37   foreach(_dir ${_dirs})
  38     foreach(_glob_dir ${ARGN})
  39       file(GLOB _dir_list ${_parent_src_dir}/${_dir}/${_glob_dir})
  40       if(NOT _dir_list)
  41         if(_glob_dir STREQUAL ".")
  42           set(_dir_list ${_parent_src_dir}/${_dir}/.)
  43         endif()
  44       endif()
  45       #message(STATUS "${_dir}/${_glob_dir} -> ${_dir_list} ")
  46       foreach(_current_dir ${_dir_list})
  47         file(GLOB _item_list ${_current_dir}/${_file_type})
  48         #cmake bug: globbing with * also returns directories on Windows
  49         set(files_list ${_item_list})
  50         set(program_list)
  51         foreach(_current_item ${_item_list})
  52           if(files_list)
  53             if(IS_DIRECTORY ${_current_item})
  54               #message(STATUS "removing dir ${_current_item}")
  55               list(REMOVE_ITEM files_list "${_current_item}")
  56             else()
  57               if ("${_file_type}" STREQUAL "*")
  58                 foreach(_mask "/\\.[^/]+$" "\\.in$" "\\.py$" "\\.patch$" "CMakeLists\\.txt$" "\\.lyx~$")
  59                   if(_current_item MATCHES ${_mask})
  60                     #message(STATUS "removing item ${_current_item}")
  61                     list(REMOVE_ITEM files_list "${_current_item}")
  62                   endif()
  63                 endforeach()
  64               endif()
  65             endif()
  66           endif()
  67         endforeach(_current_item)
  68         if(files_list)
  69           list(REMOVE_ITEM files_list "${_current_dir}/lyx.svg")
  70           list(REMOVE_ITEM files_list "${_current_dir}/Makefile.am")
  71           list(REMOVE_ITEM files_list "${_current_dir}/layouttranslations")
  72           if (NOT WIN32)
  73             # subscript.sty is installed only for MikTeX since it is part of texlive
  74             list(REMOVE_ITEM files_list "${_current_dir}/subscript.sty")
  75           endif()
  76           GET_FILENAME_COMPONENT(_base_dir ${_current_dir} NAME)
  77           if(_glob_dir STREQUAL ".")
  78             set(_base_dir .)
  79           endif()
  80
  81           install(FILES ${files_list} DESTINATION "${_dest_subdir}${_dir}/${_base_dir}")
  82           #message(STATUS "Installing  ${files_list} to ${_dest_subdir}${_dir}/${_base_dir}")
  83         endif()
  84         if(program_list)
  85           if(_glob_dir STREQUAL ".")
  86             set(_base_dir .)
  87           endif()
  88           install(FILES ${program_list} DESTINATION "${_dest_subdir}${_dir}/${_base_dir}")
  89         endif()
  90       endforeach(_current_dir)
  91     endforeach(_glob_dir)
  92   endforeach(_dir)
  93 endmacro(lyx_install)
  94
  95
  96 # language-specific-directories (like ca, de, es ...) are now globbed as "[a-z][a-z]"
  97 set(_all_languages "[a-z][a-z]" "[a-z][a-z]_[A-Z][A-Z]")
  98
  99 lyx_install("data" ${TOP_SRC_DIR}/lib bind         *.bind   . ${_all_languages})
 100 lyx_install("data" ${TOP_SRC_DIR}/lib commands     *.def    .)
 101
 102 # this is handled in doc/CMakeLists.txt
 103 #lyx_install("data" ${TOP_SRC_DIR}/lib doc          *.lyx    . ${_all_languages})
 104 #lyx_install("data" ${TOP_SRC_DIR}/lib doc          *.txt    . ${_all_languages})
 105 lyx_install("data" ${TOP_SRC_DIR}/lib doc          *      biblio clipart)
 106
 107 foreach(_lang ${_all_languages})
 108   lyx_install("data" ${TOP_SRC_DIR}/lib doc/${_lang} *    clipart)
 109 endforeach()
 110
 111 foreach(_sd "examples" "templates")
 112   lyx_install("data" ${TOP_SRC_DIR}/lib ${_sd}     *    . *)
 113   lyx_install("data" ${TOP_SRC_DIR}/lib ${_sd}/*   *    . *)
 114 endforeach()
 115
 116 foreach(_sd "kbd" "layouts" "ui" ".")
 117   lyx_install("data" ${TOP_SRC_DIR}/lib ${_sd}     *    .  )
 118 endforeach()
 119
 120 foreach(_sd "lyx2lyx" "scripts" ".")
 121   lyx_install("data" ${TOP_SRC_DIR}/lib ${_sd}     *.py .  )
 122 endforeach()
 123
 124 foreach(_imgext "png" "svgz" "gif" "xpm")
 125   lyx_install("data" ${TOP_SRC_DIR}/lib images       "*.${_imgext}"      . ipa classic oxygen)
 126   lyx_install("data" ${TOP_SRC_DIR}/lib images/math  "*.${_imgext}"      . oxygen)
 127 endforeach()
 128 lyx_install("data" ${TOP_SRC_DIR}/lib        citeengines          *.citeengine .)
 129 lyx_install("data" ${TOP_SRC_DIR}/lib        scripts              *.R          .)
 130 lyx_install("data" ${TOP_SRC_DIR}/lib        xtemplates           *.xtemplate  .)
 131 lyx_install("data" ${TOP_SRC_DIR}/3rdparty   scripts/evince_sync  *            .)
 132 lyx_install("font" ${TOP_SRC_DIR}/lib/fonts  .                    *            .)
 133 lyx_install("tex"  ${TOP_SRC_DIR}/lib/tex    .                    *            .)
 134
 135 # Install
 136 set(lyxrcorig "")
 137 set(program_suffix ${PROGRAM_SUFFIX})
 138 set(version_suffix ${LYX_VERSION})
 139
 140 if(APPLE)
 141   if(LYX_BUNDLE)
 142     install(FILES ${TOP_SRC_DIR}/development/MacOSX/spotlight/Info.plist DESTINATION "${MACOSX_BUNDLE_STARTUP_COMMAND}/Contents/Library/Spotlight/LyX-Metadata.mdimporter/Contents")
 143     install(FILES "${TOP_SRC_DIR}/development/MacOSX/PkgInfo" DESTINATION "${MACOSX_BUNDLE_STARTUP_COMMAND}/Contents")
 144   endif()
 145
 146   foreach(_i lyxeditor maxima inkscape)
 147     install(PROGRAMS "${TOP_SRC_DIR}/development/MacOSX/${_i}" DESTINATION "${LYX_UTILITIES_INSTALL_PATH}")
 148   endforeach()
 149   install(FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.icns" DESTINATION "${LYX_DATA_SUBDIR}")
 150   set(lyxrcorig "${TOP_SRC_DIR}/development/MacOSX/lyxrc.dist.in")
 151 elseif(UNIX)
 152   configure_file(${TOP_SRC_DIR}/lib/lyx.desktop.in lyx${PROGRAM_SUFFIX}.desktop)
 153   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/lyx${PROGRAM_SUFFIX}.desktop DESTINATION ${SYSTEM_DATADIR}/applications)
 154   install(FILES ${TOP_SRC_DIR}/lib/images/lyx.svg RENAME lyx${PROGRAM_SUFFIX}.svg DESTINATION ${SYSTEM_DATADIR}/icons/hicolor/scalable/apps/)
 155   set(lyxrcorig "${TOP_SRC_DIR}/development/unix/lyxrc.dist.in")
 156 elseif(CYGWIN)
 157   set(lyxrcorig "${TOP_SRC_DIR}/development/cygwin/lyxrc.dist.in")
 158 elseif(WIN32)
 159   set(lyxrcorig "${TOP_SRC_DIR}/development/Win32/lyxrc.dist.in")
 160 endif()
 161
 162 if(NOT lyxrcorig STREQUAL "")
 163   configure_file("${lyxrcorig}" lyxrc.dist)
 164   lyx_install("data" ${CMAKE_CURRENT_BINARY_DIR} . lyxrc.dist .)
 165 endif()
 166
 167 if(USE_POSIX_PACKAGING AND EXISTS "${TOP_SRC_DIR}/lib/usr.bin.lyxwrap.in")
 168   # handle lyxwrap
 169   #get_filename_component(prefix "${CMAKE_INSTALL_PREFIX}" REALPATH)
 170   set(prefix "${CMAKE_INSTALL_PREFIX}")
 171   string(REGEX REPLACE "^/" "" lyxwrapprefix1 "${prefix}")
 172   string(REPLACE "/" "." lyxwrapprefix ${lyxwrapprefix1})
 173   #message(STATUS "lyxwrapprefix = ${lyxwrapprefix}")
 174   configure_file(${TOP_SRC_DIR}/lib/usr.bin.lyxwrap.in "${lyxwrapprefix}.${LYX_UTILITIES_INSTALL_PATH}.lyx${PROGRAM_SUFFIX}")
 175   install(FILES "${CMAKE_CURRENT_BINARY_DIR}/${lyxwrapprefix}.${LYX_UTILITIES_INSTALL_PATH}.lyx${PROGRAM_SUFFIX}" DESTINATION /etc/apparmor.d/)
 176 endif()