development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif()
  15
  16 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  17
  18 # Supress regeneration
  19 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  20
  21
  22 include(LyXMacros)
  23
  24
  25 # Usage LYX_OPTION
  26 # 1. parameter: option name without prefix 'LYX_'
  27 # 2. parameter: description
  28 # 3. parameter: default value, ON or OFF
  29 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  30
  31
  32 LYX_OPTION_INIT()
  33
  34 # Options for all compilers/systems
  35 LYX_OPTION(CPACK "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  36 LYX_OPTION(INSTALL "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  37 LYX_OPTION(NLS "Use nls" OFF ALL)
  38 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  39 LYX_OPTION(ENCHANT "Require Enchant" OFF ALL)
  40 LYX_OPTION(HUNSPELL "Require Hunspell" OFF ALL)
  41 LYX_OPTION(DEVEL_VERSION "Build developer version" OFF ALL)
  42 LYX_OPTION(RELEASE "Build release version, build debug when disabled" ON ALL)
  43 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" ON ALL)
  44 LYX_OPTION(PCH "Use precompiled headers" OFF ALL)
  45 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  46 LYX_OPTION(MERGE_REBUILD "Rebuild generated files from merged files build" OFF ALL)
  47 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  48 LYX_OPTION(INSTALL_PREFIX "Install path for LyX" OFF ALL)
  49 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  50
  51 # GCC specific
  52 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  53 LYX_OPTION(EXTERNAL_BOOST "Use external boost" OFF GCC)
  54 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  55 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  56 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  57 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  58 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  59
  60 # MSVC specific
  61 LYX_OPTION(CONSOLE "Show console on Windows" ON MSVC)
  62 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  63 LYX_OPTION(WALL "Enable all warnings" OFF MSVC)
  64 LYX_OPTION(CONFIGURE_CHECKS "Also run configure checks for MSVC" OFF MSVC)
  65 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
  66
  67 # Check option dependencies
  68 if(LYX_CPACK)
  69         set(LYX_INSTALL ON)
  70 endif()
  71
  72 if(LYX_INSTALL)
  73         set(LYX_NLS ON)
  74         if (WIN32)
  75                 set(LYX_HUNSPELL ON)
  76         endif()
  77         set(LYX_CONSOLE OFF)
  78         set(LYX_PACKAGE_SUFFIX ON)
  79         set(LYX_RELEASE ON)
  80         set(LYX_PROFILE OFF)
  81 endif()
  82
  83 if(LYX_MERGE_FILES)
  84         set(LYX_PCH OFF)
  85 else()
  86         set(LYX_MERGE_REBUILD OFF)
  87 endif()
  88
  89 if(LYX_DEPENDENCIES_DOWNLOAD)
  90         message(STATUS)
  91         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
  92         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
  93         set(deps_files lyx20-deps-msvc2010-x86.zip)
  94         foreach(it ${deps_files})
  95                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
  96                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
  97                 if(NOT already_downloaded)
  98                         message(STATUS "Downloading ${it} ...")
  99                         file(DOWNLOAD ftp://ftp.devel.lyx.org/pub/contrib/windows/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS)
 100                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 101                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 102                 endif()
 103         endforeach()
 104         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 105 endif()
 106
 107
 108 message(STATUS)
 109
 110 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 111 set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 112
 113
 114
 115 if(UNIX OR MINGW)
 116         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 117         message(STATUS "Using GCC version ${GCC_VERSION}")
 118         if(NOT GCC_VERSION VERSION_LESS 4.4)
 119                 set(LYX_USE_TR1 1)
 120                 # GCC <= 4.5 does not support regex: there are linker errors
 121                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 122                 set(LYX_USE_TR1_REGEX 0)
 123         endif()
 124 else()
 125         if(MSVC10)
 126                 set(LYX_USE_TR1 1)
 127                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 128         endif()
 129 endif()
 130
 131
 132 set(VERSION_INFO "CMake Build")
 133
 134 # Try to get some informations from configure.ac
 135
 136 include(LyXPaths)    #called here to define the needed TOP_SRC_DIR-variable
 137 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 138
 139 if(WIN32)
 140         set(USE_WINDOWS_PACKAGING 1)
 141 elseif(APPLE)
 142         set(USE_MACOSX_PACKAGING 1)
 143 else()
 144         set(USE_POSIX_PACKAGING 1)
 145 endif()
 146
 147 macro(setstripped _varname _value)
 148         string(STRIP ${_value} _v)
 149         if(USE_POSIX_PACKAGING)
 150                 string(TOLOWER ${_v} ${_varname})
 151         else()
 152                 set(${_varname} ${_v})
 153         endif()
 154 endmacro(setstripped)
 155
 156 foreach(_c_l ${_config_lines} )
 157         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 158                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 159                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 160                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 161                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 162                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 163                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 164                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 165                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 166                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 167                 endif()
 168         endif()
 169         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 170                 set(LYX_DATE "${CMAKE_MATCH_1}")
 171         endif()
 172 endforeach(_c_l)
 173
 174
 175 if (LYX_INSTALL_PREFIX)
 176         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 177         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 178 endif()
 179 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 180
 181 if(LYX_PACKAGE_SUFFIX)
 182         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 183 else()
 184         set(PACKAGE ${PACKAGE_BASE})
 185 endif()
 186
 187 if(LYX_PROGRAM_SUFFIX)
 188         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 189 else()
 190         set(PROGRAM_SUFFIX "")
 191 endif()
 192
 193
 194 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 195         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 196         if (UNIX)
 197                 # don't use the default "/usr/local"
 198                 # but respect the user-choice on the command-line
 199                 if(LYX_INSTALL_SUFFIX)
 200                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 201                 else()
 202                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 203                 endif()
 204         endif()
 205         if(WIN32)
 206                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 207         endif()
 208 endif()
 209
 210 if (WIN32)
 211         set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 212 else()
 213         set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 214 endif()
 215
 216 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 217 set(LYX_LOCALEDIR "locale")
 218 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 219 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 220
 221
 222 if(NOT GROUP_CODE)
 223         #set(GROUP_CODE "The Golden Code")
 224         set(GROUP_CODE flat)
 225 endif()
 226
 227 # lyx's source files
 228 set(LYX_CPP_FILES *.cpp)
 229 set(LYX_HPP_FILES *.h)
 230 set(LYX_MOC_FILES moc_*.cpp)
 231
 232
 233 include(ProjectSourceGroup)
 234
 235
 236 if(LYX_PROFILE)
 237         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 238         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 239 endif()
 240
 241 if(LYX_RELEASE)
 242         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build release version" FORCE)
 243 else()
 244         set(CMAKE_BUILD_TYPE Debug CACHE STRING "Build debug version" FORCE)
 245 endif()
 246
 247 # When shared libs are supported enable this option
 248 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 249 if(LYX_SHARED_LIBRARIES)
 250         set(library_type SHARED)
 251 else()
 252         set(library_type STATIC)
 253 endif()
 254
 255 if(NOT MSVC)
 256         if(NOT LYX_QUIET)
 257                 set(CMAKE_VERBOSE_MAKEFILE ON)
 258         endif()
 259         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 260         if(LYX_STDLIB_DEBUG)
 261                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 262         endif()
 263         if(LYX_CONCEPT_CHECKS)
 264                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 265         endif()
 266         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 267         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 268         if(MINGW)
 269                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 270         else()
 271                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 272         endif()
 273         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 274 endif()
 275
 276
 277 find_package(Qt4 REQUIRED)
 278 find_package(ICONV REQUIRED)
 279 find_package(ZLIB REQUIRED)
 280
 281 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 282
 283 if(LYX_ASPELL)
 284         find_package(ASPELL)
 285         include_directories(${ASPELL_INCLUDE_DIR})
 286 endif()
 287
 288 if(LYX_ENCHANT)
 289         find_package(Enchant REQUIRED)
 290         include_directories(${ENCHANT_INCLUDE_DIR})
 291 endif()
 292
 293 if(LYX_HUNSPELL)
 294         find_package(Hunspell REQUIRED)
 295         include_directories(${HUNSPELL_INCLUDE_DIR})
 296 endif()
 297
 298 if(LYX_NLS)
 299         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python HINTS ${GNUWIN32_DIR}/python)
 300         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 301                 message(FATAL_ERROR "Python 2.6 needed!")
 302         endif()
 303         find_package(LyXGettext REQUIRED)
 304         include_directories(${TOP_SRC_DIR}/po)
 305         add_subdirectory(po)
 306 endif()
 307
 308 if(LYX_EXTERNAL_LIBINTL)
 309         find_package(Libintl REQUIRED)
 310         add_definitions(-DHAVE_GETTEXT) #TODO move to config.h
 311 else()
 312         if(LYX_NLS)
 313                 add_subdirectory(intl)
 314         else()
 315                 # do not compile if nls disabled
 316         endif()
 317 endif()
 318
 319 if(LYX_EXTERNAL_BOOST)
 320         message(STATUS "Searching for boost")
 321         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 322         if(Boost_FOUND)
 323                 message(STATUS "Boost found")
 324                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 325                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 326         else()
 327                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 328         endif()
 329 else()
 330         if(LYX_USE_TR1_REGEX)
 331                 set(Lyx_Boost_Libraries boost_signals)
 332         else()
 333                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 334         endif()
 335         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 336         include_directories(${TOP_SRC_DIR}/boost)
 337         add_subdirectory(boost)
 338 endif()
 339
 340
 341
 342
 343 if(WIN32)
 344         if(NOT LYX_CONSOLE)
 345                 set(WIN32_CONSOLE WIN32)
 346                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 347         endif()
 348         if(MSVC)
 349                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 350                 # disable checked iterators for msvc release builds to get maximum speed
 351                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 352         else()
 353                 add_definitions(-DWINVER=0x0500)
 354         endif()
 355 endif()
 356
 357 message(STATUS "")
 358 foreach(_v PACKAGE PACKAGE_VERSION
 359         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 360         LYX_ABS_TOP_SRCDIR
 361         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 362         if(NOT DEFINED ${_v})
 363                 message(FATAL_ERROR "${_v} not defined")
 364         endif()
 365         string(SUBSTRING "${_v}                            " 0 28 _v1)
 366         message(STATUS "----- ${_v1}: ${${_v}}")
 367 endforeach(_v)
 368 message(STATUS "")
 369
 370
 371 if(LYX_PCH)
 372         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 373         # Not sure if it works for all non-msvc compilers
 374         include(PCHSupport_26)
 375         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${TOP_BINARY_DIR}/pcheaders.h)
 376         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 377         add_definitions(-DLYX_ENABLE_PCH)
 378
 379         if(MSVC)
 380                 macro(lyx_add_msvc_pch name_)
 381                         set_source_files_properties(${${name_}_sources} PROPERTIES
 382                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 383                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 384                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 385                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 386                                 ${TOP_BINARY_DIR}/pcheaders.h)
 387                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 388                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 389                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 390                 endmacro(lyx_add_msvc_pch)
 391                 macro(lyx_add_gcc_pch name_)
 392                 endmacro()
 393         else()
 394                 macro(lyx_add_msvc_pch name_)
 395                 endmacro()
 396                 macro(lyx_add_gcc_pch name_)
 397                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 398                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 399                 endmacro()
 400         endif()
 401 else()
 402         macro(lyx_add_msvc_pch)
 403         endmacro(lyx_add_msvc_pch)
 404         macro(lyx_add_gcc_pch name_)
 405         endmacro()
 406 endif()
 407
 408 if(MSVC)
 409         if(LYX_VLD)
 410                 set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 411                 set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 412                 set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 413                 include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 414         endif()
 415
 416         if(LYX_WALL)
 417                 # Use the highest warning level
 418                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 419
 420                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 421                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 422                 else()
 423                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 424                 endif()
 425
 426                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 427                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 428                 else()
 429                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 430                 endif()
 431
 432                 # add here warnings which should produce an error /weXXXX
 433                 set(MSVC_W_ERROR   "/we4101 /we4189")
 434                 # add here warnings which should be disabled /wdXXXX
 435                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 436
 437                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 438                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 439                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 440
 441         else()
 442                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 443
 444                 # add here warnings which should produce an error /weXXXX
 445                 set(MSVC_W_ERROR   "/we4101 /we4189")
 446                 # add here warnings which should be disabled /wdXXXX
 447                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 448
 449                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 450                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 451                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 452
 453         endif()
 454         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 455         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 456         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 457
 458         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 459         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 460         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 461         message(STATUS "")
 462 endif()
 463
 464
 465 if(LYX_DEBUG_GLIBC)
 466         set(_GLIBCXX_DEBUG 1)
 467 endif()
 468
 469 if(LYX_DEBUG_GLIBC_PEDANTIC)
 470         set(_GLIBCXX_DEBUG_PEDANTIC 1)
 471 endif()
 472
 473 # compiler tests, config.h generation
 474 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 475         configure_file(configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 476 else()
 477         include(ConfigureChecks.cmake)
 478         configure_file(configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 479 endif()
 480
 481 configure_file(config.h.cmake ${TOP_BINARY_DIR}/config.h)
 482
 483
 484 add_subdirectory(src)
 485 add_subdirectory(lyx2lyx)
 486 add_subdirectory(scripts)
 487
 488
 489 if(LYX_INSTALL)
 490         FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 491         if(${LYX_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 492                 message(FATAL_ERROR "Perl required!")
 493         endif()
 494         add_subdirectory(man)
 495         add_subdirectory(doc)
 496         include(../Install)
 497 endif()
 498
 499
 500 message(STATUS)
 501 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=1 or 0:")
 502 message(STATUS)
 503 LYX_OPTION_LIST_ALL()
 504
 505
 506 set(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 507 set(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 508 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 509
 510 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 511 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 512
 513 set(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 514
 515 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 516 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 517 #
 518 # needed by rpm
 519 set(CPACK_SET_DESTDIR "ON")
 520 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 521 set(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 522 set(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 523 #
 524 # the next ones are needed by deb
 525 set(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 526 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 527
 528 # This is experimental, valid on _my_ system (Kornel)
 529 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 530 if(ASPELL_FOUND)
 531         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 532 endif()
 533 if(ENCHANT_FOUND)
 534         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libenchant1c2a (>= 1.6.0-0),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 535 endif()
 536 if(LYX_EXTERNAL_BOOST)
 537         if(Boost_FOUND)
 538                 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libboost-regex1.40.0 (>= 1.40.0-4),libboost-signals1.40.0 (>= 1.40.0-4),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 539         endif()
 540 endif()
 541 #
 542 # for the next ones, cpack insists on data with values in some file
 543 set(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 544 set(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 545
 546 # Find the revision number and use it as the release in rpm-package-build.
 547 # This way we may omit the otherwise needed "--force" parameter when
 548 # installing from that rpm package.
 549 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 550 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 551 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 552         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 553         # We use this value also to set the package-patch-value
 554         if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 555                 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 556         endif()
 557 endif()
 558
 559 # we do not have a readme or welcome data,
 560 # so we do not provide infofiles for
 561 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 562
 563 if(LYX_CPACK)
 564         include(CPack)
 565 endif()
 566
 567 #Now it is possible to create some packages
 568 # cd <BuildDir>
 569 # make package
 570 #############################################################################################
 571 # So, e.g. for variables
 572 #    CMAKE_PROJECT_NAME                     : lyx
 573 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 574 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 575 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 576 #    CMAKE_SYSTEM_NAME                      : Linux
 577 #    CPACK_BINARY_DEB:BOOL                  : ON
 578 #
 579 # the package name builds as "lyx-2.0.1-Linux.deb"
 580 #
 581 ############################## rpm ################################### deb ##################
 582 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 583 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 584 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 585 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 586 #
 587 message(STATUS)