development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif()
  15
  16 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  17
  18 # Supress regeneration
  19 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  20
  21 # where to look first for cmake modules,
  22 # before ${CMAKE_ROOT}/Modules is checked
  23 include(LyXMacros)
  24
  25
  26 # Usage LYX_OPTION
  27 # 1. parameter: option name without prefix 'LYX_'
  28 # 2. parameter: description
  29 # 3. parameter: default value, ON or OFF
  30 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  31
  32
  33 LYX_OPTION_INIT()
  34
  35 # Options for all compilers/systems
  36 LYX_OPTION(CPACK "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  37 LYX_OPTION(INSTALL "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  38 LYX_OPTION(NLS "Use nls" OFF ALL)
  39 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  40 LYX_OPTION(ENCHANT "Require Enchant" OFF ALL)
  41 LYX_OPTION(HUNSPELL "Require Hunspell" OFF ALL)
  42 LYX_OPTION(DEVEL_VERSION "Build developer version" OFF ALL)
  43 LYX_OPTION(RELEASE "Build release version, build debug when disabled" ON ALL)
  44 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" ON ALL)
  45 LYX_OPTION(PCH "Use precompiled headers" OFF ALL)
  46 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  47 LYX_OPTION(MERGE_REBUILD "Rebuild generated files from merged files build" OFF ALL)
  48 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  49 LYX_OPTION(INSTALL_PREFIX "Install path for LyX" OFF ALL)
  50 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  51
  52 # GCC specific
  53 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  54 LYX_OPTION(EXTERNAL_BOOST "Use external boost" OFF GCC)
  55 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  56 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  57 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  58 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  59 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  60
  61 # MSVC specific
  62 LYX_OPTION(CONSOLE "Show console on Windows" ON MSVC)
  63 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  64 LYX_OPTION(WALL "Enable all warnings" OFF MSVC)
  65 LYX_OPTION(CONFIGURE_CHECKS "Also run configure checks for MSVC" OFF MSVC)
  66 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
  67
  68 # Check option dependencies
  69 if(LYX_CPACK)
  70         set(LYX_INSTALL ON)
  71 endif()
  72
  73 if(LYX_INSTALL)
  74         set(LYX_NLS ON)
  75         if (WIN32)
  76                 set(LYX_HUNSPELL ON)
  77         endif()
  78         set(LYX_CONSOLE OFF)
  79         set(LYX_PACKAGE_SUFFIX ON)
  80         set(LYX_RELEASE ON)
  81         set(LYX_PROFILE OFF)
  82 endif()
  83
  84 if(LYX_MERGE_FILES)
  85         set(LYX_PCH OFF)
  86 else()
  87         set(LYX_MERGE_REBUILD OFF)
  88 endif()
  89
  90 if(LYX_DEPENDENCIES_DOWNLOAD)
  91         message(STATUS)
  92         set(LYX_DEPENDENCIES_DIR ${TOP_BINARY_DIR}/msvc2010-deps)
  93         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
  94         set(deps_files lyx20-deps-msvc2010-x86.zip)
  95         foreach(it ${deps_files})
  96                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
  97                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
  98                 if(NOT already_downloaded)
  99                         message(STATUS "Downloading ${it} ...")
 100                         file(DOWNLOAD ftp://ftp.devel.lyx.org/pub/contrib/windows/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS)
 101                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 102                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 103                 endif()
 104         endforeach()
 105         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 106 endif()
 107
 108
 109 message(STATUS)
 110
 111 set(EXECUTABLE_OUTPUT_PATH  ${TOP_BINARY_DIR}/bin)
 112 set(LIBRARY_OUTPUT_PATH  ${TOP_BINARY_DIR}/lib)
 113
 114
 115
 116 if(UNIX OR MINGW)
 117         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 118         message(STATUS "Using GCC version ${GCC_VERSION}")
 119         if(NOT GCC_VERSION VERSION_LESS 4.4)
 120                 set(LYX_USE_TR1 1)
 121                 # GCC <= 4.5 does not support regex: there are linker errors
 122                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 123                 set(LYX_USE_TR1_REGEX 0)
 124         endif()
 125 else()
 126         if(MSVC10)
 127                 set(LYX_USE_TR1 1)
 128                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 129         endif()
 130 endif()
 131
 132
 133 set(VERSION_INFO "CMake Build")
 134
 135 # Try to get some informations from configure.ac
 136
 137 include(LyXPaths)    #called here to define the needed TOP_SRC_DIR-variable
 138 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 139
 140 if(WIN32)
 141         set(USE_WINDOWS_PACKAGING 1)
 142 elseif(APPLE)
 143         set(USE_MACOSX_PACKAGING 1)
 144 else()
 145         set(USE_POSIX_PACKAGING 1)
 146 endif()
 147
 148 macro(setstripped _varname _value)
 149         string(STRIP ${_value} _v)
 150         if(USE_POSIX_PACKAGING)
 151                 string(TOLOWER ${_v} ${_varname})
 152         else()
 153                 set(${_varname} ${_v})
 154         endif()
 155 endmacro(setstripped)
 156
 157 foreach(_c_l ${_config_lines} )
 158         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 159                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 160                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 161                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 162                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 163                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 164                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 165                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 166                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 167                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 168                 endif()
 169         endif()
 170         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 171                 set(LYX_DATE "${CMAKE_MATCH_1}")
 172         endif()
 173 endforeach(_c_l)
 174
 175
 176 if (LYX_INSTALL_PREFIX)
 177         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 178         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 179 endif()
 180 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 181
 182 if(LYX_PACKAGE_SUFFIX)
 183         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 184 else()
 185         set(PACKAGE ${PACKAGE_BASE})
 186 endif()
 187
 188 if(LYX_PROGRAM_SUFFIX)
 189         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 190 else()
 191         set(PROGRAM_SUFFIX "")
 192 endif()
 193
 194
 195 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 196         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 197         if (UNIX)
 198                 # don't use the default "/usr/local"
 199                 # but respect the user-choice on the command-line
 200                 if(LYX_INSTALL_SUFFIX)
 201                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 202                 else()
 203                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 204                 endif()
 205         endif()
 206         if(WIN32)
 207                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 208         endif()
 209 endif()
 210
 211 if (WIN32)
 212         set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 213 else()
 214         set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 215 endif()
 216
 217 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 218 set(LYX_LOCALEDIR "locale")
 219 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 220 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 221
 222
 223 if(NOT GROUP_CODE)
 224         #set(GROUP_CODE "The Golden Code")
 225         set(GROUP_CODE flat)
 226 endif()
 227
 228 # lyx's source files
 229 set(LYX_CPP_FILES *.cpp)
 230 set(LYX_HPP_FILES *.h)
 231 set(LYX_MOC_FILES moc_*.cpp)
 232
 233
 234 include(ProjectSourceGroup)
 235
 236
 237 if(LYX_PROFILE)
 238         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 239         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 240 endif()
 241
 242 if(LYX_RELEASE)
 243         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build release version" FORCE)
 244 else()
 245         set(CMAKE_BUILD_TYPE Debug CACHE STRING "Build debug version" FORCE)
 246 endif()
 247
 248 # When shared libs are supported enable this option
 249 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 250 if(LYX_SHARED_LIBRARIES)
 251         set(library_type SHARED)
 252 else()
 253         set(library_type STATIC)
 254 endif()
 255
 256 if(NOT MSVC)
 257         if(NOT LYX_QUIET)
 258                 set(CMAKE_VERBOSE_MAKEFILE ON)
 259         endif()
 260         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 261         if(LYX_STDLIB_DEBUG)
 262                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 263         endif()
 264         if(LYX_CONCEPT_CHECKS)
 265                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 266         endif()
 267         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 268         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 269         if(MINGW)
 270                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 271         else()
 272                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 273         endif()
 274         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 275 endif()
 276
 277
 278 find_package(Qt4 REQUIRED)
 279 find_package(ICONV REQUIRED)
 280 find_package(ZLIB REQUIRED)
 281
 282 include_directories(${TOP_BINARY_DIR} ${TOP_SRC_DIR}/src)
 283
 284 if(LYX_ASPELL)
 285         find_package(ASPELL)
 286         include_directories(${ASPELL_INCLUDE_DIR})
 287 endif()
 288
 289 if(LYX_ENCHANT)
 290         find_package(Enchant REQUIRED)
 291         include_directories(${ENCHANT_INCLUDE_DIR})
 292 endif()
 293
 294 if(LYX_HUNSPELL)
 295         find_package(Hunspell REQUIRED)
 296         include_directories(${HUNSPELL_INCLUDE_DIR})
 297 endif()
 298
 299 if(LYX_NLS)
 300         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python HINTS ${GNUWIN32_DIR}/python)
 301         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 302                 message(FATAL_ERROR "Python 2.6 needed!")
 303         endif()
 304         find_package(LyXGettext REQUIRED)
 305         include_directories(${TOP_SRC_DIR}/po)
 306         add_subdirectory(po)
 307 endif()
 308
 309 if(LYX_EXTERNAL_LIBINTL)
 310         find_package(Libintl REQUIRED)
 311         add_definitions(-DHAVE_GETTEXT) #TODO move to config.h
 312 else()
 313         if(LYX_NLS)
 314                 add_subdirectory(intl)
 315         else()
 316                 # do not compile if nls disabled
 317         endif()
 318 endif()
 319
 320 if(LYX_EXTERNAL_BOOST)
 321         message(STATUS "Searching for boost")
 322         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 323         if(Boost_FOUND)
 324                 message(STATUS "Boost found")
 325                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 326                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 327         else()
 328                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 329         endif()
 330 else()
 331         if(LYX_USE_TR1_REGEX)
 332                 set(Lyx_Boost_Libraries boost_signals)
 333         else()
 334                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 335         endif()
 336         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 337         include_directories(${TOP_SRC_DIR}/boost)
 338         add_subdirectory(boost)
 339 endif()
 340
 341
 342
 343
 344 if(WIN32)
 345         if(NOT LYX_CONSOLE)
 346                 set(WIN32_CONSOLE WIN32)
 347                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 348         endif()
 349         if(MSVC)
 350                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 351                 # disable checked iterators for msvc release builds to get maximum speed
 352                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 353         else()
 354                 add_definitions(-DWINVER=0x0500)
 355         endif()
 356 endif()
 357
 358 message(STATUS "")
 359 foreach(_v PACKAGE PACKAGE_VERSION
 360         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 361         LYX_ABS_TOP_SRCDIR
 362         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 363         if(NOT DEFINED ${_v})
 364                 message(FATAL_ERROR "${_v} not defined")
 365         endif()
 366         string(SUBSTRING "${_v}                            " 0 28 _v1)
 367         message(STATUS "----- ${_v1}: ${${_v}}")
 368 endforeach(_v)
 369 message(STATUS "")
 370
 371
 372 if(LYX_PCH)
 373         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 374         # Not sure if it works for all non-msvc compilers
 375         include(PCHSupport_26)
 376         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${TOP_BINARY_DIR}/pcheaders.h)
 377         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${TOP_BINARY_DIR}/config_pch.cpp)
 378         add_definitions(-DLYX_ENABLE_PCH)
 379
 380         if(MSVC)
 381                 macro(lyx_add_msvc_pch name_)
 382                         set_source_files_properties(${${name_}_sources} PROPERTIES
 383                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 384                         set_source_files_properties(${TOP_BINARY_DIR}/config_pch.cpp PROPERTIES
 385                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 386                         set(${name_}_sources ${${name_}_sources} ${TOP_BINARY_DIR}/config_pch.cpp
 387                                 ${TOP_BINARY_DIR}/pcheaders.h)
 388                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 389                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 390                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 391                 endmacro(lyx_add_msvc_pch)
 392                 macro(lyx_add_gcc_pch name_)
 393                 endmacro()
 394         else()
 395                 macro(lyx_add_msvc_pch name_)
 396                 endmacro()
 397                 macro(lyx_add_gcc_pch name_)
 398                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 399                         ADD_PRECOMPILED_HEADER(${name_} ${TOP_BINARY_DIR}/config_pch.cpp ${TOP_BINARY_DIR}/config.h.gch)
 400                 endmacro()
 401         endif()
 402 else()
 403         macro(lyx_add_msvc_pch)
 404         endmacro(lyx_add_msvc_pch)
 405         macro(lyx_add_gcc_pch name_)
 406         endmacro()
 407 endif()
 408
 409 if(MSVC)
 410         if(LYX_VLD)
 411                 set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 412                 set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 413                 set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 414                 include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 415         endif()
 416
 417         if(LYX_WALL)
 418                 # Use the highest warning level
 419                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 420
 421                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 422                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 423                 else()
 424                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 425                 endif()
 426
 427                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 428                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 429                 else()
 430                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 431                 endif()
 432
 433                 # add here warnings which should produce an error /weXXXX
 434                 set(MSVC_W_ERROR   "/we4101 /we4189")
 435                 # add here warnings which should be disabled /wdXXXX
 436                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 437
 438                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 439                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 440                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 441
 442         else()
 443                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 444
 445                 # add here warnings which should produce an error /weXXXX
 446                 set(MSVC_W_ERROR   "/we4101 /we4189")
 447                 # add here warnings which should be disabled /wdXXXX
 448                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 449
 450                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 451                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 452                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 453
 454         endif()
 455         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 456         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 457         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 458
 459         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 460         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 461         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 462         message(STATUS "")
 463 endif()
 464
 465
 466 if(LYX_DEBUG_GLIBC)
 467         set(_GLIBCXX_DEBUG 1)
 468 endif()
 469
 470 if(LYX_DEBUG_GLIBC_PEDANTIC)
 471         set(_GLIBCXX_DEBUG_PEDANTIC 1)
 472 endif()
 473
 474 # compiler tests, config.h generation
 475 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 476         configure_file(configCompiler.h.msvc ${TOP_BINARY_DIR}/configCompiler.h)
 477 else()
 478         include(ConfigureChecks.cmake)
 479         configure_file(configCompiler.h.cmake ${TOP_BINARY_DIR}/configCompiler.h)
 480 endif()
 481
 482 configure_file(config.h.cmake ${TOP_BINARY_DIR}/config.h)
 483
 484
 485 add_subdirectory(src)
 486 add_subdirectory(lyx2lyx)
 487 add_subdirectory(scripts)
 488
 489
 490 if(LYX_INSTALL)
 491         FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 492         if(${LYX_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 493                 message(FATAL_ERROR "Perl required!")
 494         endif()
 495         add_subdirectory(man)
 496         add_subdirectory(doc)
 497         include(../Install)
 498 endif()
 499
 500
 501 message(STATUS)
 502 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=1 or 0:")
 503 message(STATUS)
 504 LYX_OPTION_LIST_ALL()
 505
 506
 507 set(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 508 set(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 509 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 510
 511 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 512 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 513
 514 set(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 515
 516 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 517 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 518 #
 519 # needed by rpm
 520 set(CPACK_SET_DESTDIR "ON")
 521 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 522 set(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 523 set(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 524 #
 525 # the next ones are needed by deb
 526 set(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 527 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 528
 529 # This is experimental, valid on _my_ system (Kornel)
 530 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 531 if(ASPELL_FOUND)
 532         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 533 endif()
 534 if(ENCHANT_FOUND)
 535         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libenchant1c2a (>= 1.6.0-0),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 536 endif()
 537 if(LYX_EXTERNAL_BOOST)
 538         if(Boost_FOUND)
 539                 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libboost-regex1.40.0 (>= 1.40.0-4),libboost-signals1.40.0 (>= 1.40.0-4),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 540         endif()
 541 endif()
 542 #
 543 # for the next ones, cpack insists on data with values in some file
 544 set(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 545 set(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 546
 547 # Find the revision number and use it as the release in rpm-package-build.
 548 # This way we may omit the otherwise needed "--force" parameter when
 549 # installing from that rpm package.
 550 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 551 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 552 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 553         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 554         # We use this value also to set the package-patch-value
 555         if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 556                 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 557         endif()
 558 endif()
 559
 560 # we do not have a readme or welcome data,
 561 # so we do not provide infofiles for
 562 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 563
 564 if(LYX_CPACK)
 565         include(CPack)
 566 endif()
 567
 568 #Now it is possible to create some packages
 569 # cd <BuildDir>
 570 # make package
 571 #############################################################################################
 572 # So, e.g. for variables
 573 #    CMAKE_PROJECT_NAME                     : lyx
 574 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 575 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 576 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 577 #    CMAKE_SYSTEM_NAME                      : Linux
 578 #    CPACK_BINARY_DEB:BOOL                  : ON
 579 #
 580 # the package name builds as "lyx-2.0.1-Linux.deb"
 581 #
 582 ############################## rpm ################################### deb ##################
 583 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 584 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 585 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 586 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 587 #
 588 message(STATUS)