development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif()
  15
  16 set(LYX_PROJECT lyx)
  17 project(${LYX_PROJECT})
  18
  19 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  20
  21 # Supress regeneration
  22 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  23
  24 # where to look first for cmake modules,
  25 # before ${CMAKE_ROOT}/Modules is checked
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  27 include(LyXMacros)
  28
  29
  30 # Usage LYX_OPTION
  31 # 1. parameter: option name without prefix 'LYX_'
  32 # 2. parameter: description
  33 # 3. parameter: default value, ON or OFF
  34 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  35
  36
  37 LYX_OPTION_INIT()
  38
  39 LYX_OPTION(CPACK "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  40 if(LYX_CPACK)
  41         set(LYX_INSTALL ON CACHE BOOL "INSTALL option" FORCE)
  42 endif()
  43
  44 LYX_OPTION(INSTALL "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  45 if(LYX_INSTALL)
  46         set(LYX_NLS ON CACHE BOOL "Nls option" FORCE)
  47         set(LYX_ASPELL ON CACHE BOOL "Aspell option" FORCE)
  48         if (WIN32)
  49                 set(LYX_HUNSPELL ON CACHE BOOL "Hunspell option" FORCE)
  50         endif()
  51         set(LYX_NO_CONSOLE ON CACHE BOOL "No console option" FORCE)
  52         set(LYX_PACKAGE_SUFFIX ON CACHE BOOL "Package suffix option" FORCE)
  53         set(LYX_RELEASE ON CACHE BOOL "Release option" FORCE)
  54         set(LYX_DEBUG OFF CACHE BOOL "Debug option" FORCE)
  55         set(LYX_PROFILE OFF CACHE BOOL "Profile option" FORCE)
  56 endif()
  57
  58 LYX_OPTION(NLS "Use nls" OFF ALL)
  59 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  60 LYX_OPTION(ENCHANT "Require Enchant" OFF ALL)
  61 LYX_OPTION(HUNSPELL "Require Hunspell" OFF ALL)
  62 LYX_OPTION(DEBUG "Build debug version" OFF ALL)
  63 LYX_OPTION(DEVEL_VERSION "Build developer version" OFF ALL)
  64 LYX_OPTION(RELEASE "Build release version" ON ALL)
  65 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  66 LYX_OPTION(USE_EXTERNAL_BOOST "Use external boost" OFF GCC)
  67 LYX_OPTION(USE_EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  68 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" ON ALL)
  69 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  70 LYX_OPTION(INSTALL_PREFIX "Install path for LyX" OFF ALL)
  71 LYX_OPTION(NO_CONSOLE "Suppress console on Windows" OFF MSVC)
  72 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  73 LYX_OPTION(WALL "Enable all warnings" OFF MSVC)
  74 LYX_OPTION(DISABLE_PCH "Disable precompiled headers" ON ALL)
  75 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  76 LYX_OPTION(MERGE_REBUILD "Rebuild generated files from merged files build" OFF ALL)
  77 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  78 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  79 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  80 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  81 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  82
  83
  84 message(STATUS)
  85
  86 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  87 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  88
  89
  90
  91 if(UNIX OR MINGW)
  92         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
  93         message(STATUS "Using GCC version ${GCC_VERSION}")
  94         if(NOT GCC_VERSION VERSION_LESS 4.4)
  95                 set(LYX_USE_TR1 1)
  96                 # GCC <= 4.5 does not support regex: there are linker errors
  97                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
  98                 set(LYX_USE_TR1_REGEX 0)
  99         endif()
 100 else()
 101         if(MSVC10)
 102                 set(LYX_USE_TR1 1)
 103                 set(LYX_USE_TR1_REGEX 1)
 104         endif()
 105 endif()
 106
 107
 108 set(VERSION_INFO "CMake Build")
 109
 110 # Try to get some informations from configure.ac
 111
 112 include(LyXPaths)    #called here to define the needed TOP_SRC_DIR-variable
 113 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 114
 115 if(WIN32)
 116         set(USE_WINDOWS_PACKAGING 1)
 117 elseif(APPLE)
 118         set(USE_MACOSX_PACKAGING 1)
 119 else()
 120         set(USE_POSIX_PACKAGING 1)
 121 endif()
 122
 123 macro(setstripped _varname _value)
 124         string(STRIP ${_value} _v)
 125         if(USE_POSIX_PACKAGING)
 126                 string(TOLOWER ${_v} ${_varname})
 127         else()
 128                 set(${_varname} ${_v})
 129         endif()
 130 endmacro(setstripped)
 131
 132 foreach(_c_l ${_config_lines} )
 133         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 134                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 135                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 136                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 137                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 138                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 139                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 140                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 141                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 142                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 143                 endif()
 144         endif()
 145         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 146                 set(LYX_DATE "${CMAKE_MATCH_1}")
 147         endif()
 148 endforeach(_c_l)
 149
 150
 151 if (LYX_INSTALL_PREFIX)
 152         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 153         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 154 endif()
 155
 156 if(LYX_PACKAGE_SUFFIX)
 157         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 158 else()
 159         set(PACKAGE ${PACKAGE_BASE})
 160 endif()
 161
 162 if(LYX_PROGRAM_SUFFIX)
 163         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 164 else()
 165         set(PROGRAM_SUFFIX "")
 166 endif()
 167
 168
 169 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 170         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 171         if (UNIX)
 172                 # don't use the default "/usr/local"
 173                 # but respect the user-choice on the command-line
 174                 if(LYX_INSTALL_SUFFIX)
 175                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 176                 else()
 177                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 178                 endif()
 179         endif()
 180         if(WIN32)
 181                 set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 182         endif()
 183 endif()
 184
 185 if (WIN32)
 186         set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 187 else()
 188         set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 189 endif()
 190
 191 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 192 set(LYX_LOCALEDIR "locale")
 193 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 194 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 195
 196
 197 if(NOT GROUP_CODE)
 198         #set(GROUP_CODE "The Golden Code")
 199         set(GROUP_CODE flat)
 200 endif()
 201
 202 # lyx's source files
 203 set(LYX_CPP_FILES *.cpp)
 204 set(LYX_HPP_FILES *.h)
 205 set(LYX_MOC_FILES moc_*.cpp)
 206
 207
 208 include(ProjectSourceGroup)
 209
 210
 211 if(LYX_PROFILE)
 212         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 213         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 214 endif()
 215
 216 if(LYX_RELEASE)
 217         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 218 endif()
 219
 220 if(LYX_DEBUG)
 221         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 222 endif()
 223
 224 # When shared libs are supported enable this option
 225 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 226 if(LYX_SHARED_LIBRARIES)
 227         set(library_type SHARED)
 228 else()
 229         set(library_type STATIC)
 230 endif()
 231
 232 if(NOT MSVC)
 233         if(NOT LYX_QUIET)
 234                 set(CMAKE_VERBOSE_MAKEFILE ON)
 235         endif()
 236         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 237         if(LYX_STDLIB_DEBUG)
 238                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 239         endif()
 240         if(LYX_CONCEPT_CHECKS)
 241                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 242         endif()
 243         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 244         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 245         if(MINGW)
 246                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 247         else()
 248                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 249         endif()
 250         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 251 endif()
 252
 253
 254 find_package(Qt4 REQUIRED)
 255 find_package(ICONV REQUIRED)
 256 find_package(ZLIB REQUIRED)
 257
 258 include_directories(${CMAKE_BINARY_DIR} ${TOP_SRC_DIR}/src)
 259
 260 if(LYX_ASPELL)
 261         find_package(ASPELL)
 262         include_directories(${ASPELL_INCLUDE_DIR})
 263 endif()
 264
 265 if(LYX_ENCHANT)
 266         find_package(Enchant REQUIRED)
 267         include_directories(${ENCHANT_INCLUDE_DIR})
 268 endif()
 269
 270 if(LYX_HUNSPELL)
 271         find_package(Hunspell REQUIRED)
 272         include_directories(${HUNSPELL_INCLUDE_DIR})
 273 endif()
 274
 275 if(LYX_NLS)
 276         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python)
 277         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 278                 message(FATAL_ERROR "Python 2.6 needed!")
 279         endif()
 280         find_package(LyXGettext REQUIRED)
 281         include_directories(${TOP_SRC_DIR}/po)
 282         add_subdirectory(po)
 283 endif()
 284
 285 if(LYX_USE_EXTERNAL_LIBINTL)
 286         find_package(Libintl REQUIRED)
 287         add_definitions(-DHAVE_GETTEXT) #TODO move to config.h
 288 else()
 289         add_subdirectory(intl)
 290 endif()
 291
 292 if(LYX_USE_EXTERNAL_BOOST)
 293         message(STATUS "Searching for boost")
 294         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 295         if(Boost_FOUND)
 296                 message(STATUS "Boost found")
 297                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 298                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 299         else()
 300                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 301         endif()
 302 else()
 303         if(LYX_USE_TR1_REGEX)
 304                 set(Lyx_Boost_Libraries boost_signals)
 305         else()
 306                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 307         endif()
 308         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 309         include_directories(${TOP_SRC_DIR}/boost)
 310         add_subdirectory(boost)
 311 endif()
 312
 313
 314
 315
 316 if(WIN32)
 317         if(LYX_NO_CONSOLE)
 318                 set(WIN32_CONSOLE WIN32)
 319                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 320         endif()
 321         if(MSVC)
 322                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 323                 # disable checked iterators for msvc release builds to get maximum speed
 324                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 325         else()
 326                 add_definitions(-DWINVER=0x0500)
 327         endif()
 328 endif()
 329
 330 message(STATUS "")
 331 foreach(_v PACKAGE PACKAGE_VERSION
 332         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 333         LYX_ABS_TOP_SRCDIR
 334         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 335         if(NOT DEFINED ${_v})
 336                 message(FATAL_ERROR "${_v} not defined")
 337         endif()
 338         string(SUBSTRING "${_v}                            " 0 28 _v1)
 339         message(STATUS "----- ${_v1}: ${${_v}}")
 340 endforeach(_v)
 341 message(STATUS "")
 342
 343
 344 # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 345 # Not sure if it works for all non-msvc compilers
 346 include(PCHSupport_26)
 347
 348 if(NOT LYX_DISABLE_PCH)
 349         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 350         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 351         add_definitions(-DLYX_ENABLE_PCH)
 352
 353         if(MSVC AND NOT MERGE_FILES)
 354                 macro(lyx_add_msvc_pch name_)
 355                         set_source_files_properties(${${name_}_sources} PROPERTIES
 356                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 357                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 358                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 359                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 360                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 361                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 362                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 363                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 364                 endmacro(lyx_add_msvc_pch)
 365                 macro(lyx_add_gcc_pch name_)
 366                 endmacro()
 367         else()
 368                 macro(lyx_add_msvc_pch name_)
 369                 endmacro()
 370                 macro(lyx_add_gcc_pch name_)
 371                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 372                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 373                 endmacro()
 374         endif()
 375 else()
 376         set(LYX_DISABLE_PCH TRUE CACHE TYPE STRING)
 377         macro(lyx_add_msvc_pch)
 378         endmacro(lyx_add_msvc_pch)
 379         macro(lyx_add_gcc_pch name_)
 380         endmacro()
 381 endif()
 382
 383 if(MSVC)
 384         if(LYX_VLD)
 385                 set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 386                 set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 387                 set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 388                 include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 389         endif()
 390
 391         # TODO options
 392         if(LYX_WALL)
 393                 # Use the highest warning level
 394                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 395
 396                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 397                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 398                 else()
 399                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 400                 endif()
 401
 402                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 403                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 404                 else()
 405                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 406                 endif()
 407
 408                 # add here warnings which should produce an error /weXXXX
 409                 set(MSVC_W_ERROR   "/we4101 /we4189")
 410                 # add here warnings which should be disabled /wdXXXX
 411                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 412
 413                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 414                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 415                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 416
 417         else()
 418                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 419
 420                 # add here warnings which should produce an error /weXXXX
 421                 set(MSVC_W_ERROR   "/we4101 /we4189")
 422                 # add here warnings which should be disabled /wdXXXX
 423                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 424
 425                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 426                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 427                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 428
 429         endif()
 430         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 431         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 432         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 433
 434         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 435         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 436         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 437         message(STATUS "")
 438 endif()
 439
 440
 441 if(LYX_DEBUG_GLIBC)
 442         set(_GLIBCXX_DEBUG 1)
 443 endif()
 444
 445 if(LYX_DEBUG_GLIBC_PEDANTIC)
 446         set(_GLIBCXX_DEBUG_PEDANTIC 1)
 447 endif()
 448
 449 # compiler tests, config.h generation
 450 if(MSVC AND NOT CONFIGURECHECKS)
 451         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 452 else()
 453         include(ConfigureChecks.cmake)
 454         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 455 endif()
 456
 457 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 458
 459
 460 add_subdirectory(src)
 461 add_subdirectory(lyx2lyx)
 462 add_subdirectory(scripts)
 463
 464
 465 if(LYX_INSTALL)
 466         FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 467         if(${LYX_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 468                 message(FATAL_ERROR "Perl required!")
 469         endif()
 470         add_subdirectory(man)
 471         add_subdirectory(doc)
 472         include(../Install)
 473 endif()
 474
 475
 476 message(STATUS)
 477 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=1 or 0:")
 478 message(STATUS)
 479 LYX_OPTION_LIST_ALL()
 480
 481
 482 set(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 483 set(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 484 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 485
 486 set(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 487 #
 488 # needed by rpm
 489 set(CPACK_SET_DESTDIR "ON")
 490 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 491 set(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 492 set(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 493 #
 494 # the next ones are needed by deb
 495 set(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 496 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 497
 498 # This is experimental, valid on _my_ system (Kornel)
 499 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 500 if(ASPELL_FOUND)
 501         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 502 endif()
 503 if(ENCHANT_FOUND)
 504         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libenchant1c2a (>= 1.6.0-0),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 505 endif()
 506 if(LYX_USE_EXTERNAL_BOOST)
 507         if(Boost_FOUND)
 508                 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libboost-regex1.40.0 (>= 1.40.0-4),libboost-signals1.40.0 (>= 1.40.0-4),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 509         endif()
 510 endif()
 511 #
 512 # for the next ones, cpack insists on data with values in some file
 513 set(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 514 set(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 515
 516 # Find the revision number and use it as the release in rpm-package-build.
 517 # This way we may omit the otherwise needed "--force" parameter when
 518 # installing from that rpm package.
 519 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 520 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 521 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 522         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 523         # We use this value also to set the package-patch-value
 524         if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 525                 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 526         endif()
 527 endif()
 528
 529 # we do not have a readme or welcome data,
 530 # so we do not provide infofiles for
 531 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 532
 533 include(CPack)
 534
 535 #Now it is possible to create some packages
 536 # cd <BuildDir>
 537 # make package
 538 #############################################################################################
 539 # So, e.g. for variables
 540 #    CMAKE_PROJECT_NAME                     : lyx
 541 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 542 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 543 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 544 #    CMAKE_SYSTEM_NAME                      : Linux
 545 #    CPACK_BINARY_DEB:BOOL                  : ON
 546 #
 547 # the package name builds as "lyx-2.0.1-Linux.deb"
 548 #
 549 ############################## rpm ################################### deb ##################
 550 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 551 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 552 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 553 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 554 #
 555 message(STATUS)