development/cmake/Install.cmake

   1
   2 # TODO: set correct path in call to cmake
   3 # e.g. cmake /usr/src/lyx/lyx-devel/development/cmake -DCMAKE_INSTALL_PREFIX=/usr/local -Dnls=1
   4
   5 if(NOT(LYX_BUNDLE) AND APPLE)
   6         message(STATUS "Installing to ${CMAKE_INSTALL_PREFIX}, defined by CMAKE_INSTALL_PREFIX")
   7 endif()
   8
   9 # the macro scans the directories "_parent_src_dir/_dir/_current_dir" for *._file_type files
  10 # and installs the files in CMAKE_INSTALL_PREFIX/_current_dir
  11 # dir_item is on item of the remaining arguments
  12 #
  13 # Special handling for ${_file_type} == "*"
  14 #     Here we try to exclude files which we do not want to install
  15 # Depending on _what, installation on UNIX goes to
  16 # data -> ${LYX_DATA_SUBDIR}
  17 # font -> share/${_lyx}/fonts/
  18 # bin -> bin
  19 # tex -> share/texmf/tex/latex/${_lyx}/
  20 macro(lyx_install _what _parent_src_dir _gl_dir _file_type)
  21   #message("checking parents ${_parent_src_dir}")
  22   file(GLOB _dirs RELATIVE "${_parent_src_dir}" ${_parent_src_dir}/${_gl_dir})
  23   #cmake bug on Windows: if _gl_dir==. _dirs is empty but on linux _dirs==.
  24   if(NOT _dirs)
  25     set(_dirs .)
  26   endif()
  27   # Select installation dir(s)
  28   # Mark, that _dest_subdir may be a list
  29   if ("${_what}" STREQUAL "data")
  30     get_data_destination(_dest_subdir)
  31   elseif ("${_what}" STREQUAL "font")
  32     get_font_destination(_dest_subdir)
  33   elseif ("${_what}" STREQUAL "tex")
  34     get_tex_destination(_dest_subdir)
  35   else()
  36     message(FATAL_ERROR "Undefined parameter _what = ${_what} in call to lyx_install")
  37   endif()
  38   foreach(_dir ${_dirs})
  39     foreach(_glob_dir ${ARGN})
  40       file(GLOB _dir_list ${_parent_src_dir}/${_dir}/${_glob_dir})
  41       if(NOT _dir_list)
  42         if(_glob_dir STREQUAL ".")
  43           set(_dir_list ${_parent_src_dir}/${_dir}/.)
  44         endif()
  45       endif()
  46       #message(STATUS "${_dir}/${_glob_dir} -> ${_dir_list} ")
  47       foreach(_current_dir ${_dir_list})
  48         file(GLOB _item_list ${_current_dir}/${_file_type})
  49         #cmake bug: globbing with * also returns directories on Windows
  50         set(files_list ${_item_list})
  51         set(program_list)
  52         foreach(_current_item ${_item_list})
  53           if(files_list)
  54             if(IS_DIRECTORY ${_current_item})
  55               #message(STATUS "removing dir ${_current_item}")
  56               list(REMOVE_ITEM files_list "${_current_item}")
  57             else()
  58               if ("${_file_type}" STREQUAL "*")
  59                 foreach(_mask "/\\.[^/]+$" "\\.in$" "\\.py$" "\\.patch$" "CMakeLists\\.txt$" "\\.lyx~$")
  60                   if(_current_item MATCHES ${_mask})
  61                     #message(STATUS "removing item ${_current_item}")
  62                     list(REMOVE_ITEM files_list "${_current_item}")
  63                   endif()
  64                 endforeach()
  65               endif()
  66             endif()
  67           endif()
  68         endforeach(_current_item)
  69         if(files_list)
  70           list(REMOVE_ITEM files_list "${_current_dir}/lyx.svg")
  71           list(REMOVE_ITEM files_list "${_current_dir}/Makefile.am")
  72           list(REMOVE_ITEM files_list "${_current_dir}/layouttranslations")
  73           if (NOT WIN32)
  74             # subscript.sty is installed only for MikTeX since it is part of texlive
  75             list(REMOVE_ITEM files_list "${_current_dir}/subscript.sty")
  76           endif()
  77           GET_FILENAME_COMPONENT(_base_dir ${_current_dir} NAME)
  78           if(_glob_dir STREQUAL ".")
  79             set(_base_dir .)
  80           endif()
  81
  82           foreach(_dst ${_dest_subdir})
  83             install(FILES ${files_list} DESTINATION "${_dst}${_dir}/${_base_dir}")
  84             #message(STATUS "Installing  ${files_list} to ${_dest_subdir}${_dir}/${_base_dir}")
  85           endforeach()
  86         endif()
  87         if(program_list)
  88           if(_glob_dir STREQUAL ".")
  89             set(_base_dir .)
  90           endif()
  91           install(FILES ${program_list} DESTINATION "${_dest_subdir}${_dir}/${_base_dir}")
  92         endif()
  93       endforeach(_current_dir)
  94     endforeach(_glob_dir)
  95   endforeach(_dir)
  96 endmacro(lyx_install)
  97
  98
  99 # language-specific-directories (like ca, de, es ...) are now globbed as "[a-z][a-z]"
 100 set(_all_languages "[a-z][a-z]" "[a-z][a-z]_[A-Z][A-Z]")
 101
 102 lyx_install("data" ${TOP_SRC_DIR}/lib bind         *.bind   . ${_all_languages})
 103 lyx_install("data" ${TOP_SRC_DIR}/lib commands     *.def    .)
 104
 105 # this is handled in doc/CMakeLists.txt
 106 #lyx_install("data" ${TOP_SRC_DIR}/lib doc          *.lyx    . ${_all_languages})
 107 #lyx_install("data" ${TOP_SRC_DIR}/lib doc          *.txt    . ${_all_languages})
 108 lyx_install("data" ${TOP_SRC_DIR}/lib doc          *      biblio clipart)
 109
 110 foreach(_lang ${_all_languages})
 111   lyx_install("data" ${TOP_SRC_DIR}/lib doc/${_lang} *    clipart)
 112 endforeach()
 113
 114 foreach(_sd "examples" "templates")
 115   lyx_install("data" ${TOP_SRC_DIR}/lib ${_sd}     *    . *)
 116   lyx_install("data" ${TOP_SRC_DIR}/lib ${_sd}/*   *    . *)
 117 endforeach()
 118
 119 foreach(_sd "kbd" "layouts" "ui" ".")
 120   lyx_install("data" ${TOP_SRC_DIR}/lib ${_sd}     *    .  )
 121 endforeach()
 122
 123 foreach(_sd "lyx2lyx" "scripts" ".")
 124   lyx_install("data" ${TOP_SRC_DIR}/lib ${_sd}     *.py .  )
 125 endforeach()
 126 foreach(_script listerrors)
 127   lyx_install("data" ${TOP_SRC_DIR}/lib scripts ${_script} . )
 128 endforeach()
 129
 130
 131 foreach(_imgext "png" "svgz" "gif" "xpm")
 132   lyx_install("data" ${TOP_SRC_DIR}/lib images       "*.${_imgext}"      . bullets ipa classic oxygen)
 133   lyx_install("data" ${TOP_SRC_DIR}/lib images/math  "*.${_imgext}"      . oxygen)
 134 endforeach()
 135 lyx_install("data" ${TOP_SRC_DIR}/lib        citeengines          *.citeengine .)
 136 lyx_install("data" ${TOP_SRC_DIR}/lib        scripts              *.R          .)
 137 lyx_install("data" ${TOP_SRC_DIR}/lib        scripts              saxon*.*     .)
 138 lyx_install("data" ${TOP_SRC_DIR}/lib        docbook              *            . epub3 xhtml5 xhtml lib common)
 139 lyx_install("data" ${TOP_SRC_DIR}/lib        xtemplates           *.xtemplate  .)
 140 lyx_install("data" ${TOP_SRC_DIR}/lib        tabletemplates       *.lyx        .)
 141 lyx_install("data" ${TOP_SRC_DIR}/3rdparty   scripts/evince_sync  *            .)
 142 lyx_install("font" ${TOP_SRC_DIR}/lib/fonts  .                    *            .)
 143 lyx_install("tex"  ${TOP_SRC_DIR}/lib/tex    .                    *            .)
 144
 145 # Install
 146 set(lyxrcorig "")
 147 set(program_suffix ${PROGRAM_SUFFIX})
 148 set(version_suffix ${LYX_VERSION})
 149
 150 if(APPLE)
 151   if(LYX_BUNDLE)
 152     install(FILES ${TOP_SRC_DIR}/development/MacOSX/spotlight/Info.plist DESTINATION "${MACOSX_BUNDLE_STARTUP_COMMAND}/Contents/Library/Spotlight/LyX-Metadata.mdimporter/Contents")
 153     install(FILES "${TOP_SRC_DIR}/development/MacOSX/PkgInfo" DESTINATION "${MACOSX_BUNDLE_STARTUP_COMMAND}/Contents")
 154   endif()
 155
 156   foreach(_i lyxeditor maxima inkscape lilypond lilypond-book)
 157     install(PROGRAMS "${TOP_SRC_DIR}/development/MacOSX/${_i}" DESTINATION "${LYX_UTILITIES_INSTALL_PATH}")
 158   endforeach()
 159   install(FILES "${TOP_SRC_DIR}/development/MacOSX/LyX.icns" DESTINATION "${LYX_DATA_SUBDIR}")
 160   set(lyxrcorig "${TOP_SRC_DIR}/development/MacOSX/lyxrc.dist.in")
 161 elseif(UNIX)
 162   configure_file(${TOP_SRC_DIR}/lib/lyx.desktop.in lyx${PROGRAM_SUFFIX}.desktop)
 163   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/lyx${PROGRAM_SUFFIX}.desktop DESTINATION ${SYSTEM_DATADIR}/applications)
 164   install(FILES ${TOP_SRC_DIR}/lib/images/lyx.svg RENAME lyx${PROGRAM_SUFFIX}.svg DESTINATION ${SYSTEM_DATADIR}/icons/hicolor/scalable/apps/)
 165   set(lyxrcorig "${TOP_SRC_DIR}/development/unix/lyxrc.dist.in")
 166 elseif(CYGWIN)
 167   set(lyxrcorig "${TOP_SRC_DIR}/development/cygwin/lyxrc.dist.in")
 168 elseif(WIN32)
 169   set(lyxrcorig "${TOP_SRC_DIR}/development/Win32/lyxrc.dist.in")
 170 endif()
 171 foreach(_file lyx.svg icon.aliases)
 172   install(FILES ${TOP_SRC_DIR}/lib/images/${_file} DESTINATION ${LYX_DATA_SUBDIR}/images/)
 173 endforeach()
 174
 175 if(NOT lyxrcorig STREQUAL "")
 176   configure_file("${lyxrcorig}" lyxrc.dist)
 177   lyx_install("data" ${CMAKE_CURRENT_BINARY_DIR} . lyxrc.dist .)
 178 endif()
 179
 180 if(USE_POSIX_PACKAGING AND EXISTS "${TOP_SRC_DIR}/lib/usr.bin.lyxwrap.in")
 181   # handle lyxwrap
 182   #get_filename_component(prefix "${CMAKE_INSTALL_PREFIX}" REALPATH)
 183   set(prefix "${CMAKE_INSTALL_PREFIX}")
 184   string(REGEX REPLACE "^/" "" lyxwrapprefix1 "${prefix}")
 185   string(REPLACE "/" "." lyxwrapprefix ${lyxwrapprefix1})
 186   #message(STATUS "lyxwrapprefix = ${lyxwrapprefix}")
 187   configure_file(${TOP_SRC_DIR}/lib/usr.bin.lyxwrap.in "${lyxwrapprefix}.${LYX_UTILITIES_INSTALL_PATH}.lyx${PROGRAM_SUFFIX}")
 188   install(FILES "${CMAKE_CURRENT_BINARY_DIR}/${lyxwrapprefix}.${LYX_UTILITIES_INSTALL_PATH}.lyx${PROGRAM_SUFFIX}" DESTINATION /etc/apparmor.d/)
 189 endif()
 190
 191 if ("${PROGRAM_SUFFIX}" MATCHES "^[0-9]+\.[0-9]+$")
 192   install(FILES ${TOP_SRC_DIR}/lib/org.lyx.LyX.metainfo.xml DESTINATION ${SYSTEM_DATADIR}/metainfo RENAME org.lyx.LyX${PROGRAM_SUFFIX}.metainfo.xml)
 193 else()
 194   install(FILES ${TOP_SRC_DIR}/lib/org.lyx.LyX.metainfo.xml DESTINATION ${SYSTEM_DATADIR}/metainfo)
 195 endif()