development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif()
  15
  16 set(LYX_PROJECT lyx)
  17 project(${LYX_PROJECT})
  18
  19 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  20
  21 # Supress regeneration
  22 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  23
  24 # where to look first for cmake modules,
  25 # before ${CMAKE_ROOT}/Modules is checked
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  27 include(LyXMacros)
  28
  29
  30 # Usage LYX_OPTION
  31 # 1. parameter: option name without prefix 'LYX_'
  32 # 2. parameter: description
  33 # 3. parameter: default value, ON or OFF
  34 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  35
  36
  37 LYX_OPTION_INIT()
  38
  39 LYX_OPTION(CPACK "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  40 if(LYX_CPACK)
  41         set(LYX_INSTALL ON CACHE BOOL "INSTALL option" FORCE)
  42 endif()
  43
  44 LYX_OPTION(INSTALL "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  45 if(LYX_INSTALL)
  46         set(LYX_NLS ON CACHE BOOL "Nls option" FORCE)
  47         set(LYX_ASPELL ON CACHE BOOL "Aspell option" FORCE)
  48         if (WIN32)
  49                 set(LYX_HUNSPELL ON CACHE BOOL "Hunspell option" FORCE)
  50         endif()
  51         set(LYX_CONSOLE OFF CACHE BOOL "No console option" FORCE)
  52         set(LYX_PACKAGE_SUFFIX ON CACHE BOOL "Package suffix option" FORCE)
  53         set(LYX_RELEASE ON CACHE BOOL "Release option" FORCE)
  54         set(LYX_PROFILE OFF CACHE BOOL "Profile option" FORCE)
  55 endif()
  56
  57 LYX_OPTION(NLS "Use nls" OFF ALL)
  58 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  59 LYX_OPTION(ENCHANT "Require Enchant" OFF ALL)
  60 LYX_OPTION(HUNSPELL "Require Hunspell" OFF ALL)
  61 LYX_OPTION(DEVEL_VERSION "Build developer version" OFF ALL)
  62 LYX_OPTION(RELEASE "Build release version, build debug when disabled" ON ALL)
  63 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  64 LYX_OPTION(EXTERNAL_BOOST "Use external boost" OFF GCC)
  65 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  66 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" ON ALL)
  67 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  68 LYX_OPTION(INSTALL_PREFIX "Install path for LyX" OFF ALL)
  69 LYX_OPTION(CONSOLE "Show console on Windows" ON MSVC)
  70 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  71 LYX_OPTION(WALL "Enable all warnings" OFF MSVC)
  72 LYX_OPTION(PCH "Use precompiled headers" OFF ALL)
  73 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  74 LYX_OPTION(MERGE_REBUILD "Rebuild generated files from merged files build" OFF ALL)
  75 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  76 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  77 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  78 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  79 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  80 LYX_OPTION(LYX_CONFIGURE_CHECKS "Also run configure checks for MSVC" OFF MSVC)
  81
  82
  83 message(STATUS)
  84
  85 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  86 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  87
  88
  89
  90 if(UNIX OR MINGW)
  91         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
  92         message(STATUS "Using GCC version ${GCC_VERSION}")
  93         if(NOT GCC_VERSION VERSION_LESS 4.4)
  94                 set(LYX_USE_TR1 1)
  95                 # GCC <= 4.5 does not support regex: there are linker errors
  96                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
  97                 set(LYX_USE_TR1_REGEX 0)
  98         endif()
  99 else()
 100         if(MSVC10)
 101                 set(LYX_USE_TR1 1)
 102                 set(LYX_USE_TR1_REGEX 1)
 103         endif()
 104 endif()
 105
 106
 107 set(VERSION_INFO "CMake Build")
 108
 109 # Try to get some informations from configure.ac
 110
 111 include(LyXPaths)    #called here to define the needed TOP_SRC_DIR-variable
 112 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 113
 114 if(WIN32)
 115         set(USE_WINDOWS_PACKAGING 1)
 116 elseif(APPLE)
 117         set(USE_MACOSX_PACKAGING 1)
 118 else()
 119         set(USE_POSIX_PACKAGING 1)
 120 endif()
 121
 122 macro(setstripped _varname _value)
 123         string(STRIP ${_value} _v)
 124         if(USE_POSIX_PACKAGING)
 125                 string(TOLOWER ${_v} ${_varname})
 126         else()
 127                 set(${_varname} ${_v})
 128         endif()
 129 endmacro(setstripped)
 130
 131 foreach(_c_l ${_config_lines} )
 132         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 133                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 134                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 135                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 136                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 137                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 138                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 139                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 140                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 141                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 142                 endif()
 143         endif()
 144         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 145                 set(LYX_DATE "${CMAKE_MATCH_1}")
 146         endif()
 147 endforeach(_c_l)
 148
 149
 150 if (LYX_INSTALL_PREFIX)
 151         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 152         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 153 endif()
 154
 155 if(LYX_PACKAGE_SUFFIX)
 156         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 157 else()
 158         set(PACKAGE ${PACKAGE_BASE})
 159 endif()
 160
 161 if(LYX_PROGRAM_SUFFIX)
 162         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 163 else()
 164         set(PROGRAM_SUFFIX "")
 165 endif()
 166
 167
 168 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 169         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 170         if (UNIX)
 171                 # don't use the default "/usr/local"
 172                 # but respect the user-choice on the command-line
 173                 if(LYX_INSTALL_SUFFIX)
 174                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 175                 else()
 176                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 177                 endif()
 178         endif()
 179         if(WIN32)
 180                 set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 181         endif()
 182 endif()
 183
 184 if (WIN32)
 185         set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 186 else()
 187         set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 188 endif()
 189
 190 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 191 set(LYX_LOCALEDIR "locale")
 192 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 193 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 194
 195
 196 if(NOT GROUP_CODE)
 197         #set(GROUP_CODE "The Golden Code")
 198         set(GROUP_CODE flat)
 199 endif()
 200
 201 # lyx's source files
 202 set(LYX_CPP_FILES *.cpp)
 203 set(LYX_HPP_FILES *.h)
 204 set(LYX_MOC_FILES moc_*.cpp)
 205
 206
 207 include(ProjectSourceGroup)
 208
 209
 210 if(LYX_PROFILE)
 211         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 212         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 213 endif()
 214
 215 if(LYX_RELEASE)
 216         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build release version" FORCE)
 217 else()
 218         set(CMAKE_BUILD_TYPE Debug CACHE STRING "Build debug version" FORCE)
 219 endif()
 220
 221 # When shared libs are supported enable this option
 222 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 223 if(LYX_SHARED_LIBRARIES)
 224         set(library_type SHARED)
 225 else()
 226         set(library_type STATIC)
 227 endif()
 228
 229 if(NOT MSVC)
 230         if(NOT LYX_QUIET)
 231                 set(CMAKE_VERBOSE_MAKEFILE ON)
 232         endif()
 233         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 234         if(LYX_STDLIB_DEBUG)
 235                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 236         endif()
 237         if(LYX_CONCEPT_CHECKS)
 238                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 239         endif()
 240         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 241         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 242         if(MINGW)
 243                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 244         else()
 245                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 246         endif()
 247         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 248 endif()
 249
 250
 251 find_package(Qt4 REQUIRED)
 252 find_package(ICONV REQUIRED)
 253 find_package(ZLIB REQUIRED)
 254
 255 include_directories(${CMAKE_BINARY_DIR} ${TOP_SRC_DIR}/src)
 256
 257 if(LYX_ASPELL)
 258         find_package(ASPELL)
 259         include_directories(${ASPELL_INCLUDE_DIR})
 260 endif()
 261
 262 if(LYX_ENCHANT)
 263         find_package(Enchant REQUIRED)
 264         include_directories(${ENCHANT_INCLUDE_DIR})
 265 endif()
 266
 267 if(LYX_HUNSPELL)
 268         find_package(Hunspell REQUIRED)
 269         include_directories(${HUNSPELL_INCLUDE_DIR})
 270 endif()
 271
 272 if(LYX_NLS)
 273         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python)
 274         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 275                 message(FATAL_ERROR "Python 2.6 needed!")
 276         endif()
 277         find_package(LyXGettext REQUIRED)
 278         include_directories(${TOP_SRC_DIR}/po)
 279         add_subdirectory(po)
 280 endif()
 281
 282 if(LYX_EXTERNAL_LIBINTL)
 283         find_package(Libintl REQUIRED)
 284         add_definitions(-DHAVE_GETTEXT) #TODO move to config.h
 285 else()
 286         add_subdirectory(intl)
 287 endif()
 288
 289 if(LYX_EXTERNAL_BOOST)
 290         message(STATUS "Searching for boost")
 291         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 292         if(Boost_FOUND)
 293                 message(STATUS "Boost found")
 294                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 295                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 296         else()
 297                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 298         endif()
 299 else()
 300         if(LYX_USE_TR1_REGEX)
 301                 set(Lyx_Boost_Libraries boost_signals)
 302         else()
 303                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 304         endif()
 305         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 306         include_directories(${TOP_SRC_DIR}/boost)
 307         add_subdirectory(boost)
 308 endif()
 309
 310
 311
 312
 313 if(WIN32)
 314         if(NOT LYX_CONSOLE)
 315                 set(WIN32_CONSOLE WIN32)
 316                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 317         endif()
 318         if(MSVC)
 319                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 320                 # disable checked iterators for msvc release builds to get maximum speed
 321                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 322         else()
 323                 add_definitions(-DWINVER=0x0500)
 324         endif()
 325 endif()
 326
 327 message(STATUS "")
 328 foreach(_v PACKAGE PACKAGE_VERSION
 329         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 330         LYX_ABS_TOP_SRCDIR
 331         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 332         if(NOT DEFINED ${_v})
 333                 message(FATAL_ERROR "${_v} not defined")
 334         endif()
 335         string(SUBSTRING "${_v}                            " 0 28 _v1)
 336         message(STATUS "----- ${_v1}: ${${_v}}")
 337 endforeach(_v)
 338 message(STATUS "")
 339
 340
 341 if(LYX_MERGE_FILES)
 342         set(LYX_PCH OFF)
 343 else()
 344         set(LYX_MERGE_REBUILD OFF)
 345 endif()
 346
 347 if(LYX_PCH)
 348         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 349         # Not sure if it works for all non-msvc compilers
 350         include(PCHSupport_26)
 351         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 352         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 353         add_definitions(-DLYX_ENABLE_PCH)
 354
 355         if(MSVC)
 356                 macro(lyx_add_msvc_pch name_)
 357                         set_source_files_properties(${${name_}_sources} PROPERTIES
 358                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 359                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 360                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 361                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 362                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 363                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 364                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 365                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 366                 endmacro(lyx_add_msvc_pch)
 367                 macro(lyx_add_gcc_pch name_)
 368                 endmacro()
 369         else()
 370                 macro(lyx_add_msvc_pch name_)
 371                 endmacro()
 372                 macro(lyx_add_gcc_pch name_)
 373                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 374                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 375                 endmacro()
 376         endif()
 377 else()
 378         set(LYX_PCH OFF CACHE STRING "Disable precompiled headers")
 379         macro(lyx_add_msvc_pch)
 380         endmacro(lyx_add_msvc_pch)
 381         macro(lyx_add_gcc_pch name_)
 382         endmacro()
 383 endif()
 384
 385 if(MSVC)
 386         if(LYX_VLD)
 387                 set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 388                 set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 389                 set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 390                 include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 391         endif()
 392
 393         if(LYX_WALL)
 394                 # Use the highest warning level
 395                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 396
 397                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 398                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 399                 else()
 400                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 401                 endif()
 402
 403                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 404                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 405                 else()
 406                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 407                 endif()
 408
 409                 # add here warnings which should produce an error /weXXXX
 410                 set(MSVC_W_ERROR   "/we4101 /we4189")
 411                 # add here warnings which should be disabled /wdXXXX
 412                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 413
 414                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 415                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 416                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 417
 418         else()
 419                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 420
 421                 # add here warnings which should produce an error /weXXXX
 422                 set(MSVC_W_ERROR   "/we4101 /we4189")
 423                 # add here warnings which should be disabled /wdXXXX
 424                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 425
 426                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 427                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 428                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 429
 430         endif()
 431         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 432         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 433         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 434
 435         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 436         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 437         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 438         message(STATUS "")
 439 endif()
 440
 441
 442 if(LYX_DEBUG_GLIBC)
 443         set(_GLIBCXX_DEBUG 1)
 444 endif()
 445
 446 if(LYX_DEBUG_GLIBC_PEDANTIC)
 447         set(_GLIBCXX_DEBUG_PEDANTIC 1)
 448 endif()
 449
 450 # compiler tests, config.h generation
 451 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 452         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 453 else()
 454         include(ConfigureChecks.cmake)
 455         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 456 endif()
 457
 458 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 459
 460
 461 add_subdirectory(src)
 462 add_subdirectory(lyx2lyx)
 463 add_subdirectory(scripts)
 464
 465
 466 if(LYX_INSTALL)
 467         FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 468         if(${LYX_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 469                 message(FATAL_ERROR "Perl required!")
 470         endif()
 471         add_subdirectory(man)
 472         add_subdirectory(doc)
 473         include(../Install)
 474 endif()
 475
 476
 477 message(STATUS)
 478 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=1 or 0:")
 479 message(STATUS)
 480 LYX_OPTION_LIST_ALL()
 481
 482
 483 set(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 484 set(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 485 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 486
 487 set(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 488 #
 489 # needed by rpm
 490 set(CPACK_SET_DESTDIR "ON")
 491 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 492 set(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 493 set(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 494 #
 495 # the next ones are needed by deb
 496 set(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 497 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 498
 499 # This is experimental, valid on _my_ system (Kornel)
 500 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 501 if(ASPELL_FOUND)
 502         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 503 endif()
 504 if(ENCHANT_FOUND)
 505         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libenchant1c2a (>= 1.6.0-0),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 506 endif()
 507 if(LYX_EXTERNAL_BOOST)
 508         if(Boost_FOUND)
 509                 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libboost-regex1.40.0 (>= 1.40.0-4),libboost-signals1.40.0 (>= 1.40.0-4),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 510         endif()
 511 endif()
 512 #
 513 # for the next ones, cpack insists on data with values in some file
 514 set(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 515 set(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 516
 517 # Find the revision number and use it as the release in rpm-package-build.
 518 # This way we may omit the otherwise needed "--force" parameter when
 519 # installing from that rpm package.
 520 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 521 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 522 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 523         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 524         # We use this value also to set the package-patch-value
 525         if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 526                 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 527         endif()
 528 endif()
 529
 530 # we do not have a readme or welcome data,
 531 # so we do not provide infofiles for
 532 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 533
 534 include(CPack)
 535
 536 #Now it is possible to create some packages
 537 # cd <BuildDir>
 538 # make package
 539 #############################################################################################
 540 # So, e.g. for variables
 541 #    CMAKE_PROJECT_NAME                     : lyx
 542 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 543 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 544 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 545 #    CMAKE_SYSTEM_NAME                      : Linux
 546 #    CPACK_BINARY_DEB:BOOL                  : ON
 547 #
 548 # the package name builds as "lyx-2.0.1-Linux.deb"
 549 #
 550 ############################## rpm ################################### deb ##################
 551 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 552 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 553 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 554 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 555 #
 556 message(STATUS)