development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif()
  15
  16 set(LYX_PROJECT lyx)
  17 project(${LYX_PROJECT})
  18
  19 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  20
  21 # Supress regeneration
  22 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  23
  24 # where to look first for cmake modules,
  25 # before ${CMAKE_ROOT}/Modules is checked
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  27 include(LyXMacros)
  28
  29
  30 # Usage LYX_OPTION
  31 # 1. parameter: option name without prefix 'LYX_'
  32 # 2. parameter: description
  33 # 3. parameter: default value, ON or OFF
  34 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  35
  36
  37 LYX_OPTION_INIT()
  38
  39 # Options for all compilers/systems
  40 LYX_OPTION(CPACK "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  41 LYX_OPTION(INSTALL "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  42 LYX_OPTION(NLS "Use nls" OFF ALL)
  43 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  44 LYX_OPTION(ENCHANT "Require Enchant" OFF ALL)
  45 LYX_OPTION(HUNSPELL "Require Hunspell" OFF ALL)
  46 LYX_OPTION(DEVEL_VERSION "Build developer version" OFF ALL)
  47 LYX_OPTION(RELEASE "Build release version, build debug when disabled" ON ALL)
  48 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" ON ALL)
  49 LYX_OPTION(PCH "Use precompiled headers" OFF ALL)
  50 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  51 LYX_OPTION(MERGE_REBUILD "Rebuild generated files from merged files build" OFF ALL)
  52 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  53 LYX_OPTION(INSTALL_PREFIX "Install path for LyX" OFF ALL)
  54 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  55
  56 # GCC specific
  57 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  58 LYX_OPTION(EXTERNAL_BOOST "Use external boost" OFF GCC)
  59 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  60 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  61 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  62 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  63 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  64
  65 # MSVC specific
  66 LYX_OPTION(CONSOLE "Show console on Windows" ON MSVC)
  67 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  68 LYX_OPTION(WALL "Enable all warnings" OFF MSVC)
  69 LYX_OPTION(LYX_CONFIGURE_CHECKS "Also run configure checks for MSVC" OFF MSVC)
  70
  71
  72 # Check option dependencies
  73 if(LYX_CPACK)
  74         set(LYX_INSTALL ON)
  75 endif()
  76
  77 if(LYX_INSTALL)
  78         set(LYX_NLS ON)
  79         set(LYX_ASPELL ON)
  80         if (WIN32)
  81                 set(LYX_HUNSPELL ON)
  82         endif()
  83         set(LYX_CONSOLE OFF)
  84         set(LYX_PACKAGE_SUFFIX ON)
  85         set(LYX_RELEASE ON)
  86         set(LYX_PROFILE OFF)
  87 endif()
  88
  89 if(LYX_MERGE_FILES)
  90         set(LYX_PCH OFF)
  91 else()
  92         set(LYX_MERGE_REBUILD OFF)
  93 endif()
  94
  95
  96
  97 message(STATUS)
  98
  99 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
 100 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
 101
 102
 103
 104 if(UNIX OR MINGW)
 105         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 106         message(STATUS "Using GCC version ${GCC_VERSION}")
 107         if(NOT GCC_VERSION VERSION_LESS 4.4)
 108                 set(LYX_USE_TR1 1)
 109                 # GCC <= 4.5 does not support regex: there are linker errors
 110                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 111                 set(LYX_USE_TR1_REGEX 0)
 112         endif()
 113 else()
 114         if(MSVC10)
 115                 set(LYX_USE_TR1 1)
 116                 set(LYX_USE_TR1_REGEX 1)
 117         endif()
 118 endif()
 119
 120
 121 set(VERSION_INFO "CMake Build")
 122
 123 # Try to get some informations from configure.ac
 124
 125 include(LyXPaths)    #called here to define the needed TOP_SRC_DIR-variable
 126 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 127
 128 if(WIN32)
 129         set(USE_WINDOWS_PACKAGING 1)
 130 elseif(APPLE)
 131         set(USE_MACOSX_PACKAGING 1)
 132 else()
 133         set(USE_POSIX_PACKAGING 1)
 134 endif()
 135
 136 macro(setstripped _varname _value)
 137         string(STRIP ${_value} _v)
 138         if(USE_POSIX_PACKAGING)
 139                 string(TOLOWER ${_v} ${_varname})
 140         else()
 141                 set(${_varname} ${_v})
 142         endif()
 143 endmacro(setstripped)
 144
 145 foreach(_c_l ${_config_lines} )
 146         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 147                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 148                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 149                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 150                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 151                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 152                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 153                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 154                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 155                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 156                 endif()
 157         endif()
 158         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 159                 set(LYX_DATE "${CMAKE_MATCH_1}")
 160         endif()
 161 endforeach(_c_l)
 162
 163
 164 if (LYX_INSTALL_PREFIX)
 165         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 166         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 167 endif()
 168
 169 if(LYX_PACKAGE_SUFFIX)
 170         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 171 else()
 172         set(PACKAGE ${PACKAGE_BASE})
 173 endif()
 174
 175 if(LYX_PROGRAM_SUFFIX)
 176         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 177 else()
 178         set(PROGRAM_SUFFIX "")
 179 endif()
 180
 181
 182 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 183         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 184         if (UNIX)
 185                 # don't use the default "/usr/local"
 186                 # but respect the user-choice on the command-line
 187                 if(LYX_INSTALL_SUFFIX)
 188                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 189                 else()
 190                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 191                 endif()
 192         endif()
 193         if(WIN32)
 194                 set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 195         endif()
 196 endif()
 197
 198 if (WIN32)
 199         set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 200 else()
 201         set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 202 endif()
 203
 204 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 205 set(LYX_LOCALEDIR "locale")
 206 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 207 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 208
 209
 210 if(NOT GROUP_CODE)
 211         #set(GROUP_CODE "The Golden Code")
 212         set(GROUP_CODE flat)
 213 endif()
 214
 215 # lyx's source files
 216 set(LYX_CPP_FILES *.cpp)
 217 set(LYX_HPP_FILES *.h)
 218 set(LYX_MOC_FILES moc_*.cpp)
 219
 220
 221 include(ProjectSourceGroup)
 222
 223
 224 if(LYX_PROFILE)
 225         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 226         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 227 endif()
 228
 229 if(LYX_RELEASE)
 230         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build release version" FORCE)
 231 else()
 232         set(CMAKE_BUILD_TYPE Debug CACHE STRING "Build debug version" FORCE)
 233 endif()
 234
 235 # When shared libs are supported enable this option
 236 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 237 if(LYX_SHARED_LIBRARIES)
 238         set(library_type SHARED)
 239 else()
 240         set(library_type STATIC)
 241 endif()
 242
 243 if(NOT MSVC)
 244         if(NOT LYX_QUIET)
 245                 set(CMAKE_VERBOSE_MAKEFILE ON)
 246         endif()
 247         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 248         if(LYX_STDLIB_DEBUG)
 249                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 250         endif()
 251         if(LYX_CONCEPT_CHECKS)
 252                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 253         endif()
 254         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 255         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 256         if(MINGW)
 257                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 258         else()
 259                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 260         endif()
 261         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 262 endif()
 263
 264
 265 find_package(Qt4 REQUIRED)
 266 find_package(ICONV REQUIRED)
 267 find_package(ZLIB REQUIRED)
 268
 269 include_directories(${CMAKE_BINARY_DIR} ${TOP_SRC_DIR}/src)
 270
 271 if(LYX_ASPELL)
 272         find_package(ASPELL)
 273         include_directories(${ASPELL_INCLUDE_DIR})
 274 endif()
 275
 276 if(LYX_ENCHANT)
 277         find_package(Enchant REQUIRED)
 278         include_directories(${ENCHANT_INCLUDE_DIR})
 279 endif()
 280
 281 if(LYX_HUNSPELL)
 282         find_package(Hunspell REQUIRED)
 283         include_directories(${HUNSPELL_INCLUDE_DIR})
 284 endif()
 285
 286 if(LYX_NLS)
 287         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python)
 288         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 289                 message(FATAL_ERROR "Python 2.6 needed!")
 290         endif()
 291         find_package(LyXGettext REQUIRED)
 292         include_directories(${TOP_SRC_DIR}/po)
 293         add_subdirectory(po)
 294 endif()
 295
 296 if(LYX_EXTERNAL_LIBINTL)
 297         find_package(Libintl REQUIRED)
 298         add_definitions(-DHAVE_GETTEXT) #TODO move to config.h
 299 else()
 300         add_subdirectory(intl)
 301 endif()
 302
 303 if(LYX_EXTERNAL_BOOST)
 304         message(STATUS "Searching for boost")
 305         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 306         if(Boost_FOUND)
 307                 message(STATUS "Boost found")
 308                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 309                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 310         else()
 311                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 312         endif()
 313 else()
 314         if(LYX_USE_TR1_REGEX)
 315                 set(Lyx_Boost_Libraries boost_signals)
 316         else()
 317                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 318         endif()
 319         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 320         include_directories(${TOP_SRC_DIR}/boost)
 321         add_subdirectory(boost)
 322 endif()
 323
 324
 325
 326
 327 if(WIN32)
 328         if(NOT LYX_CONSOLE)
 329                 set(WIN32_CONSOLE WIN32)
 330                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 331         endif()
 332         if(MSVC)
 333                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 334                 # disable checked iterators for msvc release builds to get maximum speed
 335                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 336         else()
 337                 add_definitions(-DWINVER=0x0500)
 338         endif()
 339 endif()
 340
 341 message(STATUS "")
 342 foreach(_v PACKAGE PACKAGE_VERSION
 343         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 344         LYX_ABS_TOP_SRCDIR
 345         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 346         if(NOT DEFINED ${_v})
 347                 message(FATAL_ERROR "${_v} not defined")
 348         endif()
 349         string(SUBSTRING "${_v}                            " 0 28 _v1)
 350         message(STATUS "----- ${_v1}: ${${_v}}")
 351 endforeach(_v)
 352 message(STATUS "")
 353
 354
 355 if(LYX_PCH)
 356         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 357         # Not sure if it works for all non-msvc compilers
 358         include(PCHSupport_26)
 359         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 360         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 361         add_definitions(-DLYX_ENABLE_PCH)
 362
 363         if(MSVC)
 364                 macro(lyx_add_msvc_pch name_)
 365                         set_source_files_properties(${${name_}_sources} PROPERTIES
 366                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 367                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 368                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 369                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 370                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 371                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 372                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 373                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 374                 endmacro(lyx_add_msvc_pch)
 375                 macro(lyx_add_gcc_pch name_)
 376                 endmacro()
 377         else()
 378                 macro(lyx_add_msvc_pch name_)
 379                 endmacro()
 380                 macro(lyx_add_gcc_pch name_)
 381                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 382                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 383                 endmacro()
 384         endif()
 385 else()
 386         macro(lyx_add_msvc_pch)
 387         endmacro(lyx_add_msvc_pch)
 388         macro(lyx_add_gcc_pch name_)
 389         endmacro()
 390 endif()
 391
 392 if(MSVC)
 393         if(LYX_VLD)
 394                 set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 395                 set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 396                 set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 397                 include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 398         endif()
 399
 400         if(LYX_WALL)
 401                 # Use the highest warning level
 402                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 403
 404                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 405                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 406                 else()
 407                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 408                 endif()
 409
 410                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 411                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 412                 else()
 413                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 414                 endif()
 415
 416                 # add here warnings which should produce an error /weXXXX
 417                 set(MSVC_W_ERROR   "/we4101 /we4189")
 418                 # add here warnings which should be disabled /wdXXXX
 419                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 420
 421                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 422                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 423                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 424
 425         else()
 426                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 427
 428                 # add here warnings which should produce an error /weXXXX
 429                 set(MSVC_W_ERROR   "/we4101 /we4189")
 430                 # add here warnings which should be disabled /wdXXXX
 431                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 432
 433                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 434                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 435                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 436
 437         endif()
 438         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 439         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 440         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 441
 442         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 443         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 444         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 445         message(STATUS "")
 446 endif()
 447
 448
 449 if(LYX_DEBUG_GLIBC)
 450         set(_GLIBCXX_DEBUG 1)
 451 endif()
 452
 453 if(LYX_DEBUG_GLIBC_PEDANTIC)
 454         set(_GLIBCXX_DEBUG_PEDANTIC 1)
 455 endif()
 456
 457 # compiler tests, config.h generation
 458 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 459         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 460 else()
 461         include(ConfigureChecks.cmake)
 462         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 463 endif()
 464
 465 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 466
 467
 468 add_subdirectory(src)
 469 add_subdirectory(lyx2lyx)
 470 add_subdirectory(scripts)
 471
 472
 473 if(LYX_INSTALL)
 474         FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 475         if(${LYX_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 476                 message(FATAL_ERROR "Perl required!")
 477         endif()
 478         add_subdirectory(man)
 479         add_subdirectory(doc)
 480         include(../Install)
 481 endif()
 482
 483
 484 message(STATUS)
 485 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=1 or 0:")
 486 message(STATUS)
 487 LYX_OPTION_LIST_ALL()
 488
 489
 490 set(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 491 set(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 492 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 493
 494 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 495 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 496
 497 set(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 498 #
 499 # needed by rpm
 500 set(CPACK_SET_DESTDIR "ON")
 501 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 502 set(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 503 set(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 504 #
 505 # the next ones are needed by deb
 506 set(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 507 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 508
 509 # This is experimental, valid on _my_ system (Kornel)
 510 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 511 if(ASPELL_FOUND)
 512         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 513 endif()
 514 if(ENCHANT_FOUND)
 515         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libenchant1c2a (>= 1.6.0-0),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 516 endif()
 517 if(LYX_EXTERNAL_BOOST)
 518         if(Boost_FOUND)
 519                 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libboost-regex1.40.0 (>= 1.40.0-4),libboost-signals1.40.0 (>= 1.40.0-4),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 520         endif()
 521 endif()
 522 #
 523 # for the next ones, cpack insists on data with values in some file
 524 set(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 525 set(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 526
 527 # Find the revision number and use it as the release in rpm-package-build.
 528 # This way we may omit the otherwise needed "--force" parameter when
 529 # installing from that rpm package.
 530 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 531 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 532 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 533         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 534         # We use this value also to set the package-patch-value
 535         if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 536                 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 537         endif()
 538 endif()
 539
 540 # we do not have a readme or welcome data,
 541 # so we do not provide infofiles for
 542 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 543
 544 include(CPack)
 545
 546 #Now it is possible to create some packages
 547 # cd <BuildDir>
 548 # make package
 549 #############################################################################################
 550 # So, e.g. for variables
 551 #    CMAKE_PROJECT_NAME                     : lyx
 552 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 553 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 554 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 555 #    CMAKE_SYSTEM_NAME                      : Linux
 556 #    CPACK_BINARY_DEB:BOOL                  : ON
 557 #
 558 # the package name builds as "lyx-2.0.1-Linux.deb"
 559 #
 560 ############################## rpm ################################### deb ##################
 561 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 562 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 563 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 564 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 565 #
 566 message(STATUS)