development/cmake/ConfigureChecks.cmake

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 include(CheckIncludeFile)
   8 include(CheckIncludeFileCXX)
   9 include(CheckIncludeFiles)
  10 include(CheckSymbolExists)
  11 include(CheckFunctionExists)
  12 include(CheckLibraryExists)
  13 include(CheckTypeSize)
  14 include(CheckCXXSourceCompiles)
  15 include(CheckCXXSourceRuns)
  16 include(MacroBoolTo01)
  17 include(TestBigEndian)
  18
  19 test_big_endian(WORDS_BIGENDIAN)
  20
  21 #check_include_file_cxx(istream HAVE_ISTREAM)
  22 #check_include_file_cxx(ostream HAVE_OSTREAM)
  23 #check_include_file_cxx(sstream HAVE_SSTREAM)
  24 #check_include_file_cxx(ios HAVE_IOS)
  25 #check_include_file_cxx(locale HAVE_LOCALE)
  26
  27 # defines will be written to configIncludes.h
  28 set(Include_Defines)
  29 foreach(_h_file aspell.h aspell/aspell.h limits.h locale.h
  30         stdlib.h sys/stat.h sys/time.h sys/types.h sys/utime.h
  31         sys/socket.h unistd.h inttypes.h utime.h string.h argz.h)
  32         string(REGEX REPLACE "[/\\.]" "_" _hf ${_h_file})
  33         string(TOUPPER ${_hf} _HF)
  34         check_include_files(${_h_file} HAVE_${_HF})
  35         set(Include_Defines "${Include_Defines}#cmakedefine HAVE_${_HF} 1\n")
  36 endforeach()
  37 check_include_file_cxx(regex HAVE_REGEX)
  38 set(Include_Defines "${Include_Defines}#cmakedefine HAVE_REGEX 1\n")
  39 configure_file(${LYX_CMAKE_DIR}/configIncludes.cmake ${TOP_BINARY_DIR}/configIncludes.h.cmake)
  40 configure_file(${TOP_BINARY_DIR}/configIncludes.h.cmake ${TOP_BINARY_DIR}/configIncludes.h)
  41
  42 # defines will be written to configFunctions.h
  43 set(Function_Defines)
  44 foreach(_f alloca __argz_count __argz_next __argz_stringify
  45         chmod close _close dcgettext fcntl fork __fsetlocking
  46         getcwd getegid getgid getpid _getpid gettext getuid lstat lockf mempcpy mkdir _mkdir
  47         mkfifo open _open pclose _pclose popen _popen putenv readlink
  48         setenv setlocale strcasecmp stpcpy strdup strerror strtoul tsearch unsetenv wcslen)
  49   string(TOUPPER ${_f} _UF)
  50   check_function_exists(${_f} HAVE_${_UF})
  51   set(Function_Defines "${Function_Defines}#cmakedefine HAVE_${_UF} 1\n")
  52 endforeach()
  53 configure_file(${LYX_CMAKE_DIR}/configFunctions.cmake ${TOP_BINARY_DIR}/configFunctions.h.cmake)
  54 configure_file(${TOP_BINARY_DIR}/configFunctions.h.cmake ${TOP_BINARY_DIR}/configFunctions.h)
  55
  56 check_symbol_exists(alloca "malloc.h" HAVE_SYMBOL_ALLOCA)
  57 check_symbol_exists(asprintf "stdio.h" HAVE_ASPRINTF)
  58 check_symbol_exists(wprintf "stdio.h" HAVE_WPRINTF)
  59 check_symbol_exists(snprintf "stdio.h" HAVE_SNPRINTF)
  60 check_symbol_exists(printf "stdio.h" HAVE_POSIX_PRINTF)
  61 check_symbol_exists(pid_t "sys/types.h" HAVE_PID_T)
  62 check_symbol_exists(intmax_t "inttypes.h" HAVE_INTTYPES_H_WITH_UINTMAX)
  63 check_symbol_exists(uintmax_t "stdint.h" HAVE_STDINT_H_WITH_UINTMAX)
  64 check_symbol_exists(LC_MESSAGES "locale.h" HAVE_LC_MESSAGES)
  65 check_symbol_exists(PATH_MAX "limits.h" HAVE_DEF_PATH_MAX)
  66
  67 check_type_size(intmax_t HAVE_INTMAX_T)
  68 macro_bool_to_01(HAVE_UINTMAX_T HAVE_STDINT_H_WITH_UINTMAX)
  69
  70 check_type_size("long double"  HAVE_LONG_DOUBLE)
  71 check_type_size("long long"  HAVE_LONG_LONG)
  72 check_type_size(wchar_t HAVE_WCHAR_T)
  73 check_type_size(wint_t  HAVE_WINT_T)
  74
  75
  76 #check_cxx_source_compiles(
  77 #       "
  78 #       #include <algorithm>
  79 #       using std::count;
  80 #       int countChar(char * b, char * e, char const c)
  81 #       {
  82 #               return count(b, e, c);
  83 #       }
  84 #       int main(){return 0;}
  85 #       "
  86 #HAVE_STD_COUNT)
  87
  88 #check_cxx_source_compiles(
  89 #       "
  90 #       #include <cctype>
  91 #       using std::tolower;
  92 #       int main(){return 0;}
  93 #       "
  94 #CXX_GLOBAL_CSTD)
  95
  96 check_cxx_source_compiles(
  97         "
  98         #include <iconv.h>
  99         // this declaration will fail when there already exists a non const char** version which returns size_t
 100         double iconv(iconv_t cd,  char **inbuf, size_t *inbytesleft, char **outbuf, size_t *outbytesleft);
 101         int main() { return 0; }
 102         "
 103 HAVE_ICONV_CONST)
 104
 105 check_cxx_source_compiles(
 106         "
 107         int i[ ( sizeof(wchar_t)==2 ? 1 : -1 ) ];
 108         int main(){return 0;}
 109         "
 110 SIZEOF_WCHAR_T_IS_2)
 111
 112 check_cxx_source_compiles(
 113         "
 114         int i[ ( sizeof(wchar_t)==4 ? 1 : -1 ) ];
 115         int main(){return 0;}
 116         "
 117 SIZEOF_WCHAR_T_IS_4)
 118
 119 check_cxx_source_compiles(
 120         "
 121         int i[ ( sizeof(long long)>sizeof(long) ? 1 : -1 ) ];
 122         int main(){return 0;}
 123         "
 124 SIZEOF_LONG_LONG_GREATER_THAN_SIZEOF_LONG)
 125
 126 check_cxx_source_compiles(
 127         "
 128         #include <execinfo.h>
 129         #include <cxxabi.h>
 130         int main() {
 131                 void* array[200];
 132                 size_t size = backtrace(array, 200);
 133                 backtrace_symbols(array, size);
 134                 int status = 0;
 135                 abi::__cxa_demangle(\"abcd\", 0, 0, &status);
 136         }
 137         "
 138 LYX_CALLSTACK_PRINTING)
 139
 140 # Check whether STL is libstdc++
 141 check_cxx_source_compiles(
 142         "
 143         #include <vector>
 144         int main() {
 145         #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 146                 this is not libstdc++
 147         #endif
 148                 return(0);
 149         }
 150         "
 151 lyx_cv_lib_stdcxx)
 152
 153 # Check whether STL is libstdc++ with C++11 ABI
 154 check_cxx_source_compiles(
 155         "
 156         #include <vector>
 157         int main() {
 158         #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 159                 this is not libstdc++ using the C++11 ABI
 160         #endif
 161                 return(0);
 162         }
 163         "
 164 USE_GLIBCXX_CXX11_ABI)
 165
 166 check_cxx_source_compiles(
 167         "
 168         #ifndef __clang__
 169                 this is not clang
 170         #endif
 171         int main() {
 172           return(0);
 173         }
 174         "
 175 lyx_cv_prog_clang)
 176
 177 check_cxx_source_compiles(
 178   "
 179   #include <memory>
 180   using std::make_unique;
 181   int main() {
 182     return(0);
 183   }
 184   "
 185 HAVE_DEF_MAKE_UNIQUE)
 186
 187 check_cxx_source_compiles(
 188   "
 189   #include <mutex>
 190   static std::once_flag flag;
 191   int main() {
 192     std::call_once(flag, [](){ return; });
 193     return(0);
 194   }
 195   "
 196 LYX_USE_STD_CALL_ONCE)
 197
 198 set(USE_LLVM_LIBCPP)
 199 set(STD_STRING_USES_COW)
 200 set(USE_GLIBCXX_CXX11_ABI)
 201 if(lyx_cv_lib_stdcxx)
 202   if(NOT USE_GLIBCXX_CXX11_ABI)
 203     set(STD_STRING_USES_COW 1)
 204   endif()
 205 else()
 206   if(lyx_cv_prog_clang)
 207     # use libc++ provided by llvm instead of GNU libstdc++
 208     set(USE_LLVM_LIBCPP 1)
 209   endif()
 210 endif()
 211
 212 set(QPA_XCB)
 213 set(HAVE_QT5_X11_EXTRAS)
 214 if(LYX_USE_QT MATCHES "QT5")
 215
 216   set(CMAKE_REQUIRED_INCLUDES ${Qt5Core_INCLUDE_DIRS})
 217   set(CMAKE_REQUIRED_FLAGS)
 218   #message(STATUS "Qt5Core_INCLUDE_DIRS = ${Qt5Core_INCLUDE_DIRS}")
 219   check_include_file_cxx(QtGui/qtgui-config.h HAVE_QTGUI_CONFIG_H)
 220   if (HAVE_QTGUI_CONFIG_H)
 221     set(lyx_qt5_config "QtGui/qtgui-config.h")
 222   else()
 223     set(lyx_qt5_config "QtCore/qconfig.h")
 224   endif()
 225   check_cxx_source_runs(
 226     "
 227     #include <${lyx_qt5_config}>
 228     #include <string>
 229     using namespace std;
 230     string a(QT_QPA_DEFAULT_PLATFORM_NAME);
 231     int main(int argc, char **argv)
 232     {
 233       if (a.compare(\"xcb\") == 0)
 234         return(0);
 235       else
 236         return 1;
 237     }
 238     "
 239     QT_USES_X11)
 240   set(QPA_XCB ${QT_USES_X11})
 241
 242   if (Qt5X11Extras_FOUND)
 243     get_target_property(_x11extra_prop Qt5::X11Extras IMPORTED_CONFIGURATIONS)
 244     get_target_property(_x11extra_link_libraries Qt5::X11Extras IMPORTED_LOCATION_${_x11extra_prop})
 245     set(CMAKE_REQUIRED_LIBRARIES ${_x11extra_link_libraries})
 246     set(CMAKE_REQUIRED_INCLUDES ${Qt5X11Extras_INCLUDE_DIRS})
 247     set(CMAKE_REQUIRED_FLAGS "${Qt5X11Extras_EXECUTABLE_COMPILE_FLAGS} -fPIC -DQT_NO_VERSION_TAGGING")
 248     #message(STATUS "CMAKE_REQUIRED_LIBRARIES = ${_x11extra_link_libraries}")
 249     #message(STATUS "CMAKE_REQUIRED_INCLUDES = ${Qt5X11Extras_INCLUDE_DIRS}")
 250     #message(STATUS "CMAKE_REQUIRED_FLAGS = ${CMAKE_REQUIRED_FLAGS}")
 251     check_cxx_source_compiles(
 252             "
 253             #include <QtX11Extras/QX11Info>
 254             int main()
 255             {
 256               bool isX11 = QX11Info::isPlatformX11();
 257             }
 258             "
 259       QT_HAS_X11_EXTRAS)
 260     set(HAVE_QT5_X11_EXTRAS ${QT_HAS_X11_EXTRAS})
 261     set(LYX_QT5_X11_EXTRAS_LIBRARY ${_x11extra_link_libraries})
 262   endif()
 263   if (Qt5WinExtras_FOUND)
 264     get_target_property(_winextra_prop Qt5::WinExtras IMPORTED_CONFIGURATIONS)
 265     string(TOUPPER ${CMAKE_BUILD_TYPE} BUILD_TYPE)
 266     get_target_property(_winextra_link_libraries Qt5::WinExtras IMPORTED_LOCATION_${BUILD_TYPE})
 267     set(CMAKE_REQUIRED_LIBRARIES ${_winextra_link_libraries})
 268     set(CMAKE_REQUIRED_INCLUDES ${Qt5WinExtras_INCLUDE_DIRS})
 269     set(CMAKE_REQUIRED_FLAGS ${Qt5WinExtras_EXECUTABLE_COMPILE_FLAGS})
 270   endif()
 271 elseif(LYX_USE_QT MATCHES "QT4")
 272   set(CMAKE_REQUIRED_LIBRARIES ${QT_QTGUI_LIBRARY})
 273   set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES})
 274   check_cxx_source_compiles(
 275           "
 276           #include <QtGui/QX11Info>
 277           int main()
 278           {
 279             QX11Info *qxi = new QX11Info;
 280             qxi->~QX11Info();
 281           }
 282           "
 283   QT_USES_X11)
 284 else()
 285   message(FATAL_ERROR "Check for QT_USES_X11: Not handled LYX_USE_QT (= ${LYX_USE_QT})")
 286 endif()