development/cmake/ConfigureChecks.cmake

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 include(CheckIncludeFile)
   8 include(CheckIncludeFileCXX)
   9 include(CheckIncludeFiles)
  10 include(CheckSymbolExists)
  11 include(CheckFunctionExists)
  12 include(CheckLibraryExists)
  13 include(CheckTypeSize)
  14 include(CheckCXXSourceCompiles)
  15 include(CheckCXXSourceRuns)
  16 include(MacroBoolTo01)
  17 include(TestBigEndian)
  18
  19 test_big_endian(WORDS_BIGENDIAN)
  20
  21 #check_include_file_cxx(istream HAVE_ISTREAM)
  22 #check_include_file_cxx(ostream HAVE_OSTREAM)
  23 #check_include_file_cxx(sstream HAVE_SSTREAM)
  24 #check_include_file_cxx(ios HAVE_IOS)
  25 #check_include_file_cxx(locale HAVE_LOCALE)
  26
  27 # defines will be written to configIncludes.h
  28 set(Include_Defines)
  29 foreach(_h_file aspell.h aspell/aspell.h limits.h locale.h
  30         stdlib.h sys/stat.h sys/time.h sys/types.h sys/utime.h
  31         sys/socket.h unistd.h inttypes.h utime.h string.h argz.h)
  32         string(REGEX REPLACE "[/\\.]" "_" _hf ${_h_file})
  33         string(TOUPPER ${_hf} _HF)
  34         check_include_files(${_h_file} HAVE_${_HF})
  35         set(Include_Defines "${Include_Defines}#cmakedefine HAVE_${_HF} 1\n")
  36 endforeach()
  37 check_include_file_cxx(regex HAVE_REGEX)
  38 set(Include_Defines "${Include_Defines}#cmakedefine HAVE_REGEX 1\n")
  39 configure_file(${LYX_CMAKE_DIR}/configIncludes.cmake ${TOP_BINARY_DIR}/configIncludes.h.cmake)
  40 configure_file(${TOP_BINARY_DIR}/configIncludes.h.cmake ${TOP_BINARY_DIR}/configIncludes.h)
  41
  42 # defines will be written to configFunctions.h
  43 set(Function_Defines)
  44 foreach(_f alloca __argz_count __argz_next __argz_stringify
  45         chmod close _close dcgettext fcntl fork __fsetlocking
  46         getcwd getegid getgid getpid _getpid gettext getuid lstat lockf mempcpy mkdir _mkdir
  47         mkfifo open _open pclose _pclose popen _popen putenv readlink
  48         setenv setlocale strcasecmp stpcpy strdup strerror strtoul tsearch unsetenv wcslen)
  49   string(TOUPPER ${_f} _UF)
  50   check_function_exists(${_f} HAVE_${_UF})
  51   set(Function_Defines "${Function_Defines}#cmakedefine HAVE_${_UF} 1\n")
  52 endforeach()
  53 configure_file(${LYX_CMAKE_DIR}/configFunctions.cmake ${TOP_BINARY_DIR}/configFunctions.h.cmake)
  54 configure_file(${TOP_BINARY_DIR}/configFunctions.h.cmake ${TOP_BINARY_DIR}/configFunctions.h)
  55
  56 check_symbol_exists(alloca "malloc.h" HAVE_SYMBOL_ALLOCA)
  57 check_symbol_exists(asprintf "stdio.h" HAVE_ASPRINTF)
  58 check_symbol_exists(wprintf "stdio.h" HAVE_WPRINTF)
  59 check_symbol_exists(snprintf "stdio.h" HAVE_SNPRINTF)
  60 check_symbol_exists(printf "stdio.h" HAVE_POSIX_PRINTF)
  61 check_symbol_exists(pid_t "sys/types.h" HAVE_PID_T)
  62 check_symbol_exists(intmax_t "inttypes.h" HAVE_INTTYPES_H_WITH_UINTMAX)
  63 check_symbol_exists(uintmax_t "stdint.h" HAVE_STDINT_H_WITH_UINTMAX)
  64 check_symbol_exists(LC_MESSAGES "locale.h" HAVE_LC_MESSAGES)
  65 check_symbol_exists(PATH_MAX "limits.h" HAVE_DEF_PATH_MAX)
  66
  67 check_type_size(intmax_t HAVE_INTMAX_T)
  68 macro_bool_to_01(HAVE_UINTMAX_T HAVE_STDINT_H_WITH_UINTMAX)
  69
  70 check_type_size("long double"  HAVE_LONG_DOUBLE)
  71 check_type_size("long long"  HAVE_LONG_LONG_INT)
  72 check_type_size(wchar_t HAVE_WCHAR_T)
  73 check_type_size(wint_t  HAVE_WINT_T)
  74
  75 if(HUNSPELL_FOUND)
  76   # check whether hunspell C++ (rather than C) ABI is provided
  77   set(HunspellTestFile "${CMAKE_BINARY_DIR}/hunspelltest.cpp")
  78   file(WRITE "${HunspellTestFile}"
  79   "
  80   #include <hunspell.hxx>
  81
  82   int main()
  83   {
  84     Hunspell sp(\"foo\", \"bar\");
  85     int i = sp.stem(\"test\").size();
  86   return(0);
  87   }
  88   "
  89   )
  90
  91   try_compile(HAVE_HUNSPELL_CXXABI
  92     "${CMAKE_BINARY_DIR}"
  93     "${HunspellTestFile}"
  94     CMAKE_FLAGS
  95       "-DINCLUDE_DIRECTORIES:STRING=${HUNSPELL_INCLUDE_DIR}"
  96     LINK_LIBRARIES ${HUNSPELL_LIBRARY}
  97     OUTPUT_VARIABLE  LOG2)
  98
  99   message(STATUS "HAVE_HUNSPELL_CXXABI = ${HAVE_HUNSPELL_CXXABI}")
 100   #message(STATUS "LOG2 = ${LOG2}")
 101   if(LYX_EXTERNAL_HUNSPELL AND LYX_STDLIB_DEBUG AND HAVE_HUNSPELL_CXXABI)
 102     message(WARNING "Compiling LyX with stdlib-debug and system hunspell libraries may lead to crashes. Consider using -DLYX_STDLIB_DEBUG=OFF or -DLYX_EXTERNAL_HUNSPELL=OFF.")
 103   endif()
 104 endif()
 105
 106 #check_cxx_source_compiles(
 107 #       "
 108 #       #include <algorithm>
 109 #       using std::count;
 110 #       int countChar(char * b, char * e, char const c)
 111 #       {
 112 #               return count(b, e, c);
 113 #       }
 114 #       int main(){return 0;}
 115 #       "
 116 #HAVE_STD_COUNT)
 117
 118 #check_cxx_source_compiles(
 119 #       "
 120 #       #include <cctype>
 121 #       using std::tolower;
 122 #       int main(){return 0;}
 123 #       "
 124 #CXX_GLOBAL_CSTD)
 125
 126 check_cxx_source_compiles(
 127         "
 128         #include <iconv.h>
 129         // this declaration will fail when there already exists a non const char** version which returns size_t
 130         double iconv(iconv_t cd,  char **inbuf, size_t *inbytesleft, char **outbuf, size_t *outbytesleft);
 131         int main() { return 0; }
 132         "
 133 HAVE_ICONV_CONST)
 134
 135 check_cxx_source_compiles(
 136         "
 137         int i[ ( sizeof(wchar_t)==2 ? 1 : -1 ) ];
 138         int main(){return 0;}
 139         "
 140 SIZEOF_WCHAR_T_IS_2)
 141
 142 check_cxx_source_compiles(
 143         "
 144         int i[ ( sizeof(wchar_t)==4 ? 1 : -1 ) ];
 145         int main(){return 0;}
 146         "
 147 SIZEOF_WCHAR_T_IS_4)
 148
 149 check_cxx_source_compiles(
 150         "
 151         int i[ ( sizeof(long long)>sizeof(long) ? 1 : -1 ) ];
 152         int main(){return 0;}
 153         "
 154 SIZEOF_LONG_LONG_GREATER_THAN_SIZEOF_LONG)
 155
 156 if(LYX_DISABLE_CALLSTACK_PRINTING)
 157   set(LYX_CALLSTACK_PRINTING OFF CACHE BOOL "Print callstack when crashing")
 158 else()
 159   check_cxx_source_compiles(
 160         "
 161         #include <execinfo.h>
 162         #include <cxxabi.h>
 163         int main() {
 164                 void* array[200];
 165                 size_t size = backtrace(array, 200);
 166                 backtrace_symbols(array, size);
 167                 int status = 0;
 168                 abi::__cxa_demangle(\"abcd\", 0, 0, &status);
 169         }
 170         "
 171   LYX_CALLSTACK_PRINTING)
 172 endif()
 173
 174 # Check whether STL is libstdc++
 175 check_cxx_source_compiles(
 176         "
 177         #include <vector>
 178         int main() {
 179         #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 180                 this is not libstdc++
 181         #endif
 182                 return(0);
 183         }
 184         "
 185 lyx_cv_lib_stdcxx)
 186
 187 # Check whether STL is libstdc++ with C++11 ABI
 188 check_cxx_source_compiles(
 189         "
 190         #include <vector>
 191         int main() {
 192         #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 193                 this is not libstdc++ using the C++11 ABI
 194         #endif
 195                 return(0);
 196         }
 197         "
 198 USE_GLIBCXX_CXX11_ABI)
 199
 200 check_cxx_source_compiles(
 201         "
 202         #ifndef __clang__
 203                 this is not clang
 204         #endif
 205         int main() {
 206           return(0);
 207         }
 208         "
 209 lyx_cv_prog_clang)
 210
 211 check_cxx_source_compiles(
 212   "
 213   #include <memory>
 214   using std::make_unique;
 215   int main() {
 216     return(0);
 217   }
 218   "
 219 HAVE_DEF_MAKE_UNIQUE)
 220
 221 check_cxx_source_compiles(
 222   "
 223   #include <mutex>
 224   static std::once_flag flag;
 225   int main() {
 226     std::call_once(flag, [](){ return; });
 227     return(0);
 228   }
 229   "
 230 LYX_USE_STD_CALL_ONCE)
 231
 232 if (ENCHANT_FOUND)
 233   set(CMAKE_REQUIRED_INCLUDES ${ENCHANT_INCLUDE_DIR})
 234   set(CMAKE_REQUIRED_LIBRARIES ${ENCHANT_LIBRARY})
 235   # Check, whether enchant is version 2.x at least
 236   check_cxx_source_compiles(
 237     "
 238     #include <enchant++.h>
 239     enchant::Broker broker;
 240     int main() {
 241       return(0);
 242     }
 243     "
 244   HAVE_ENCHANT2)
 245   if (HAVE_ENCHANT2)
 246     message(STATUS "ENCHANT2 found")
 247   endif()
 248 endif()
 249
 250 set(USE_LLVM_LIBCPP)
 251 set(STD_STRING_USES_COW)
 252 set(USE_GLIBCXX_CXX11_ABI)
 253 if(lyx_cv_lib_stdcxx)
 254   if(NOT USE_GLIBCXX_CXX11_ABI)
 255     set(STD_STRING_USES_COW 1)
 256   endif()
 257 else()
 258   if(lyx_cv_prog_clang)
 259     # use libc++ provided by llvm instead of GNU libstdc++
 260     set(USE_LLVM_LIBCPP 1)
 261   endif()
 262 endif()
 263
 264 set(QPA_XCB)
 265 set(HAVE_QT5_X11_EXTRAS)
 266 if(LYX_USE_QT MATCHES "QT5")
 267
 268   set(CMAKE_REQUIRED_INCLUDES ${Qt5Core_INCLUDE_DIRS})
 269   set(CMAKE_REQUIRED_FLAGS)
 270   #message(STATUS "Qt5Core_INCLUDE_DIRS = ${Qt5Core_INCLUDE_DIRS}")
 271   check_include_file_cxx(QtGui/qtgui-config.h HAVE_QTGUI_CONFIG_H)
 272   if (HAVE_QTGUI_CONFIG_H)
 273     set(lyx_qt5_config "QtGui/qtgui-config.h")
 274   else()
 275     set(lyx_qt5_config "QtCore/qconfig.h")
 276   endif()
 277   if(WIN32)
 278     set(QT_USES_X11 OFF CACHE BOOL "Win32 compiled without X11")
 279     # The try_run for minngw would not work here anyway
 280   else()
 281     check_cxx_source_runs(
 282       "
 283       #include <${lyx_qt5_config}>
 284       #include <string>
 285       using namespace std;
 286       string a(QT_QPA_DEFAULT_PLATFORM_NAME);
 287       int main(int argc, char **argv)
 288       {
 289         if (a.compare(\"xcb\") == 0)
 290           return(0);
 291         else
 292           return 1;
 293       }
 294       "
 295       QT_USES_X11)
 296     if(QT_USES_X11)
 297       set(QPA_XCB ${QT_USES_X11})
 298     endif()
 299   endif()
 300
 301   if (Qt5X11Extras_FOUND)
 302     get_target_property(_x11extra_prop Qt5::X11Extras IMPORTED_CONFIGURATIONS)
 303     get_target_property(_x11extra_link_libraries Qt5::X11Extras IMPORTED_LOCATION_${_x11extra_prop})
 304     set(CMAKE_REQUIRED_LIBRARIES ${_x11extra_link_libraries})
 305     set(CMAKE_REQUIRED_INCLUDES ${Qt5X11Extras_INCLUDE_DIRS})
 306     set(CMAKE_REQUIRED_FLAGS "${Qt5X11Extras_EXECUTABLE_COMPILE_FLAGS} -fPIC -DQT_NO_VERSION_TAGGING")
 307     #message(STATUS "CMAKE_REQUIRED_LIBRARIES = ${_x11extra_link_libraries}")
 308     #message(STATUS "CMAKE_REQUIRED_INCLUDES = ${Qt5X11Extras_INCLUDE_DIRS}")
 309     #message(STATUS "CMAKE_REQUIRED_FLAGS = ${CMAKE_REQUIRED_FLAGS}")
 310     check_cxx_source_compiles(
 311             "
 312             #include <QtX11Extras/QX11Info>
 313             int main()
 314             {
 315               bool isX11 = QX11Info::isPlatformX11();
 316             }
 317             "
 318       QT_HAS_X11_EXTRAS)
 319     set(HAVE_QT5_X11_EXTRAS ${QT_HAS_X11_EXTRAS})
 320     set(LYX_QT5_X11_EXTRAS_LIBRARY ${_x11extra_link_libraries})
 321   endif()
 322   if (Qt5WinExtras_FOUND)
 323     get_target_property(_winextra_prop Qt5::WinExtras IMPORTED_CONFIGURATIONS)
 324     string(TOUPPER ${CMAKE_BUILD_TYPE} BUILD_TYPE)
 325     get_target_property(_winextra_link_libraries Qt5::WinExtras IMPORTED_LOCATION_${BUILD_TYPE})
 326     set(CMAKE_REQUIRED_LIBRARIES ${_winextra_link_libraries})
 327     set(CMAKE_REQUIRED_INCLUDES ${Qt5WinExtras_INCLUDE_DIRS})
 328     set(CMAKE_REQUIRED_FLAGS ${Qt5WinExtras_EXECUTABLE_COMPILE_FLAGS})
 329   endif()
 330 elseif(LYX_USE_QT MATCHES "QT4")
 331   set(CMAKE_REQUIRED_LIBRARIES ${QT_QTGUI_LIBRARY})
 332   set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES})
 333   check_cxx_source_compiles(
 334           "
 335           #include <QtGui/QX11Info>
 336           int main()
 337           {
 338             QX11Info *qxi = new QX11Info;
 339             qxi->~QX11Info();
 340           }
 341           "
 342   QT_USES_X11)
 343 else()
 344   message(FATAL_ERROR "Check for QT_USES_X11: Not handled LYX_USE_QT (= ${LYX_USE_QT})")
 345 endif()