development/cmake/ConfigureChecks.cmake

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 include(CheckIncludeFile)
   8 include(CheckIncludeFileCXX)
   9 include(CheckIncludeFiles)
  10 include(CheckSymbolExists)
  11 include(CheckFunctionExists)
  12 include(CheckLibraryExists)
  13 include(CheckTypeSize)
  14 include(CheckCXXSourceCompiles)
  15 include(MacroBoolTo01)
  16 include(TestBigEndian)
  17
  18 test_big_endian(WORDS_BIGENDIAN)
  19
  20 #check_include_file_cxx(istream HAVE_ISTREAM)
  21 #check_include_file_cxx(ostream HAVE_OSTREAM)
  22 #check_include_file_cxx(sstream HAVE_SSTREAM)
  23 #check_include_file_cxx(ios HAVE_IOS)
  24 #check_include_file_cxx(locale HAVE_LOCALE)
  25
  26 # defines will be written to configIncludes.h
  27 set(Include_Defines)
  28 foreach(_h_file aspell.h aspell/aspell.h limits.h locale.h
  29         stdlib.h sys/stat.h sys/time.h sys/types.h sys/utime.h
  30         sys/socket.h unistd.h inttypes.h utime.h string.h argz.h)
  31         string(REGEX REPLACE "[/\\.]" "_" _hf ${_h_file})
  32         string(TOUPPER ${_hf} _HF)
  33         check_include_files(${_h_file} HAVE_${_HF})
  34         set(Include_Defines "${Include_Defines}#cmakedefine HAVE_${_HF} 1\n")
  35 endforeach()
  36 check_include_file_cxx(regex HAVE_REGEX)
  37 set(Include_Defines "${Include_Defines}#cmakedefine HAVE_REGEX 1\n")
  38 configure_file(${LYX_CMAKE_DIR}/configIncludes.cmake ${TOP_BINARY_DIR}/configIncludes.h.cmake)
  39 configure_file(${TOP_BINARY_DIR}/configIncludes.h.cmake ${TOP_BINARY_DIR}/configIncludes.h)
  40
  41 # defines will be written to configFunctions.h
  42 set(Function_Defines)
  43 foreach(_f alloca __argz_count __argz_next __argz_stringify
  44         chmod close _close dcgettext fcntl fork __fsetlocking
  45         getcwd getegid getgid getpid _getpid gettext getuid lstat lockf mempcpy mkdir _mkdir
  46         mkfifo open _open pclose _pclose popen _popen putenv readlink
  47         setenv setlocale strcasecmp stpcpy strdup strerror strtoul tsearch unsetenv wcslen)
  48   string(TOUPPER ${_f} _UF)
  49   check_function_exists(${_f} HAVE_${_UF})
  50   set(Function_Defines "${Function_Defines}#cmakedefine HAVE_${_UF} 1\n")
  51 endforeach()
  52 configure_file(${LYX_CMAKE_DIR}/configFunctions.cmake ${TOP_BINARY_DIR}/configFunctions.h.cmake)
  53 configure_file(${TOP_BINARY_DIR}/configFunctions.h.cmake ${TOP_BINARY_DIR}/configFunctions.h)
  54
  55 check_symbol_exists(alloca "malloc.h" HAVE_SYMBOL_ALLOCA)
  56 check_symbol_exists(asprintf "stdio.h" HAVE_ASPRINTF)
  57 check_symbol_exists(wprintf "stdio.h" HAVE_WPRINTF)
  58 check_symbol_exists(snprintf "stdio.h" HAVE_SNPRINTF)
  59 check_symbol_exists(printf "stdio.h" HAVE_POSIX_PRINTF)
  60 check_symbol_exists(pid_t "sys/types.h" HAVE_PID_T)
  61 check_symbol_exists(intmax_t "inttypes.h" HAVE_INTTYPES_H_WITH_UINTMAX)
  62 check_symbol_exists(uintmax_t "stdint.h" HAVE_STDINT_H_WITH_UINTMAX)
  63 check_symbol_exists(LC_MESSAGES "locale.h" HAVE_LC_MESSAGES)
  64
  65 check_type_size(intmax_t HAVE_INTMAX_T)
  66 macro_bool_to_01(HAVE_UINTMAX_T HAVE_STDINT_H_WITH_UINTMAX)
  67
  68 check_type_size("long double"  HAVE_LONG_DOUBLE)
  69 check_type_size("long long"  HAVE_LONG_LONG)
  70 check_type_size(wchar_t HAVE_WCHAR_T)
  71 check_type_size(wint_t  HAVE_WINT_T)
  72
  73
  74 #check_cxx_source_compiles(
  75 #       "
  76 #       #include <algorithm>
  77 #       using std::count;
  78 #       int countChar(char * b, char * e, char const c)
  79 #       {
  80 #               return count(b, e, c);
  81 #       }
  82 #       int main(){return 0;}
  83 #       "
  84 #HAVE_STD_COUNT)
  85
  86 #check_cxx_source_compiles(
  87 #       "
  88 #       #include <cctype>
  89 #       using std::tolower;
  90 #       int main(){return 0;}
  91 #       "
  92 #CXX_GLOBAL_CSTD)
  93
  94 check_cxx_source_compiles(
  95         "
  96         #include <iconv.h>
  97         // this declaration will fail when there already exists a non const char** version which returns size_t
  98         double iconv(iconv_t cd,  char **inbuf, size_t *inbytesleft, char **outbuf, size_t *outbytesleft);
  99         int main() { return 0; }
 100         "
 101 HAVE_ICONV_CONST)
 102
 103 check_cxx_source_compiles(
 104         "
 105         int i[ ( sizeof(wchar_t)==2 ? 1 : -1 ) ];
 106         int main(){return 0;}
 107         "
 108 SIZEOF_WCHAR_T_IS_2)
 109
 110 check_cxx_source_compiles(
 111         "
 112         int i[ ( sizeof(wchar_t)==4 ? 1 : -1 ) ];
 113         int main(){return 0;}
 114         "
 115 SIZEOF_WCHAR_T_IS_4)
 116
 117 check_cxx_source_compiles(
 118         "
 119         int i[ ( sizeof(long long)>sizeof(long) ? 1 : -1 ) ];
 120         int main(){return 0;}
 121         "
 122 SIZEOF_LONG_LONG_GREATER_THAN_SIZEOF_LONG)
 123
 124 check_cxx_source_compiles(
 125         "
 126         #include <execinfo.h>
 127         #include <cxxabi.h>
 128         int main() {
 129                 void* array[200];
 130                 size_t size = backtrace(array, 200);
 131                 backtrace_symbols(array, size);
 132                 int status = 0;
 133                 abi::__cxa_demangle(\"abcd\", 0, 0, &status);
 134         }
 135         "
 136 LYX_CALLSTACK_PRINTING)
 137
 138 # Check whether STL is libstdc++
 139 check_cxx_source_compiles(
 140         "
 141         #include <vector>
 142         int main() {
 143         #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 144                 this is not libstdc++
 145         #endif
 146                 return(0);
 147         }
 148         "
 149 lyx_cv_lib_stdcxx)
 150
 151 # Check whether STL is libstdc++ with C++11 ABI
 152 check_cxx_source_compiles(
 153         "
 154         #include <vector>
 155         int main() {
 156         #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 157                 this is not libstdc++ using the C++11 ABI
 158         #endif
 159                 return(0);
 160         }
 161         "
 162 USE_GLIBCXX_CXX11_ABI)
 163
 164 check_cxx_source_compiles(
 165         "
 166         #ifndef __clang__
 167                 this is not clang
 168         #endif
 169         int main() {
 170           return(0);
 171         }
 172         "
 173 lyx_cv_prog_clang)
 174
 175 set(USE_LLVM_LIBCPP)
 176 set(STD_STRING_USES_COW)
 177 set(USE_GLIBCXX_CXX11_ABI)
 178 if(lyx_cv_lib_stdcxx)
 179   if(NOT USE_GLIBCXX_CXX11_ABI)
 180     set(STD_STRING_USES_COW 1)
 181   endif()
 182 else()
 183   if(lyx_cv_prog_clang)
 184     # use libc++ provided by llvm instead of GNU libstdc++
 185     set(USE_LLVM_LIBCPP 1)
 186   endif()
 187 endif()
 188
 189 if(LYX_USE_QT MATCHES "QT5")
 190   if (Qt5X11Extras_FOUND)
 191     get_target_property(_x11extra_prop Qt5::X11Extras IMPORTED_CONFIGURATIONS)
 192     get_target_property(_x11extra_link_libraries Qt5::X11Extras IMPORTED_LOCATION_${_x11extra_prop})
 193     set(CMAKE_REQUIRED_LIBRARIES ${_x11extra_link_libraries})
 194     set(CMAKE_REQUIRED_INCLUDES ${Qt5X11Extras_INCLUDE_DIRS})
 195     set(CMAKE_REQUIRED_FLAGS "${Qt5X11Extras_EXECUTABLE_COMPILE_FLAGS} -fPIC -DQT_NO_VERSION_TAGGING")
 196     #message(STATUS "CMAKE_REQUIRED_LIBRARIES = ${_x11extra_link_libraries}")
 197     #message(STATUS "CMAKE_REQUIRED_INCLUDES = ${Qt5X11Extras_INCLUDE_DIRS}")
 198     #message(STATUS "CMAKE_REQUIRED_FLAGS = ${CMAKE_REQUIRED_FLAGS}")
 199     check_cxx_source_compiles(
 200             "
 201             #include <QtX11Extras/QX11Info>
 202             int main()
 203             {
 204               bool isX11 = QX11Info::isPlatformX11();
 205             }
 206             "
 207     QT_USES_X11)
 208   endif()
 209   if (Qt5WinExtras_FOUND)
 210     get_target_property(_winextra_prop Qt5::WinExtras IMPORTED_CONFIGURATIONS)
 211     string(TOUPPER ${CMAKE_BUILD_TYPE} BUILD_TYPE)
 212     get_target_property(_winextra_link_libraries Qt5::WinExtras IMPORTED_LOCATION_${BUILD_TYPE})
 213     set(CMAKE_REQUIRED_LIBRARIES ${_winextra_link_libraries})
 214     set(CMAKE_REQUIRED_INCLUDES ${Qt5WinExtras_INCLUDE_DIRS})
 215     set(CMAKE_REQUIRED_FLAGS ${Qt5WinExtras_EXECUTABLE_COMPILE_FLAGS})
 216   endif()
 217 elseif(LYX_USE_QT MATCHES "QT4")
 218   set(CMAKE_REQUIRED_LIBRARIES ${QT_QTGUI_LIBRARY})
 219   set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES})
 220   check_cxx_source_compiles(
 221           "
 222           #include <QtGui/QX11Info>
 223           int main()
 224           {
 225             QX11Info *qxi = new QX11Info;
 226             qxi->~QX11Info();
 227           }
 228           "
 229   QT_USES_X11)
 230 else()
 231   message(FATAL_ERROR "Check for QT_USES_X11: Not handled LYX_USE_QT (= ${LYX_USE_QT})")
 232 endif()
 233